#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v33;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Country;
use Common::RSMath qw(round);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName   => 'B',
        serviceID   => 'J',
        dateBegin   => 'C',
        countryCode => 'A',
        artistName  => 'F',
        albumName   => 'G',
        trackName   => 'H',
        productType => 'L',
        formatType  => 'K',
        units       => 'N',
        price       => 'R',
    };
}

sub _unverifiedFieldMap {
    {
        itemID => 'E',    # upc or isrc
    };
}

sub _headerIdentifier { ( dateBegin => 'Sales Period' ) }

sub currencyCode { 'AUD' }

sub saleDates {
    my $self = shift;
    my $dt   = $self->_getByFieldName('dateBegin');

    my $startDate;
    my $endDate;

    if ( $dt =~ /^(\d{4})(\d{2})$/ ) {
        my ( $year, $month ) = ( $1, $2 );
        my $d = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
        ( $startDate, $endDate ) = $self->_getDates( date_begin => $d );
    }

    return ( $startDate, $endDate );
}

sub serviceID {
    my $self      = shift;
    my $service   = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if ($serviceID);

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub upc {
    my $self = shift;
    my $upc  = $self->_getByFieldName('itemID');
    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        $upc =~ s/^10//;    # remove leading "10"
        return $upc;
    }

    if ( !defined $self->productType ) {
        $upc =~ s/^10//;    # remove leading "10"
        return $upc if ( $upc =~ /^\d+$/ );    # if it's all numbers then it might be a UPC ...
    }
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('itemID');
    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        $isrc =~ s/^5//;                       # remove leading "5"
        return $isrc;
    }

    if ( !defined $self->productType ) {
        $isrc =~ s/^5//;                       # remove leading "5"
        return $isrc if ( $isrc =~ /^[a-z]{2}/i );    # if it starts with 2 letters then it might be an ISRC ...
    }
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || '';

    if ( $type =~ /^Album\/Multi Track Single$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^(track|video)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( !$type ) {
        return $self->handleError( "Missing product_type.", RPS::DB::Item::SaleImportError::kErrorNonqualifying );
    }

    return $self->handleError( "Unknown type: $type", RPS::DB::Item::SaleImportError::kErrorProductType );

}

sub formatType {
    my $self = shift;
    my $code = $self->_getByFieldName('formatType');

    if (   $code =~ /^Ad-funded Streaming$/i
        || $code =~ /^Cloud Service$/i
        || $code =~ /^Subscription Streaming$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $code =~ /^Permanent Download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }
    return $self->handleError( "Unknown sales channel: $code", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    if ( $type =~ /^Album\/Multi Track Single$/i || $type =~ /^track$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $type =~ /^video$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        return $self->handleError( "Unknown type: $type", RPS::DB::Item::SaleImportError::kErrorMediaType );
    }
}

sub countryCode {
    my $self = shift;

    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');
    if ( $cname =~ /^(\w{2,3})$/ )    # 2 or 3 character
    {
        $ccode = $cname;
    } else {
        my $o = Common::Country->Get($cname);
        if ( !$o ) {
            return $cname;            # Return original name and let MapFace deal with it
        }
        $ccode = $o->alpha2();
    }
    return $ccode;
}

sub units {
    my $self  = shift;
    my $units = $self->SUPER::units();
    my $price = $self->SUPER::price();

    if ( $units =~ /\d\.\d+e-\d{2}/i ) {
        $units = 0;
    }

    $units = round($units);

    # The 'sign' of the units is driven by the price.
    # If the price is negative, we'll store negative units,
    # regardless of whether the units were positive or negative
    # in the sale file.  Accordingly, the price is always
    # positive.  This ensures that returns are recorded correctly.
    #
    if ( defined($price) && $price != 0 ) {
        return $price < 0 ? abs($units) * -1 : abs($units);
    } else {
        return $units;
    }
}

sub _isValidSaleRecord {
    my $self = shift;

    my $price  = $self->_getByFieldName('price');
    my $itemID = $self->_getByFieldName('itemID');

    return 0 if ( '' eq $price && '' eq $itemID );

    return ( defined( $self->price ) && ( $self->trackName || $self->albumName ) );
}

#####    MapFace    #####
#

sub _mapFaceCompatibleVersions {
    return ( 33, 34, 65 );
}

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('formatType');
}

sub _mapFaceMediaType {
    return ('productType');
}

###
1;    # Play nicely.
###