package RPS::Import::WMG::Wireless;

use strict;

use Date::Calc qw(Decode_Month Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_upc normalize_isrc);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::WMG::Util;
use base 'RPS::Import::Importer';

my %field_map = (
    1 => {
        vendor_id  => 3,
        artist     => 4,
        upc        => 5,
        isrc       => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 19,
        price      => 20,
    },
    2 => {
        vendor_id  => 3,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 17,
        price      => 18,
    },
    3 => {
        vendor_id  => 3,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 19,
        price      => 20,
    },
    4 => {
        vendor_id  => 3,
        artist     => 4,
        upc        => 5,
        isrc       => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 17,
        price      => 18,
    },
    5 => {
        vendor_id  => 3,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 17,
        price      => 19,
    },
    6 => {
        vendor_id  => 3,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        retail     => 18,
        price      => 19,
    },
    7 => {
        vendor_id  => 2,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 16,
        price      => 18,
        retail     => 19,
    },
    8 => {
        format     => 5,
        track      => 8,
        trans_type => 10,
        units      => 12,
        retail     => 13,
        price      => 14,
        artist     => 16,
        isrc       => 17,
        upc        => 18,
    },
    9 => {
        vendor_id  => 2,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        retail     => 16,
        units      => 17,
        price      => 19,
    },
    10 => {
        vendor_id  => 2,
        artist     => 4,
        isrc       => 5,
        upc        => 6,
        format     => 12,
        track      => 14,
        trans_type => 15,
        units      => 17,
        price      => 19,
        retail     => 20,
    },
);

# public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $fileObj  = $args{file};
    my $version  = $self->_version;
    my $fileName = $fileObj->OrigFileName;

    # for cmd-line testing
    #my $fileName = $args{OrigFileName};

    # determine which sheet has the details
    my $lines;
    foreach my $sheet ( @{ $args{sheets} } ) {
        if ( $version == 8 ) {
            if ( $sheet->[0][0] eq 'PARTNER_IDENTITY' and $sheet->[0][1] eq 'ACCOUNT' ) {
                $lines = $sheet;
                last;
            }
        } elsif ( $sheet->[0][0] eq 'PRODUCT_INSTANCE_ID' and $sheet->[0][1] eq 'Item Type' ) {
            $lines = $sheet;
            last;
        }
    }
    unless ($lines) {
        $self->errstr("couldn't find data sheet");
        return undef;
    }

    my $offsets = $field_map{$version};
    unless ($offsets) {
        print STDERR "unknown version ($version)\n";
        return undef;
    }

    my $file = $self->_getFileSpecs($fileName);
    return undef unless ( ref $file eq 'HASH' );

    # warner wireless files are atomic
    $self->{fileServiceID} = $file->{serviceID};
    $fileObj->ServiceID( $file->{serviceID} );
    $fileObj->Atomic(1);
    $fileObj->Save();

    my @billTo = RPS::Import::WMG::Util::getWirelessBillto( $self->{fileServiceID} );
    if ( $billTo[0] ) {
        unless ( RPS::Import::WMG::Util::getWirelessSellto( $self->{fileServiceID}, $billTo[0] ) ) {
            $self->warning();
            print STDERR "unknown sellto mapping: $billTo[0]\n";
        }
    } else {
        $self->warning();
        print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
    }

    my $header  = shift @$lines;
    my $linenum = 2;
    my %errors  = ();

    foreach my $line (@$lines) {
        my $prodtype = RPS::File::Sale::TYPE_TRACK;

        my $vendorID = $line->[ $offsets->{vendor_id} ];
        my $artist   = $line->[ $offsets->{artist} ];
        my $upc      = normalize_upc( $line->[ $offsets->{upc} ] );
        $upc = '' unless ( $upc =~ /\d+/ );
        my $isrc      = normalize_isrc( $line->[ $offsets->{isrc} ] );
        my $track     = $line->[ $offsets->{track} ];
        my $units     = $self->numeric( $line->[ $offsets->{units} ] );
        my $price     = $self->numeric( $line->[ $offsets->{price} ] );
        my $retail    = $self->numeric( $line->[ $offsets->{retail} ] );
        my $transType = lc( $line->[ $offsets->{trans_type} ] );

        my $fmt = $line->[ $offsets->{format} ];
        $fmt =~ s/warner//i;
        $fmt = 'voice ringer' if ( $track =~ m/\(voice\s*ringer\)/i );    # UGLY!!

        if ( $units && defined $price && $track ) {
            if ( $version != 3 ) {
                $retail /= $units if ( $version != 7 && $self->{fileServiceID} != Client::Service::DSP_NEXTEL );
                $price /= $units;
            }

            if ( $transType ne 'purchase' ) {
                $price  = abs($price);
                $retail = abs($retail);
                $units *= -1 unless ( $units < 0 );
            }

            my $ppdRate = $retail ? $price / $retail : '';
            my $sale = RPS::Import::SaleRec->new();

            my $format = '';
            unless ( $format = RPS::Import::WMG::Util::getWirelessFormatTypeID($fmt) ) {
                $self->warning();
                print STDERR "unknown format mapping: $fmt\n" unless $errors{$fmt};
                $errors{$fmt} = 1;
            }

            my $priceType = RPS::Import::WMG::Util::getWirelessPriceType($fmt) || '';

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin( $file->{dateBegin} );
            $sale->dateEnd( $file->{dateEnd} );
            $sale->serviceProductID($vendorID);
            $sale->upc($upc);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->wholesaleRate($ppdRate);
            $sale->retail($retail);
            $sale->priceType($priceType);
            $sale->lineNum($linenum);

            #$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale( sale => $sale );
        }    #else { print STDERR "skip: u: $units p: $price a: $artist t: $track ($linenum)\n"; }
        $linenum++;
    }

    $self->warning() if ( keys %errors );
    unshift @$lines, $header;
    return $linenum;
}

#
# Private methods
#

sub _getFileSpecs {
    my $self     = shift;
    my $fileName = shift;
    my ( $serviceID, $formatID );

    #$fileName =~ s/.warner//i;
    my ( $serviceName, $month, $year ) = $fileName =~ /(.+)[\s_-]([a-zA-Z]+)[\s_-]*(\d{2,})/;
    $serviceName =~ s/(.warner)|(wmg.)//i;
    $serviceName =~ s/.(oa|settlements)//i;    # remove decoration
    $year += 2000 if ( $year < 2000 );

    $month = Decode_Month($month);
    unless ( $month && $serviceName ) {
        $self->errstr('bad file name');
        print STDERR "can't parse '$fileName'\n";
        return undef;
    }

    unless ( $serviceID = $self->getServiceID($serviceName) ) {
        $self->errstr('unknown service');
        print STDERR "can't map '$serviceName' to service_id\n";
        return undef;
    }

    return {
        serviceID => $serviceID,
        dateBegin => sprintf( "%d-%02d-01", $year, $month ),
        dateEnd   => sprintf( "%d-%02d-%d", $year, $month, Days_in_Month( $year, $month ) ),
    };
}

###
1;    # Play nicely.
###