package RPS::Import::WMG::SprintFTDL;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_isrc);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::WMG::Util;
use base 'RPS::Import::Importer';

my %field_map = (
    9 => {
        track       => 0,
        svc_prod_id => 1,
        units       => 2,
        isrc        => 3,
        retail      => 4,
        cli_prod_id => 6,
        price       => 7,
    },
    10 => {
        track       => 0,
        svc_prod_id => 1,
        units       => 2,
        isrc        => 3,
        cli_prod_id => 5,
        retail      => 6,
        price       => 8,
    },
    11 => {
        track => 0,
        units => 2,
        isrc  => 3,
        price => 4,
    },
    20 => {
        track       => 0,
        svc_prod_id => 1,
        units       => 2,
        isrc        => 3,
        retail      => 5,
        cli_prod_id => 7,
        price       => 8,
    },
);

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $sheets   = $args{sheets};
    my $fileObj  = $args{file};
    my $version  = $self->_version();
    my $fileName = $fileObj->OrigFileName;

    #my $fileName = $args{OrigFileName}; # for cmd-line testing

    my ( $dateBegin, $dateEnd ) = $self->_getDates($fileName);
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("couldn't get dates");
        print STDERR "fileName: $fileName\n";
        return undef;
    }

    my ( $billTo, $sellTo ) = RPS::Import::WMG::Util::getWirelessInfo( $self->{fileServiceID} );
    unless ( $billTo && $sellTo ) {
        $self->warning();
        print STDERR "unknown billto/sellto mapping: $self->{fileServiceID}\n";
    }

    $fileObj->Atomic(1);
    $fileObj->Save();

    my $offsets   = $field_map{$version};
    my $prodType  = RPS::File::Sale::TYPE_TRACK;
    my $format    = RPS::File::Sale::FORMAT_DUALDOWNLOAD;
    my $priceType = RPS::Import::WMG::Util::getWirelessPriceType('dual_download');
    my %errors;
    my $linenum;
    my $i = 0;

    foreach my $sheet (@$sheets) {
        $linenum = 100000 * ( $i + 1 );    # keeps linenum unique for each sheet

        foreach my $line (@$sheet) {
            my $track     = $line->[ $offsets->{track} ];
            my $cliProdID = exists $offsets->{cli_prod_id} ? $line->[ $offsets->{cli_prod_id} ] : '';
            my $svcProdID = exists $offsets->{svc_prod_id} ? $line->[ $offsets->{svc_prod_id} ] : '';
            my $isrc      = $line->[ $offsets->{isrc} ] ne 'PREMIUM DEFAU' ? $line->[ $offsets->{isrc} ] : '';
            my ($units)   = $line->[ $offsets->{units} ] =~ m/^(\d+)$/;
            my ($retail) = exists $offsets->{retail} ? $line->[ $offsets->{retail} ] =~ m/^(\d*\.?\d*)$/ : '';
            my ($price) = $line->[ $offsets->{price} ] =~ m/^(\d*\.?\d*)$/;

            if ( $track && $units && $price =~ m/\d/ ) {
                $isrc =~ s/^\w://;
                $isrc =~ s/\W//g;
                normalize_isrc($isrc) if $isrc;
                $isrc =~ s/^Y//;

                my $ppdRate = $retail ? $price / $retail : '';

                my $sale = RPS::Import::SaleRec->new();

                $sale->productType($prodType);
                $sale->formatType($format);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->serviceProductID($svcProdID);
                $sale->clientProductID($cliProdID);
                $sale->trackName($track);
                $sale->isrc($isrc);
                $sale->units($units);
                $sale->price($price);
                $sale->retail($retail);
                $sale->wholesaleRate($ppdRate);
                $sale->priceType($priceType);
                $sale->lineNum($linenum);

                #$args{dumper}($sale); # for cmd-line testing
                $self->_insertSale( sale => $sale );
            }    #else { print STDERR "skip u: $units p: $price t: $track ($linenum)\n" }
            $linenum++;
        }
        $i++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self     = shift;
    my $fileName = shift;

    my ( $qtr, $year, $monthEnd );
    if ( $fileName =~ m/\D(\d)\w\w.*?qtr\D*?(\d{4})\D/ )    # ... 1st qtr 2006 ....
    {
        ( $qtr, $year ) = ( $1, $2 );
    } elsif ( $fileName =~ m/Q(\d)\D(\d{4})\D/ ) {
        ( $qtr, $year ) = ( $1, $2 );
    } elsif ( $fileName =~ m/\b\w+\W\w+\W(\w+)\D+(\d{4})\D/ ) {
        ( $monthEnd, $year ) = ( $1, $2 );
        $monthEnd = Decode_Month($monthEnd) if $monthEnd;
    }

    return unless ( $year && ( $qtr || $monthEnd ) );

    $monthEnd ||= $qtr * 3;

    return ( sprintf( "%04d-%02d-01", $year, $monthEnd - 2 ),
        sprintf( "%04d-%02d-%02d", $year, $monthEnd, Days_in_Month( $year, $monthEnd ) ) );
}

###
1;    # Play nicely.
###