package RPS::Import::TMobile;

use strict;

use Date::Calc qw(Decode_Month Days_in_Month);

use lib '/app/tools/data_classes/lib';

#private constants
my %field_map = (
    1 => {
        track  => 0,
        artist => 1,
        format => 2,
        retail => 3,
        isrc   => 4,
        units  => 5,
    },
    2 => {
        track   => 0,
        artist  => 1,
        units   => 2,
        credits => 3,
        isrc    => 5,
    },
);

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

# public methods

sub _importLines {
    my $self    = shift;
    my %args    = @_;
    my $lines   = $args{sheets}->[1];
    my $version = $self->_version();

    my $offsets = $field_map{$version};
    return undef unless ($lines);

    my $priceType = '';
    if ( $self->is_wmg )    # warner
    {
        require RPS::Import::WMG::Util;
        if ( $version == 2 ) {
            unless ( $priceType = RPS::Import::WMG::Util::getWirelessPriceType('ringback') ) {
                $self->warning();
                print STDERR "unknown format mapping: ringback\n";
            }
        }
        my $fileObj = $args{file};
        $fileObj->Atomic(1);
        $fileObj->Save();
    }
    my ( $dateBegin, $dateEnd, $rates ) = $self->_getDatesAndRates( $args{sheets}->[0] );
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr('couldn\'t get dates');
        return undef;
    }

    unless ( ref($rates) eq 'HASH' ) {
        $self->errstr('couldn\'t get rates');
        return undef;
    }

    my %errors  = ();
    my $linenum = 1;
    foreach my $line (@$lines) {
        my ( $format, $retail, $price, $credits );

        my $prodtype = RPS::File::Sale::TYPE_TRACK;
        my $artist   = $line->[ $offsets->{artist} ];
        my $track    = $line->[ $offsets->{track} ];
        my $units    = $line->[ $offsets->{units} ];
        my $isrc     = $line->[ $offsets->{isrc} ];
        $isrc = '' unless ( $isrc =~ m/[a-zA-Z]\d+/ );

        if ( $track && ( $artist || $isrc ) && ( $units !~ /[a-zA-Z]/ ) ) {
            if ( $version == 1 ) {
                if ( $self->is_wmg() ) {
                    my $fmt = $line->[ $offsets->{format} ];
                    $format = RPS::Import::WMG::Util::getWirelessFormatTypeID($fmt);
                    unless ( $format || $errors{$fmt} ) {
                        $self->errstr('unknown format');
                        print STDERR "unknown format: $fmt\n";
                        $errors{$fmt} = 1;
                        $linenum++;
                        next;
                    }

                    $priceType = RPS::Import::WMG::Util::getWirelessPriceType($fmt);
                    unless ( $priceType || $errors{$fmt} ) {
                        $self->warning();
                        print STDERR "unknown format mapping: $fmt ($linenum)\n";
                        $errors{$fmt} = 1;
                    }
                } else {
                    $format = RPS::File::Sale::FORMAT_RINGBACK;
                }

                $retail = $line->[ $offsets->{retail} ];
                unless ( $price = $rates->{$format}{$retail} ) {
                    print STDERR "can't map '$format' '$retail' to a rate\n";
                    return undef;
                }
            } elsif ( $version == 2 ) {
                $format  = RPS::File::Sale::FORMAT_RINGBACK;
                $retail  = $rates->{retail};
                $price   = $rates->{share};
                $credits = $line->[ $offsets->{credits} ];
            }

            my $rate;

            if ($retail) {
                $rate = $price / $retail;
            } else {
                $rate = 0;
            }

            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->isrc($isrc);
            $sale->price($price);
            $sale->wholesaleRate($rate);
            $sale->retail($retail);
            $sale->priceType($priceType);
            $sale->lineNum($linenum);

            if ( $units > 0 ) {
                $sale->units($units);

                #$args{dumper}($sale); # for cmd-line testing
                $self->_insertSale( sale => $sale );
            }

            if ( $credits > 0 ) {
                $sale->units( $credits * -1 );

                #$args{dumper}($sale); # for cmd-line testing
                $self->_insertSale( sale => $sale );
            }
        }    #else { print STDERR "skip u: $units p: $price t: $track a: $artist i: $isrc ($linenum)\n"; }
        $linenum++;
    }
    $self->warning() if ( keys %errors );

    return $linenum;
}

#
# Private methods
#

sub _getDatesAndRates {
    my $self  = shift;
    my $sheet = shift;
    my ( $month, $year );
    my %rates;

    foreach my $line (@$sheet) {
        next if ( lc $line->[0] eq 'total' );
        if ( $line->[0] =~ /for the month of\s(\w+)\s(\d{4})/i ) {
            $year  = $2;
            $month = Decode_Month($1);
        }

        # version 2
        elsif ( $line->[3] =~ /^\d+$/ && $line->[4] =~ /(\d+\.)?\d+$/ && $line->[5] =~ /(\d+\.)?\d+$/ && $line->[6] =~ /^\d+\.\d+$/ ) {
            $rates{retail} = $line->[4];
            $rates{share}  = $line->[5];
        } elsif ( $line->[0] =~ m/\w+/ && $line->[1] =~ m/^\d+$/ && $line->[2] =~ /(\d+\.)?\d+$/ ) {
            my $formatID = $self->getWirelessFormatID( $line->[0] );
            unless ($formatID) {
                print STDERR "can't get format from '$line->[0]'\n";
                next;
            }
            $rates{$formatID}{ $line->[2] } = $line->[3];
        }
    }

    return unless ( $month && $year );

    return ( sprintf( "%d-%02d-01", $year, $month ), sprintf( "%d-%02d-%d", $year, $month, Days_in_Month( $year, $month ) ), \%rates );
}

###
1;    # Play nicely.
###