package RPS::Import::Xandrie::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'N',
                serviceID    => 'B',
                countryCode  => 'AC',
                dateBegin    => 'G',
                dateEnd      => 'G',
                productType  => 'D',
                formatType   => 'C',
                upc          => 'H',
                albumName    => 'J',
                isrc         => 'O',
                trackNum     => 'Q',
                trackName    => 'L',
                units        => 'X',
                currencyCode => 'Z',
                price        => 'Y',
            },
         },
    };
}

sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _trackArtist => 'M',
                _albumArtist => 'K',
            },
        }
    };
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'Product UPC',
            },
        },
    };
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: $service");
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($name);
    return $oCountry ? $oCountry->alpha2 : undef ;
}

sub saleDates {
    my $self = shift;

    my $dt = $self->_getDateBegin() || '';
    if ( $dt =~ /^(\d{1,2}\/\d{1,2}\/\d{4})/ ) {
        $dt = $1;
    }

    return $self->_getDates( date_begin => $dt );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    if ( $type =~ /^album$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^track$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail( "Unable to determine product_type from: '$type'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^download$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub artistName {
    my $self = shift;

    my $trackArtist = $self->_getByFieldName('_trackArtist') || '';
    my $albumArtist = $self->_getByFieldName('_albumArtist') || '';

    return $self->productType eq RPS::File::Sale::TYPE_TRACK
        ? ( $trackArtist || $albumArtist )
        : $albumArtist;
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }


1;