package RPS::Import::UnitedMasters::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use lib '/app/tools/data_classes/lib';

use Client::Service;
use RPS::Import::ServiceMap;

use parent 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName       => 'AF',
        serviceID       => 'T',
        countryCode     => 'M',
        dateBegin       => 'Q',
        dateEnd         => 'R',
        productType     => 'B',
        clientProductID => 'AE',
        artistName      => 'E',
        upc             => 'AD',
        albumName       => 'AB',
        isrc            => 'B',
        trackName       => 'C',
        units           => 'N',
        price           => 'H',
    };
}

sub _unverifiedFieldMap {
    {
        _sale_type => 'O',
        _dsp       => 'T',
    };
}

sub _headerIdentifier { upc => 'Product UPC' }

sub currencyCode { 'USD' }

sub dateBegin {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';
    if ( $date =~ /(\d{1,2})[\/\.-](\d{1,2})[\/\.-](\d{4})/ ) {
        return sprintf "%04d-%02d-%02d", $3, $1, $2;
    }

    $self->fail("Unable to determine date begin from: '$date'");
}

sub dateEnd {
    my $self = shift;

    my $date = $self->_getByFieldName('dateEnd') || '';
    if ( $date =~ /(\d{1,2})[\/\.-](\d{1,2})[\/\.-](\d{4})/ ) {
        return sprintf "%04d-%02d-%02d", $3, $1, $2;
    }

    $self->fail("Unable to determine date end from: '$date'");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: '$service'");
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || 'US';
    my $country = Common::Country->Get($name);
    return $country->alpha2() if $country;

    $self->fail("Unable to determine country code from: '$name'");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    return RPS::File::Sale::TYPE_TRACK if $type;

    $self->fail("Unable to determine product type from: '$type'");
}

sub formatType {
    my $self = shift;

    my $saleType = $self->_getByFieldName('_sale_type') || '';
    my $dsp      = $self->_getByFieldName('_dsp')       || '';

    if ( $dsp =~ /^SoundExchange$/i ) {
        return RPS::File::Sale::FORMAT_PERFORMANCE;
    }

    if ( $saleType =~ /^Download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $saleType =~ /^Streaming$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $saleType =~ /^Video Stream \(Audio \+ Video\)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $saleType =~ /^Synch$/i ) {
        if ( $dsp =~ /^(?:Facebook Audio Library|Facebook Fingerprinting|TikTok|Snap)$/i ) {
            return RPS::File::Sale::FORMAT_STREAM;
        }
    } elsif ( $saleType =~ /^Other$/i ) {
        if ( $dsp =~ /^(?:Pandora|iTunes Match|TDC Play|Meta)$/i ) {
            return RPS::File::Sale::FORMAT_STREAM;
        }
    }

    $self->fail("Unable to determine format type from: '$saleType' and '$dsp'");
}

sub mediaType {
    my $self = shift;

    my $saleType = $self->_getByFieldName('_sale_type') || '';
    my $dsp      = $self->_getByFieldName('_dsp')       || '';

    if ( $dsp =~ /^SoundExchange$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    if ( $saleType =~ /^Download$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $saleType =~ /^Streaming$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $saleType =~ /^Video Stream \(Audio \+ Video\)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } elsif ( $saleType =~ /^Synch$/i ) {
        if ( $dsp =~ /^(?:Facebook Audio Library|Facebook Fingerprinting|TikTok|Snap)$/i ) {
            return RPS::DB::Item::MediaType::kMediaTypeAudio;
        }
    } elsif ( $saleType =~ /^Other$/i ) {
        if ( $dsp =~ /^(?:Pandora|iTunes Match|TDC Play|Meta)$/i ) {
            return RPS::DB::Item::MediaType::kMediaTypeAudio;
        }
    }

    $self->fail("Unable to determine media type from: '$saleType' and '$dsp'");
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}


1;