package RPS::Import::YouTubeRED::v2;

use strict;
use warnings;
use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Country;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

use constant RE_YYYYMM => qr/^(\d{4})(\d{2})$/;

sub _fieldMap {
    my $self = shift;

    my %field_map = (
        2 => {
            dateBegin   => 'I',
            dateEnd     => 'I',
            countryCode => 'J',
            artistName  => 'G',
            upc         => 'F',
            isrc        => 'C',
            trackName   => 'H',
            units       => 'O',
            price       => 'P',
            mediaType   => 'L',
        },
        3 => {
            dateBegin   => 'I',
            dateEnd     => 'I',
            countryCode => 'J',
            artistName  => 'G',
            upc         => 'F',
            isrc        => 'C',
            trackName   => 'H',
            units       => 'P',
            price       => 'R',
            mediaType   => 'L',
        },
        5 => {
            labelName        => 'N',
            countryCode      => 'C',
            dateBegin        => 'B',
            dateEnd          => 'B',
            serviceProductID => 'D',
            artistName       => 'L',
            upc              => 'J',
            albumName        => 'M',
            isrc             => 'I',
            trackName        => 'E',
            units            => 'R',
            price            => 'AA',
            mediaType        => 'O',
        },
    );

    return $field_map{ $self->_version };
}

sub currencyCode      { 'USD' }
sub _headerIdentifier { upc => 'UPC' }
sub productType       { RPS::File::Sale::TYPE_TRACK }
sub formatType        { RPS::File::Sale::FORMAT_STREAM }

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getDateBegin;
    my $dateEnd   = $self->_getDateEnd;

    if ( $dateBegin =~ RE_YYYYMM ) {
        $dateBegin = sprintf "%04d-%02d-%02d", $1, $2, 1;
        $dateEnd   = sprintf "%04d-%02d-%02d", $1, $2, Days_in_Month($1, $2);
    }

    return $self->_getDates( date_begin => $dateBegin, date_end => $dateEnd );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType');
    if ( $type =~ /^audio(?:-visual)?$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $type =~ /^visual$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    $self->fail("Unknown media type $type");
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub serviceProductID {
    my $self = shift;

    my $serviceProductID = $self->_getByFieldName('serviceProductID') || "";
    return !($self->albumName || $self->trackName || $self->isrc || $self->upc) ? $serviceProductID : undef;
}

sub _isValidSaleRecord {
    my $self = shift;

    my $serviceProductID = $self->_getByFieldName('serviceProductID') || "";

    if ($self->units || $self->price) {
        return 1 if ($self->albumName || $self->trackName || $self->artistName || $self->isrc || $self->upc);

        if (!$self->albumName || !$self->trackName || $self->artistName || !$self->isrc || !$self->upc) {
            return 1 if $serviceProductID;
            $self->fail("Missing valid sales data. ");
        }
    }

    return 0;
}

1;