#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v37;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self     = shift;
    my $version  = $self->_version;
    my %fieldMap = (
        37 => {
            dateBegin   => 'A',
            countryCode => 'K',
            productType => 'H',    # Carrier Type
            upc         => 'L',    # Article Number
            albumName   => 'G',
        },
        52 => {
            dateBegin   => 'A',
            countryCode => 'L',
            productType => 'I',    # Carrier Type
            upc         => 'M',    # Article Number
            albumName   => 'G',
        },
        54 => {
            dateBegin   => 'A',
            countryCode => 'N',
            productType => 'H',    # Carrier Type
            upc         => 'O',    # Article Number
            albumName   => 'G',
        },
    );
    return $fieldMap{$version};
}

sub _unverifiedFieldMap {
    my $self     = shift;
    my $version  = $self->_version;
    my %fieldMap = (
        37 => {
            salesChannel => 'P',
            netUnits     => 'Q',
            netRevenue   => 'AA',
        },
        52 => {
            salesChannel => 'Q',
            netUnits     => 'R',
            netRevenue   => 'AB',
        },
        54 => {
            salesChannel => 'S',
            netUnits     => 'T',
            netRevenue   => 'AD',
        },
    );
    return $fieldMap{$version};
}

sub _headerIdentifier { ( dateBegin => 'Processing Period' ) }

sub physical { 1 }

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode};    # See _processHeader
}

sub countryCode {
    my $self = shift;

    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');

    $cname = "Czech Republic" if ( $cname =~ /^CZECH$/i );

    if ( $cname =~ /^(\w{2,3})$/ )    # 2 or 3 character
    {
        $ccode = $cname;
    } else {
        my $o = Common::Country->Get($cname);
        if ( !$o ) {
            $self->fail("Unknown country: $cname");
        }
        $ccode = $o->alpha2();
    }
    return $ccode;
}

sub saleDates {
    my $self = shift;
    my $dt   = $self->_getByFieldName('dateBegin');
    my $startDate;
    my $endDate;
    if ( $dt =~ /^(\d{4})(\d{2})$/ )    #  YYYYDD
    {
        my ( $year, $month ) = ( $1, $2 );
        $startDate = sprintf( "%04d-%02d-01", $year, $month );
        $endDate = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
    } elsif ( $dt =~ /^(\d{4})(\d{2}) \/ (\d{4})(\d{2})$/ )    #  YYYYMM / YYYYMM
    {
        my ( $sYear, $sMonth, $eYear, $eMonth ) = ( $1, $2, $3, $4 );
        $startDate = sprintf( "%04d-%02d-01", $sYear, $sMonth );
        $endDate = sprintf( "%04d-%02d-%02d", $eYear, $eMonth, Days_in_Month( $eYear, $eMonth ) );
    }

    return ( $startDate, $endDate );
}

sub productType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if ( $code =~ /^(D1|D5|D8)$/i ) {
        return RPS::File::Sale::TYPE_CD;
    } elsif ( $code =~ /^(L6|S6|S5|L5)$/i ) {
        return RPS::File::Sale::TYPE_LP;
    } elsif ( $code =~ /^(P1|R5|K3|Q3|P7)$/i ) {
        return RPS::File::Sale::TYPE_DVD;
    } elsif ( $code =~ /^(N8|P8)$/i ) {
        return RPS::File::Sale::TYPE_DVD_CD_SET;
    } elsif ( $code =~ /^(M1|M2|M7)$/i ) {
        return RPS::File::Sale::TYPE_CASS;
    } elsif ( $code =~ /^V1$/i ) {
        return RPS::File::Sale::TYPE_VHS;
    } elsif ( $code =~ /^D4$/i ) {
        return RPS::File::Sale::TYPE_CD_SIN;
    } else {
        $self->fail("Unknown product type from $code");
        return undef;
    }
}

sub priceLevel {
    my $self = shift;
    my $ch = $self->_getByFieldName('salesChannel') || return;

    if ( $ch =~ /^(11|21)$/ ) {
        return RPS::File::Sale::PLEVEL_FULL;
    } elsif ( $ch =~ /^(12|15|DA|07)$/i ) {
        return RPS::File::Sale::PLEVEL_UNKNOWN;
    }
    $self->fail("Unable to get price tier from $ch");
}

sub channel {
    my $self = shift;
    my $ch = $self->_getByFieldName('salesChannel') || return;

    if ( $ch =~ /^(11|21|07)$/ ) {
        return RPS::File::Sale::CHANNEL_RETAIL;
    } elsif ( $ch =~ /^12$/ ) {
        return RPS::File::Sale::CHANNEL_CLUB;
    } elsif ( $ch =~ /^15$/ ) {
        return RPS::File::Sale::CHANNEL_MAILORDER;
    } elsif ( $ch =~ /^DA$/i ) {
        return RPS::File::Sale::CHANNEL_DIRECT;
    }
}

sub sales {
    my $self    = shift;
    my $units   = $self->_getByFieldName('netUnits');
    my $revenue = $self->_getByFieldName('netRevenue');
    return ( $revenue > 0 ) ? abs($units) : 0;
}

sub salesRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('netRevenue');
    return ( $revenue > 0 ) ? $revenue : 0;
}

sub returns {
    my $self    = shift;
    my $units   = $self->_getByFieldName('netUnits');
    my $revenue = $self->_getByFieldName('netRevenue');
    return ( $revenue < 0 ) ? abs($units) : 0;
}

sub returnsRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('netRevenue');
    return ( $revenue < 0 ) ? abs($revenue) : 0;
}

sub totalRevenue {
    my $self = shift;
    return $self->salesRevenue - $self->returnsRevenue;
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    return $self->SUPER::_processSheet( $sheet, $sheetnum ) if ( $self->_version == 54 );
    if ( $self->{sheetname} =~ /^(Report|Physical)$/i ) {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

sub _processHeader {
    my $self = shift;
    my $c    = $self->_getByFieldName('netRevenue');

    # Note: _processHeader is called for every line until we actually find
    # the header (assuming _headerIdentifier() is setup correctly).  We
    # only want to look at the header line itself.
    #
    return if ( !defined $self->{_headerFound} );

    if ( $c =~ /Net Royalty Amount \((\w{2,3})\)/i ) {
        $self->{_currencyCode} = $1;
    } else {
        $self->fail("Unable to get currency code from $c");
    }
}

sub _isValidSaleRecord {
    my $self      = shift;
    my $albumName = $self->_getByFieldName('albumName');
    my $revenue   = $self->_getByFieldName('netRevenue');

    return ( $albumName && $revenue );
}

###
1;    # Play nicely.
###