#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::Master::Command::Edit;
use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Track::Track;
use RPS::DB::Item::Track;
use RPS::Master::Form;
use RPS::Master::Command::Show;

use lib '/app/tools/common/lib';
use RSApache::Response::XML;
use RSApache::Response::Redirect;
use Common::FormObject;

use RPS::Command;
use base 'RPS::Command';

sub cmd  { return 'edit'; }
sub area { return 'master'; }

use constant kTemplate => "/app/tools/rps/templates/master/index.xsl";

sub execute {
    my ($self) = @_;

    my $response = $self->SUPER::execute();
    return $response if $response;

    my $masterID = $self->getParam('MasterID');
    my $form = RPS::Master::Form->new( masterID => $masterID );

    if ( $self->getParam('formSubmit') ) {
        if ( $form->assignCGIParams( 'Form', $self->getParams() ) && $form->validate() ) {
            $form->save();

            # We want to change views, so we want to redirect to the Show command now.
            #
            my $successMessage = RPS::Message->new( type => "success", code => Common::FormObject::kSuccessFormSubmit );
            my $showParams = $self->getPassThroughParams();
            $showParams->{MasterID} = $form->masterID();
            $showParams->{msg}      = $successMessage->toString();

            my $command = RPS::Master::Command::Show->new(%$showParams);
            return RSApache::Response::Redirect->new( $command->getRedirect() );
        } else {
            $form->setError(Common::FormObject::kErrFormSubmit);
            $self->addMessageXML( type => "error", code => Common::FormObject::kErrFormSubmit );
        }
    }

    $self->{xml}{Form} = $form;

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );

    return $response;
}

1;