<!--                                                                  -->
<!--  Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved     -->
<!--  $Id$  -->
<!--                                                                  -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:dyn="http://exslt.org/dynamic" extension-element-prefixes="dyn">

    <xsl:template name="advanceLayout">
        <script type="text/javascript" src="/production/javascript/validateAdvance.js?t={$now}" />
        <form name="contractAdvance" id="contractAdvance" method="post" action="{$area}">
            <xsl:call-template name="advanceEdit" />
            <xsl:call-template name="buttons" />
        </form>
    </xsl:template>

    <xsl:template name="advanceEdit">
        <div class="AdvanceLayout">
            <input type="hidden" name="formSubmit" value="1" />
            <input type="hidden" name="c" value="advance" />

            <xsl:if test="Params/TrackContractID">
                <input type="hidden" name="TrackContractID" value="{Params/TrackContractID}" />
            </xsl:if>
            <xsl:if test="Params/AlbumContractID">
                <input type="hidden" name="AlbumContractID" value="{Params/AlbumContractID}" />
            </xsl:if>
            <xsl:if test="Params/AdvanceID">
                <input type="hidden" name="AdvanceID" value="{Params/AdvanceID}" />
            </xsl:if>
            <xsl:if test="Params/PublisherID">
                <input type="hidden" name="PublisherID" value="{Params/PublisherID}" />
            </xsl:if>

            <xsl:if test="$area = 'catalog'">
                <section class="PageSection">
                    <xsl:call-template name="albumView" />
                </section>
            </xsl:if>
            <xsl:if test="$area = 'publisher'">
                <section class="PageSection">
                    <xsl:call-template name="publisherView">
                        <xsl:with-param name="publisher" select="Form/Publisher" />
                    </xsl:call-template>
                </section>
            </xsl:if>
            <xsl:if test="$area = 'track'">
                <section class="PageSection">
                    <xsl:call-template name="trackView">
                        <xsl:with-param name="track" select="Form/Track" />
                        <xsl:with-param name="albumTitle" select="Form/Album/Title" />
                    </xsl:call-template>
                </section>
            </xsl:if>

            <section class="PageSection">
                <xsl:call-template name="advanceEditSection" />
            </section>

            <xsl:if test="Params/AdvanceID">
                <section class="PageSection">
                    <xsl:call-template name="transactionHistory" />
                </section>
            </xsl:if>

        </div>
    </xsl:template>

    <xsl:template name="advanceEditSection">
        <h3>Advance</h3>
        <xsl:call-template name="errorMessageGeneral" />
        <div class="Form-header">
            <p>Enter advance information here.</p>
            <span class="Required-notice" />
        </div>

        <fieldset class="Form-fieldset Form-fieldset-standart">
            <xsl:if test="Params/AdvanceID">
                <ul class="Form-item ValuePair">
                    <li class="ValuePair-item">
                        <span class="ValuePair-label">Advance Balance:</span>
                        <span class="ValuePair-value">
                            <xsl:call-template name="formatDollars">
                                <xsl:with-param name="dollarAmount" select="//AdvanceAccount/Balance" />
                            </xsl:call-template>
                        </span>
                    </li>
                </ul>
            </xsl:if>

            <div class="Form-item">
                <xsl:attribute name="class">
                    <xsl:text>Form-item Form-item-required</xsl:text>
                    <xsl:if test="Form/Advance[@e]">
                        <xsl:text> Form-item-error</xsl:text>
                    </xsl:if>

                </xsl:attribute>
                <label class="Form-label">
                    <span class="Form-label-caption">Add Advance</span>
                    <div class="Form-input-wrapper">
                        <input name="Form_Advance" class="Input Form-input dollarField" id="Form_Advance" type="text" value="{Form/Advance}" />
                    </div>
                </label>
                <xsl:call-template name="inlineError">
                    <xsl:with-param name="path">Form/Advance</xsl:with-param>
                    <xsl:with-param name="displayName">Advance</xsl:with-param>
                </xsl:call-template>
            </div>

            <div class="Form-item">
                <label class="Form-label">
                    <span class="Form-label-caption">Memo</span>
                    <div class="Form-input-wrapper">
                        <textarea class="Form-input Input Input-textarea" rows="4" cols="40" name="Form_Memo"><xsl:value-of select="Form/Memo" /><xsl:value-of select="Form/Memo" /></textarea>
                    </div>
                </label>
            </div>
        </fieldset>
    </xsl:template>

    <xsl:template name="transactionHistory">
        <h3>
            <span class="CollapseTrigger" onClick="showDetails(this,'transactionHistory');" onMouseOver="javascript:window.status=''; return true;">
                <span class="CollapseTrigger-icon">
                    <xsl:call-template name="icon">
                        <xsl:with-param name="type" select="'arrow-down'" />
                    </xsl:call-template>
                </span>
                Transaction History
            </span>
        </h3>
        <table class="Table Table-with-highlight" id="transactionHistory" style="display:none">
            <thead>
                <tr class="Table-row Table-row-header">
                    <th class="Table-col">Date</th>
                    <th class="Table-col">Memo</th>
                    <th class="Table-col Table-col-amount">Amount</th>
                    <th class="Table-col Table-col-amount">Balance</th>
                </tr>
            </thead>
            <tbody>
                <xsl:for-each select="//AdvanceAccount/TransactionList/Transaction">
                    <tr class="Table-row Table-row-data">
                        <td class="Table-col"><xsl:value-of select="Date" /></td>
                        <td class="Table-col">
                            <xsl:call-template name="replaceLineBreak">
                                <xsl:with-param name="string" select="Memo"/>
                            </xsl:call-template>
                        </td>
                        <td class="Table-col Table-col-amount">
                            <xsl:call-template name="formatDollars">
                                <xsl:with-param name="dollarAmount" select="Amount" />
                            </xsl:call-template>
                        </td>
                        <td class="Table-col Table-col-amount">
                            <xsl:call-template name="formatDollars">
                                <xsl:with-param name="dollarAmount" select="Balance" />
                            </xsl:call-template>
                        </td>
                    </tr>
                </xsl:for-each>
            </tbody>
        </table>
    </xsl:template>

</xsl:stylesheet>


