#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::Payee::Command::Main;
use strict;
use warnings;
use Data::Dumper;

use lib '/app/tools/appuser/lib';
use AppUser::User::User;

use lib '/app/tools/rps/lib';
use RPS::Payee::RecentlyViewedPayeeList;
use RPS::ArtistPayee::ArtistPayeeSimple;
use RPS::LabelPayee::LabelPayeeSimple;
use RPS::Publisher::US::PublisherSimple;
use RPS::Publisher::CA::PublisherSimple;
use RPS::DB::Item::Payee;
use RPS::Pagination;

use RPS::Command;
use base 'RPS::Command';

use lib '/app/tools/common/lib';
use Common::Client;
use RSApache::Response::XSLT;

sub cmd  { return 'main'; }
sub area { return 'payee'; }

use constant kTemplate => "/app/tools/rps/templates/payee/index.xsl";

sub execute {
    my ($self) = @_;

    my $response = $self->SUPER::execute();
    return $response if $response;

    $self->{xml}{RecentlyViewed} = RPS::Payee::RecentlyViewedPayeeList->new( user_id => $self->_getUser()->UserID() );

    # Check for publisher area preference for editing and listing
    #
    my $editPublisherArea = Common::Preference::Get("edit_publisher_area");

    if ($editPublisherArea) {
        $self->{xml}{EditPublisherArea} = $editPublisherArea->value();
    }

    my $listPublisherArea = Common::Preference::Get("list_publisher_area");

    if ($listPublisherArea) {
        $self->{xml}{ListPublisherArea} = $listPublisherArea->value();
    }

    my %getArgs;

    # Check for the filter param.
    my $filter = $self->getParam('publisherFilter');
    if ( 'direct' eq $filter ) {
        $getArgs{directOnly} = 1;
    } elsif ( 'admin' eq $filter ) {
        $getArgs{adminOnly} = 1;
    } elsif ( 'agent' eq $filter ) {
        $getArgs{agentOnly} = 1;
    } elsif ( 'hasAgent' eq $filter ) {
        $getArgs{withAgent} = 1;
    } elsif ( 'hasAdmin' eq $filter ) {
        $getArgs{withAdmin} = 1;
    }

    my $payeeType = $self->getParam("payeeType");
    my $page      = $self->getParam("page") || 1;
    my $pageSize  = $self->getParam("pageSize") || 10;

    my $client = Common::Client::Current();

    # Include artist payees if client does artist royalties (also check the payeeType param for the filter)
    if ( $client->isClientType(Common::Client::kArtist) && ( !$payeeType || $payeeType eq 'artist' ) ) {
        $getArgs{artistPayee} = 1;
    }

    # Include CA publishers if client does CA mechanicals
    if ( $client->isClientType(Common::Client::kCAMechanicals) && ( !$payeeType || $payeeType eq 'caPublisher' ) ) {
        $getArgs{caPublisher} = 1;
    }

    # Include US publishers if client does US mechanicals
    if ( $client->isClientType(Common::Client::kUSMechanicals) && ( !$payeeType || $payeeType eq 'publisher' ) ) {
        $getArgs{publisher} = 1;
    }

    # Include label payees if client does label royalties
    if ( $client->isClientType(Common::Client::kLabel) && ( !$payeeType || $payeeType eq 'label' ) ) {
        $getArgs{labelPayee} = 1;
    }

    my $collection = RPS::DB::Item::Payee->Get(%getArgs);

    $collection->setPagination( pageIndex => $page, pageSize => $pageSize );

    $self->{xml}{Pagination} = RPS::Pagination->new(
        total     => $collection->totalSize(),
        recordNum => $collection->{_record},
        pageSize  => $pageSize
    );

    $self->{xml}{PayeeList} = $self->_getPayeeList($collection);

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );
    return $response;
}

sub _getPayeeList {
    my ( $self, $collection ) = @_;

    my $list->{Item} = [];

    while ( $collection->hasNext() ) {
        my $obj = $collection->next();
        my $payeeItem;

        if ( $obj->artist_payee_id ) {
            $payeeItem->{ArtistPayee} = RPS::ArtistPayee::ArtistPayeeSimple->new( artistPayeeID => $obj->artist_payee_id, loadSubs => 0 );
        } elsif ( $obj->ca_publisher_id ) {
            $payeeItem->{CAPublisher} = RPS::Publisher::CA::PublisherSimple->new( publisherID => $obj->ca_publisher_id, loadSubs => 0 );
        } elsif ( $obj->publisher_id ) {
            $payeeItem->{Publisher} = RPS::Publisher::US::PublisherSimple->new( publisherID => $obj->publisher_id, loadSubs => 0 );
        } elsif ( $obj->label_payee_id ) {
            $payeeItem->{LabelPayee} = RPS::LabelPayee::LabelPayeeSimple->new( labelPayeeID => $obj->label_payee_id, loadSubs => 0 );
        }

        push @{ $list->{Item} }, $payeeItem;
    }

    return $list;
}

1;