#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v46;

use strict;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin   => 'G',
        dateEnd     => 'H',
        countryCode => 'J',
        units       => 'W',
        price       => 'AR',
        artistName  => 'S',
        formatType  => 'U',
        productType => 'R',
    };
}

sub _unverifiedFieldMap {
    {
        itemID    => 'M',
        itemTitle => 'N',
    };
}

sub _headerIdentifier { ( dateBegin => 'Sls Per Begin Quarter' ) }

sub currencyCode {
    return shift->{_currencyCode};    # See _processHeader
}

sub countryCode {
    my $self = shift;

    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');

    $cname = "Czech Republic" if ( $cname =~ /^CZECH$/i );

    if ( $cname =~ /^(\w{2,3})$/ )    # 2 or 3 character
    {
        $ccode = $cname;
    } else {
        my $o = Common::Country->Get($cname);
        if ( !$o ) {
            $self->handleError( "Unknown country: $cname", RPS::DB::Item::SaleImportError::kErrorCountry );
            return $cname;
        }
        $ccode = $o->alpha2();
    }
    return $ccode;
}

sub saleDates {
    my $self      = shift;
    my $startDate = $self->_getByFieldName('dateBegin');
    my $endDate   = $self->_getByFieldName('dateEnd');

    if ( $startDate =~ /^(\d{4})(\d)$/ || $endDate =~ /^(\d{4})(\d)$/ ) {
        my $dateBegin = $1 . "Q" . $2 if ( $startDate =~ /^(\d{4})(\d)$/ );
        my $dateEnd   = $1 . "Q" . $2 if ( $endDate =~ /^(\d{4})(\d)$/ );
        return $self->_getDates( date_begin => $dateBegin, type => 'quarter' );
    }
    return $self->_getDates( date_begin => $startDate, date_end => $endDate );    # try the date as-is
}

sub productType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if (   $code =~ /^eAlbum Audio HD$/i
        || $code =~ /^E Album$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $code =~ /^Internet Download$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }
    return $self->handleError( "Unknown product type: $code", RPS::DB::Item::SaleImportError::kErrorProductType );
}

sub formatType {
    my $self = shift;
    my $code = $self->_getByFieldName('formatType') || return;
    if ( $code =~ /^Permanent Download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $code =~ /^Streaming \(subscription\)$/i
        || $code =~ /^Subscription Streaming by Third Party$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    return $self->handleError( "Unknown format: $code", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if (   $code =~ /^Internet Download$/i
        || $code =~ /^eAlbum Audio HD$/i
        || $code =~ /^E Album$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
    return $self->handleError( "Unknown media type: $code", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

sub upc {
    my $self = shift;
    my $upc  = $self->_getByFieldName('itemID');
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $upc : undef;
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('itemID');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $isrc : undef;
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $name : undef;
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $name : undef;
}

sub _processHeader {
    my $self = shift;
    my $c    = $self->_getByFieldName('price');

    # Note: _processHeader is called for every line until we actually find
    # the header (assuming _headerIdentifier() is setup correctly).  We
    # only want to look at the header line itself.
    #
    return if ( !defined $self->{_headerFound} );

    if ( $c =~ /NOR AIF Amt (\w{3}) \(NET\)/i ) {
        $self->{_currencyCode} = $1;
    } else {
        $self->fail("Unable to get currency code from $c");
    }
    return $self->SUPER::_processHeader(@_);
}

#####    MapFace    #####
#

sub _mapFaceCompatibleVersions {
    return (46);
}

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('formatType');
}

sub _mapFaceMediaType {
    return ('productType');
}

###
1;    # Play nicely.
###