package RPS::Import::TikTok::v2;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use parent 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName    => 'H',
        serviceID    => 'C',
        countryCode  => 'K',
        dateBegin    => 'A',
        dateEnd      => 'B',
        artistName   => 'F',
        upc          => 'J',
        albumName    => 'G',
        isrc         => 'I',
        trackName    => 'E',
        units        => 'N',
        currencyCode => 'Q',
        price        => 'P',
    }
}

sub _unverifiedFieldMap { {} }

sub _headerIdentifier { upc => 'product_code' }

sub productType { RPS::File::Sale::TYPE_TRACK }
sub formatType  { RPS::File::Sale::FORMAT_STREAM }
sub mediaType   { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    my $dateEnd   = $self->_getByFieldName('dateEnd')   || '';

    # YYYYMMDD
    my @db = $dateBegin =~ /^(\d{4})(\d{2})(\d{2})$/;
    my @de = $dateEnd   =~ /^(\d{4})(\d{2})(\d{2})$/;
    if ( @db == 3 && @de == 3 ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $db[0], $db[1], $db[2] ),
            date_end   => sprintf( "%04d-%02d-%02d", $de[0], $de[1], $de[2] )
        );
    }

    $self->fail( "Unable to determine dates from: '$dateBegin' and '$dateEnd'." );
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unable to determine service from: '$service'");
}

sub countryCode {
    my $self = shift;

    my $countryCode = $self->_getByFieldName('countryCode') || '';
    return 'TL' if $countryCode =~ /^TP$/;

    my $country = Common::Country->Get($countryCode);
    return $country->alpha2 if $country;

    $self->fail( "Unable to determine country_code from: '$countryCode'." );
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

1;