#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v59;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin   => 'C',
        serviceID   => 'D',
        countryCode => 'B',
        isrc        => 'H',
        units       => 'M',
        price       => 'R',
        formatType  => 'J',
        productType => 'I',
    };
}

sub _unverifiedFieldMap {
    {
        productNumber => 'E',    # upc or isrc
        title         => 'F',    # album or track title
    };
}

sub _headerIdentifier { ( productNumber => 'Product Number' ) }

sub currencyCode { 'EUR' }

sub countryCode {
    my $self = shift;
    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');
    $cname = "Czech Republic" if ( $cname =~ /^CZECH$/i );
    my $o = Common::Country->Get($cname);
    if ( !$o ) {
        $self->handleError( "Unknown country: $cname", RPS::DB::Item::SaleImportError::kErrorCountry );
        return $cname;
    }
    $ccode = $o->alpha2();
    return $ccode;
}

sub serviceID {
    my $self      = shift;
    my $service   = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if ($serviceID);

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub saleDates {
    my $self   = shift;
    my $period = $self->_getByFieldName('dateBegin');

    if ( $period =~ /^(\d{4})(\d{2})-(\d{4})(\d{2})$/ ) {
        my $startDate = sprintf( "%04d-%02d-01", $1, $2 );
        my $endDate = sprintf( "%04d-%02d-%02d", $3, $4, Days_in_Month( $3, $4 ) );

        return $self->_getDates( date_begin => $startDate, date_end => $endDate );
    }
    return $self->_getDates( date_begin => $period );
}

sub productType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if ( $code =~ /^E-Album$|CD/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $code =~ /^Audio Track|VIDEO TRACK$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }
    return $self->handleError( "Unknown product type: $code", RPS::DB::Item::SaleImportError::kErrorProductType );
}

sub formatType {
    my $self = shift;
    my $code = $self->_getByFieldName('formatType') || return;
    if ( $code =~ /^Permanent Download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $code =~ /^Subscription Streaming$/i
        || $code =~ /^Cloud Service$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $code =~ /^Subscription Download$/i ) {
        return RPS::File::Sale::FORMAT_TETHERED;
    }

    return $self->handleError( "Unknown format: $code", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    if ( $type =~ /^VIDEO TRACK$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } elsif ( $type =~ /^E\-ALBUM|AUDIO TRACK|CD$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    return $self->handleError( "Unknown media type: $type", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

sub upc {
    my $self = shift;
    my $upc  = $self->_getByFieldName('productNumber');
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $upc : undef;
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');
    my $upc  = $self->_getByFieldName('productNumber');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? ( $isrc || $upc ) : undef;
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('title');
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $name : undef;
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('title');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $name : undef;
}

sub XXX_processHeader {
    my $self = shift;
    my $c    = $self->_getByFieldName('price');

    # Note: _processHeader is called for every line until we actually find
    # the header (assuming _headerIdentifier() is setup correctly).  We
    # only want to look at the header line itself.
    #
    return if ( !defined $self->{_headerFound} );

    if ( $c =~ /NOR AIF Amt (\w{3}) \(NET\)/i ) {
        $self->{_currencyCode} = $1;
    } else {
        $self->fail("Unable to get currency code from $c");
    }
    return $self->SUPER::_processHeader(@_);
}

#####    MapFace    #####
#

sub _mapFaceCompatibleVersions {
    return (59);
}

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('formatType');
}

sub _mapFaceMediaType {
    return ('productType');
}

###
1;    # Play nicely.
###