package RPS::Import::Spinning::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';

use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month);

use parent qw/RPS::Import::MapFaceBase RPS::Import::ImporterMixed/;

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName       => 'E',
                serviceID       => 'M',
                countryCode     => 'O',
                dateBegin       => 'A',
                productType     => 'J',
                formatType      => 'N',
                clientProductID => 'K',
                artistName      => 'G',
                upc             => 'I',
                albumName       => 'H',
                isrc            => 'J',
                trackName       => 'H',
                units           => 'Y',
                currencyCode    => 'Q',
                price           => 'AA',
                mediaType       => 'N',
            }
        }
    }
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => { upc => 'EAN' }
        }
    }
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';

    my $country = Common::Country->Get($name);
    return $country->alpha2() if $country;

    $self->handleError( "Unknown country: $name", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $name;
}

sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';

    # "2023-Q1" = 03/31/2023
    if ( my($y, $q) = $date =~ /^(\d{4})\-Q(\d)$/i ) {
        my $mBegin = $q * 3 - 2;
        my $mEnd = $q * 3;
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $mBegin, 1),
            date_end   => sprintf( "%04d-%02d-%02d", $y, $mEnd, Days_in_Month($y, $mEnd))
        )
    }

    $self->fail( "Unable to determine date from '$date'." );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    return !$type ? RPS::File::Sale::TYPE_ALBUM : RPS::File::Sale::TYPE_TRACK;
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';

    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^(?:Cloud|Subscription)$/i;

    $self->handleError( "Unknown format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';

    return RPS::DB::Item::MediaType::kMediaTypeAudio if $type =~ /^(?:Download|Cloud|Subscription)$/i;

    $self->handleError( "Unknown media type: $type", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

sub albumName {
    my $self = shift;

    my $name = $self->_getByFieldName('albumName') || '';
    return $name if $self->productType eq RPS::File::Sale::TYPE_ALBUM;
}

sub trackName {
    my $self = shift;

    my $name = $self->_getByFieldName('trackName') || '';
    return $name if $self->productType eq RPS::File::Sale::TYPE_TRACK;
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    $price =~ s/\.//g;
    $price =~ s/,/\./g;

    return $price;
}

sub unitPrice { abs shift->SUPER::unitPrice }

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->price;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceProductType { }
sub _mapFaceMediaType   { 'mediaType' }


1;