#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::WMG::WarnerMobile2;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Country;
use Date::Calc qw(Add_Delta_Days Days_in_Month);

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';
use RPS::Import::ServiceMap;

sub _fieldMap {
    {
        dateBegin   => 'B',
        dateEnd     => 'C',
        productType => 'I',
        artistName  => 'D',

        upc  => 'F',
        isrc => 'F',

        albumName => 'E',
        trackName => 'E',

        units => 'Y',
        price => 'AA',
    };
}

sub _unverifiedFieldMap {
    {
        service => 'A',

        #        type        => 'G',
        mediaCode => 'H',
        modelType => 'T',
    };
}

sub _headerIdentifier { ( upc => 'Product' ) }

sub countryCode  { 'US' }
sub currencyCode { 'USD' }

sub saleDates {
    my $self = shift;
    my $startDate;
    my $endDate;

    my $dt = $self->_getByFieldName('dateBegin');

    # transform date (if needed)
    #

    return ( $self->_getDates( date_begin => $dt ) );
}

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('service');

    return Client::Service::DSP_WARNER_MOBILE if ( $service =~ /Magento D2C/i );

    my $id = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unknown service: $service") if ( !$id );

    return $id;
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    if ( $type =~ /^(s|a|ep)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^(p|t|d|dl|ds|dt)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail("Unable to determine product from: $type");
}

sub formatType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');
    my $modelType = $self->_getByFieldName('modelType');

    if ( $mediaCode =~ /^emd$/i ) {
        if ( $modelType =~ /^PayAsYouGo$/i ) {
            return RPS::File::Sale::FORMAT_DOWNLOAD;
        } elsif ( $modelType =~ /^Streaming-AdSupported$/i
            || $modelType =~ /^Streaming-AdSupportedDirect$/i
            || $modelType =~ /^Streaming-Subscription$/i ) {
            return RPS::File::Sale::FORMAT_STREAM;
        }
    } elsif ( $mediaCode =~ /^eMastertone$/i
        || $mediaCode =~ /^UserGenMastertone$/i
        || $mediaCode =~ /^eSMSTone$/i ) {
        return RPS::File::Sale::FORMAT_RINGTONE;
    } elsif ( $mediaCode =~ /^EVD$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $mediaCode =~ /^ENHCD$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }

    $self->fail("Unable to determine format from mediaCode($mediaCode) modelType($modelType)");
}

sub mediaType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');

    if (   $mediaCode =~ /^EMD$/i
        || $mediaCode =~ /^eRingback$/i
        || $mediaCode =~ /^eMastertone$/i
        || $mediaCode =~ /^UserGenMastertone$/i
        || $mediaCode =~ /^eSMStone$/i
        || $mediaCode =~ /^ENHCD$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $mediaCode =~ /^EVD$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    $self->fail("Unable to determine media type from mediaCode($mediaCode)");
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc') || return;
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $upc : undef;
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc') || return;
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $isrc : undef;
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('albumName');
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $name : undef;
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('trackName');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $name : undef;
}

sub price {
    my $price = abs( shift->SUPER::price() );
    return $price;
}

sub units {
    my $self  = shift;
    my $units = $self->SUPER::units() || return;
    my $price = $self->SUPER::price();

    # The 'sign' of the units is driven by the price.
    # If the price is negative, we'll store negative units,
    # regardless of whether the units were positive or negative
    # in the sale file.  Accordingly, the price is always
    # positive.  This ensure that the returns are recorded
    # correctly.
    #
    if ( defined($price) ) {
        return $price < 0 ? abs($units) * -1 : $units;
    } else {
        return $units;
    }
}

sub unitPrice { abs( shift->SUPER::unitPrice ) }

sub _isValidSaleRecord {
    my $self    = shift;
    my $service = $self->_getByFieldName('service');
    return undef if ( !defined $service );
    return $self->SUPER::_isValidSaleRecord();
}

###
1;    # Play nicely.
###