package RPS::Import::SoundOn::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use parent qw/RPS::Import::MapFaceBase RPS::Import::ImporterMixed/;


sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                serviceID    => 'K',
                countryCode  => 'L',
                dateBegin    => 'A',
                formatType   => 'M',
                artistName   => 'F',
                upc          => 'G',
                albumName    => 'H',
                isrc         => 'E',
                trackName    => 'D',
                units        => 'O',
                currencyCode => 'Q',
                price        => 'X',
            }
        }
    }
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => { upc => 'UPC Code' }
        }
    }
}

sub productType { RPS::File::Sale::TYPE_TRACK }
sub mediaType   { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';

    my $country = Common::Country->Get($name);
    return $country->alpha2() if $country;

    $self->handleError( "Unknown country: $name", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $name;
}

sub saleDates {
    my $self = shift;

    my $period = $self->_getByFieldName('dateBegin') || '';

    # 2024-01-01~2024-01-31
    if ( $period =~ /^(\d{4})[-](\d{2})[-](\d{2})\s?~\s?(\d{4})[-](\d{2})[-](\d{2})$/ ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $1, $2, $3 ),
            date_end   => sprintf( "%04d-%02d-%02d", $4, $5, $6 )
        );
    }

    $self->fail( "Unable to determine date from '$period'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    if ( $type =~ /^(?:STREAMING|CREATION)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $type =~ /^DOWNLOAD$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $type =~ /^(?:OTHER|BUSINESSACCOUNT|NONPROMOTIONADVERTISING|PROMOTIONADVERTISING)$/i ) {
        $self->fail("Incorrect format type: '$type'")
    }

    $self->handleError( "Unknown format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub preProcessLine {
    my $self = shift;
    if ( $self->{sheetname} !~ /My Royalty/i ) {
        my $upc = $self->_getByFieldName('upc') || '';
        $self->fail("Sheet '" . $self->{sheetname} . "' sheet contains data for confirmation.") if $upc;
    }
}

sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceProductType { }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceMediaType   { }


1;