package RPS::Import::WMG::Integra;
use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_upc);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';
use RPS::Import::WMG::Util;

my %media_map = ( EMD => RPS::File::Sale::FORMAT_DOWNLOAD, );

my %field_map = (
    1 => {
        media_type => 2,
        title      => 3,
        upc        => 4,
        units      => 7,
        retail     => 11,
        price      => 13,
        price_type => 15,
    },
    2 => {
        media_type => 2,
        title      => 3,
        upc        => 4,
        units      => 7,
        retail     => 11,
        price      => 14,
        price_type => 15,
    },
    3 => {
        media_type => 2,
        title      => 4,
        upc        => 5,
        units      => 8,
        retail     => 12,
        price      => 15,
        price_type => 16,
    },
    4 => {
        media_type => 2,
        title      => 3,
        upc        => 5,
        units      => 8,
        retail     => 12,
        price      => 15,
        price_type => 16,
    },
);

#public methods

sub _importLines {
    my $self    = shift;
    my %args    = @_;
    my $version = $self->_version();
    my $sheets  = $args{sheets};

    my $fileObj  = $args{file};
    my $fileName = $fileObj->OrigFileName;

    # for cmd-line testing
    #my $fileName = $args{OrigFileName};

    my $offsets = $field_map{$version};

    my $prodType = RPS::File::Sale::TYPE_ALBUM;

    my @billTo = RPS::Import::WMG::Util::getWirelessBillto( $self->{fileServiceID} );
    if ( $billTo[0] ) {
        unless ( RPS::Import::WMG::Util::getWirelessSellto( $self->{fileServiceID}, $billTo[0] ) ) {
            $self->warning();
            print STDERR "unknown sellto mapping: $billTo[0]\n";
        }
    } else {
        $self->warning();
        print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
    }

    my ( $dateBegin, $dateEnd ) = $self->_getDates($fileName);

    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("couldn't get dates");
        print STDERR "file: $fileName\n";
        return 0;
    }

    my $linenum = 1;
    my $i       = 0;
    my %errors  = ();

    foreach my $sheet (@$sheets) {
        next unless ( $sheet->[0][0] =~ /distributor/i && $sheet->[0][2] =~ /media/i );

        foreach my $line (@$sheet) {
            my $title     = $line->[ $offsets->{title} ];
            my $upc       = normalize_upc( $line->[ $offsets->{upc} ] );
            my $units     = $self->numeric( $line->[ $offsets->{units} ] );
            my $retail    = $self->numeric( $line->[ $offsets->{retail} ] );
            my $price     = $self->numeric( $line->[ $offsets->{price} ] );
            my $priceType = $line->[ $offsets->{price_type} ];
            my $mediaType = uc $line->[ $offsets->{media_type} ];

            if ( $title && $units && $price ) {
                my $formatID = $media_map{$mediaType};
                unless ( $formatID || $errors{$mediaType} ) {
                    $self->errstr('unknown format');
                    print STDERR "unknown format mapping: $mediaType\n";
                    $errors{$mediaType} = 1;
                }

                $price /= $units if ( $version > 1 );
                my $wRate = $price / $retail;

                my $sale = RPS::Import::SaleRec->new();

                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->formatType($formatID);
                $sale->lineNum($linenum);
                $sale->price($price);    # price is invalid so leave it out (for now)
                $sale->priceType($priceType);
                $sale->productType($prodType);
                $sale->retail($retail);
                $sale->albumName($title);
                $sale->units($units);
                $sale->upc($upc);
                $sale->wholesaleRate($wRate);

                #$args{dumper}($sale); # for cmd-line testing
                $self->_insertSale( sale => $sale );
            }    #else { print STDERR "skip t: $title u: $units p: $price\n" }
            $linenum++;
        }
        $i++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self     = shift;
    my $fileName = lc $_[0];

    my ( $year, $month );
    if ( $fileName =~ m/\D(\d+)\D(\d+)\D\d+/ )    # Integra November Word 07-11-30.xls
    {
        ( $year, $month ) = ( $1, $2 );
    } elsif ( $fileName =~ m/integra\W(\w+)\D+(\d\d)\D/i )    # WMG INTEGRA Dec '07.XLS
    {
        $year  = $2;
        $month = Decode_Month($1);
    }
    return undef unless ( $year && $month );

    $year += 2000 unless ( $year > 1999 );

    return ( sprintf( "%04d-%02d-01", $year, $month ), sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) ) );
}

###
1;    # Play nicely.
###