#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v21;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Country;
use Common::RSMath qw(round);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin   => 'A',
        countryCode => 'B',
        artistName  => 'J',
        units       => 'L',
        price       => 'T',
        productType => 'E',    # spar code
    };
}

sub _unverifiedFieldMap {
    {
        itemID    => 'F',      # upc or isrc
        itemTitle => 'I',      # album or track title
        salesType => 'D',
    };
}

sub _headerIdentifier { ( dateBegin => 'Accounting Quarter' ) }

sub _processHeader {
    my $self = shift;

    my $price = $self->_getByFieldName('price');

    if ( $self->_isHeader() ) {
        if ( $price =~ /Due (.*)/ ) {
            if ( $1 =~ /^\xA3$/ ) {
                $self->{_currencyCode} = 'GBP';
            }
        }
    }
    return $self->SUPER::_processHeader(@_);
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode};
}

my %gFormatMediaMap = (
    '03' => {
        formatType => RPS::File::Sale::FORMAT_STREAM,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '06' => {
        formatType => RPS::File::Sale::FORMAT_STREAM,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '11' => {
        formatType => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '31' => {
        formatType => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '36' => {
        formatType => RPS::File::Sale::FORMAT_TETHERED,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '39' => {
        formatType => RPS::File::Sale::FORMAT_STREAM,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '53' => {
        formatType => RPS::File::Sale::FORMAT_RINGTONE,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '55' => {
        formatType => RPS::File::Sale::FORMAT_RINGTONE,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    '57' => {
        formatType => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeVideo,
    },
    'sc' => {
        formatType => RPS::File::Sale::FORMAT_STREAM,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    'sd' => {
        formatType => RPS::File::Sale::FORMAT_TETHERED,
        mediaType  => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
);

sub saleDates {
    my $self = shift;
    my $dt   = $self->_getByFieldName('dateBegin');

    my $startDate;
    my $endDate;

    if ( $dt =~ /^(\d{4})(\d{1})$/ ) {
        my ( $year, $quarter ) = ( $1, $2 );

        ( $startDate, $endDate ) = $self->_getDates( date_begin => "$year Q$quarter" );
    }

    return ( $startDate, $endDate );
}

sub upc {
    my $self = shift;
    my $upc  = $self->_getByFieldName('itemID');
    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        $upc =~ s/^10//;    # remove leading "10"
        return $upc;
    }

    if ( !defined $self->productType ) {
        $upc =~ s/^10//;    # remove leading "10"
        return $upc if ( $upc =~ /^\d+$/ );    # if it's all numbers then it might be a UPC ...
    }

}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('itemID');
    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        $isrc =~ s/^5//;                       # remove leading "5"
        return $isrc;
    }

    if ( !defined $self->productType ) {
        $isrc =~ s/^5//;                       # remove leading "5"
        return $isrc if ( $isrc =~ /^[a-z]{2}/i );    # if it starts with 2 letters then it might be an ISRC ...
    }
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');

    if ( !defined $self->productType ) {
        my $upc = $self->_getByFieldName('itemID');
        $upc =~ s/^10//;                              # remove leading "10"
        return $name if ( $upc =~ /^\d+$/ );          # if it's all numbers then it might be a UPC, so assume album name ...
    }

    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $name : undef;
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');

    if ( !defined $self->productType ) {
        my $isrc = $self->_getByFieldName('itemID');
        $isrc =~ s/^5//;                              # remove leading "5"
        return $name if ( $isrc =~ /^[a-z]{2}/i );    # if it starts with 2 letters then it might be an ISRC, so assume track name ...
    }

    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $name : undef;
}

sub productType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if ( $code =~ /^(B1|B2|D1)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $code =~ /^(ID|IV)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } else {
        return $self->handleError( "Unknown spar code: $code", RPS::DB::Item::SaleImportError::kErrorProductType );
    }
}

sub formatType {
    my $self      = shift;
    my $salesType = lc $self->_getByFieldName('salesType');

    my ( $formatID, $mediaType ) = $self->_getFormatMedia($salesType);
    if ($formatID) {
        return $formatID;
    } else {
        return $self->handleError( "Unknown sales channel: $salesType", RPS::DB::Item::SaleImportError::kErrorFormatType );
    }
}

sub mediaType {
    my $self      = shift;
    my $salesType = lc $self->_getByFieldName('salesType');

    my ( $formatID, $mediaType ) = $self->_getFormatMedia($salesType);

    if ($mediaType) {
        return $mediaType;
    } else {
        return $self->handleError( "Unknown sales channel: $salesType", RPS::DB::Item::SaleImportError::kErrorMediaType );
    }
}

sub _getFormatMedia {
    my ( $self, $salesType ) = @_;

    my $formatID;
    my $mediaType;
    if ( exists $gFormatMediaMap{$salesType} ) {
        $formatID  = $gFormatMediaMap{$salesType}->{formatType};
        $mediaType = $gFormatMediaMap{$salesType}->{mediaType};
    }

    return ( $formatID, $mediaType );
}

sub countryCode {
    my $self = shift;

    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');
    if ( $cname =~ /^(\w{2,3})$/ )    # 2 or 3 character
    {
        $ccode = $cname;
    } else {
        my $o = Common::Country->Get($cname);
        if ( !$o ) {

            return $cname;            # Return original name and let MapFace deal with it
        }
        $ccode = $o->alpha2();
    }
    return $ccode;
}

sub units {
    my $self  = shift;
    my $units = $self->_getByFieldName('units');
    return round($units);
}

#####    MapFace    #####
#

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('salesType');
}

sub _mapFaceMediaType {
    return ('salesType');
}

###
1;    # Play nicely.
###