package RPS::Import::Universal::v79;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use parent qw/RPS::Import::Universal::v77/;

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName   => 'A',
                serviceID   => 'K',
                countryCode => 'D',
                dateBegin   => 'C',
                formatType  => 'J',
                artistName  => 'E',
                upc         => 'F',
                albumName   => 'G',
                isrc        => 'H',
                trackName   => 'I',
                units       => 'L',
                price       => 'R',
                mediaType   => 'K',
            }
        }
    }
}


sub _unverifiedFieldMapExtended {{}}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => { upc => 'UPC' }
        }
    }
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );

    my @parts = map { s/^\s+|\s+$//gr } split(/\//, $service);
    my $serviceName = pop @parts;

    my $serviceID = $self->getServiceID($serviceName) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$serviceName};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

my %months = (
    jan => 1, feb => 2, mar => 3, apr => 4, may => 5, jun => 6,
    jul => 7, aug => 8, sep => 9, oct => 10, nov => 11, dec => 12,
);

sub saleDates {
    my $self = shift;

    # MMM YYYY
    my $period = $self->_getByFieldName('dateBegin') || '';

    if ( my ($m, $y) = $period =~ /([a-z]{3})\s*(\d{4})/i ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $months{lc $m}, 1 ),
            date_end   => sprintf( "%04d-%02d-%02d", $y, $months{lc $m}, Days_in_Month( $y, $months{lc $m} ) ),
        );
    }
    # YYYYMM
    elsif ( ($y, $m) = $period =~ /(\d{4})(\d{2})/i ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $m, 1 ),
            date_end   => sprintf( "%04d-%02d-%02d", $y, $m, Days_in_Month( $y, $m ) ),
        );
    }

    $self->fail( "Unable to determine sale date from '$period'." );
}

sub productType {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || '';
    my $trackName = $self->_getByFieldName('trackName') || '';

    if ( $isrc || $trackName ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail( "Unable to determine product type." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    if ( $type =~ /^Streaming and Subscriptions$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $type =~ /^Digital Downloads$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }

    return $self->handleError( "Unknown format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    return $type =~ /Video/i
        ? RPS::DB::Item::MediaType::kMediaTypeVideo
        : RPS::DB::Item::MediaType::kMediaTypeAudio;

    return $self->handleError( "Unknown media type: $type", RPS::DB::Item::SaleImportError::kErrorMediaType );
}



1;