<!--                                                                  -->
<!--  Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved     -->
<!--  $Id$  -->
<!--                                                                  -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:dyn="http://exslt.org/dynamic"
    xmlns:set="http://exslt.org/sets" extension-element-prefixes="dyn set">

    <xsl:template name="regionEditLayout">
        <div class="MainBaseSection">
            <script type="text/javascript" src="/production/javascript/validateRegion.js" />
            <form name="regionEdit" id="regionEdit" method="post" action="region">
                <xsl:call-template name="regionEdit" />
                <xsl:call-template name="buttons" />
            </form>
        </div>
    </xsl:template>

    <xsl:template name="regionEdit">
        <xsl:call-template name="successMessageGeneral">
            <xsl:with-param name="successMessage">Region successfully created!</xsl:with-param>
        </xsl:call-template>
        <xsl:if test="Params/_inline">
            <input type="hidden" name="_inline" value="1" />
        </xsl:if>
        <xsl:call-template name="openRunStatusMessage" />
        <xsl:if test="not(normalize-space(Form/Region/RegionID))">
            <input type="hidden" name="ReturnTo" id="ReturnTo" />
        </xsl:if>
        <input type="hidden" name="formSubmit" value="1" />
        <input type="hidden" name="c" value="edit" />
        <xsl:if test="normalize-space(Form/Region/RegionID)">
            <input type="hidden" name="RegionID" value="{Form/Region/RegionID}" />
        </xsl:if>
        <p class="User-edit-subheader">
            Enter region information here.
            <span class="Required-notice"/>
        </p>
        <xsl:call-template name="errorMessageGeneral" />
        <xsl:call-template name="columnEdit" />
    </xsl:template>

    <xsl:template name="columnEdit">
        <fieldset class="User-edit-fieldset">
            <div class="Form-item Form-item-required">
                <label class="Form-label">
                    <span class="Form-label-caption">Region</span>
                    <div class="Form-input-wrapper">
                        <input type="text" class="Input Form-input" name="Form_Region_Name" id="Form_Region_Name" value="{Form/Region/Name}">
                            <xsl:if test="$openRuns = 1">
                                <xsl:attribute name="disabled">disabled</xsl:attribute>
                            </xsl:if>
                        </input>
                        <xsl:call-template name="inlineError">
                            <xsl:with-param name="path">Form/Region/Name</xsl:with-param>
                            <xsl:with-param name="displayName">Region</xsl:with-param>
                        </xsl:call-template>
                    </div>
                </label>
            </div>
            <div class="Form-item">
                <label class="Form-label">
                    <span class="Form-label-caption">Description</span>
                    <div class="Form-input-wrapper">
                        <textarea class="Input Form-input" rows="4" cols="40" name="Form_Region_Description">
                            <xsl:if test="$openRuns = 1">
                                <xsl:attribute name="disabled">disabled</xsl:attribute>
                            </xsl:if>
                            <xsl:value-of select="Form/Region/Description" />
                        </textarea>
                    </div>
                </label>
            </div>
        </fieldset>
        <fieldset class="User-edit-fieldset User-edit-fieldset-dualselect">
            <div class="Form-item Form-item-required">
                <label class="Form-label">
                    <span class="Form-label-caption">Countries</span>
                    <div class="Form-input-wrapper">
                        <xsl:variable name="selectCountriesAvailable">
                            <map>
                                <xsl:for-each select="Form/CountryList/Country">
                                    <mapEntry>
                                        <name><xsl:value-of select="Name" /> (<xsl:value-of select="CountryCode" />)</name>
                                        <value><xsl:value-of select="CountryCode"/></value>
                                    </mapEntry>
                                </xsl:for-each>
                            </map>
                        </xsl:variable>
                        <xsl:variable name="selectCountriesSelected">
                            <map>
                                <xsl:for-each select="Form/Region/CountryList/Country">
                                    <mapEntry>
                                        <name><xsl:value-of select="CountryName" /> (<xsl:value-of select="CountryCode" />)</name>
                                        <value><xsl:value-of select="CountryCode"/></value>
                                    </mapEntry>
                                </xsl:for-each>
                            </map>
                        </xsl:variable>
                        <xsl:call-template name="uiDualSelect">
                            <xsl:with-param name="name" select="'Form_Region_CountryList_CountryCodes'"/>
                            <xsl:with-param name="label" select="'Countries'"/>
                            <xsl:with-param name="itemsAvailable" select="$selectCountriesAvailable"/>
                            <xsl:with-param name="itemsSelected" select="$selectCountriesSelected"/>
                            <xsl:with-param name="disabled">
                                <xsl:if test="$openRuns = 1">
                                    <xsl:text>true</xsl:text>
                                </xsl:if>
                            </xsl:with-param>
                        </xsl:call-template>
                    </div>
                </label>
                <xsl:call-template name="inlineError">
                    <xsl:with-param name="path">Form/Region/CountryList/CountryCodes</xsl:with-param>
                    <xsl:with-param name="displayName">Countries</xsl:with-param>
                </xsl:call-template>
            </div>
        </fieldset>
    </xsl:template>

</xsl:stylesheet>
