'==========================================================================
'
' NAME: Schtask-AD_Auto_SRV_OnBoarding-1.0.0-M-R1-DEV.vbs
'
' AUTHOR:  Max Erenburg
' DATE  : 5/27/2020
'
' COMMENT: This script will verify corp. connectivity and if exists proceed to run automation script prescribed.
' 	Utilized this for any debug / QA testing (line 136 commented out to all run on a host other than a DC only for debug testing)
' 
'==========================================================================

Option Explicit

Dim vDate, vTime, altTime, altDate, vDateTime
vDateTime = Now

Dim oShell, oFSO, oProcessEnv, sScript, iErrCode, sMsg
Dim sDebug, sDebugBlat, sSuccess, sPilot
Dim sMailbox1, sMailbox2, sRelayHost, sCN, sFQDN, sTry
Dim sSrcRoot, sSystem32, sLogDir, sScriptsDir, sEmailDir, sDebugLog
Dim sDomFQDN, sLib, sBlat, sEngKey
Dim sCoreBlat, sCoreBlat2, sCoreWMI, sCoreInfo, sCoreInfo2, sCoreInfo3, DebugLog
Dim oWMI, sWMIFailed, sWMIMsgBody2
Dim ProductName, IsServer, IsServerCore, CBVer, CSDver, s64Bit, DC, sPBV, PBV, sPTV, PTV
Dim description, address, subnet, subnetmask

Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oProcessEnv = oShell.Environment("PROCESS")

' Packager's defined variable's
Const DEPLOYNAME = "AD_Auto_SRV_OnBoarding-1.0.0"
Const SIDE = "-M"
Const RELEASE = "-R1-DEV"
sScript = "Schtask-" & DEPLOYNAME & SIDE & RELEASE

sDebug = "False" : sDebugBlat = "False"
sSuccess = "False" ' Set to False if you dont want success emails. ' For enterprise deployment set to false, for one of installations leave as True
sPilot = "False" ' Set to False if you dont want attachment of debug file to success emails. ' Use for QA/UAT, once ready for Production deployments set to False

sMailbox1 = "merenburg@theorchard.com" : sMailbox2 = ""
sRelayHost = "smtp-relay.gmail.com"
sCN = oProcessEnv("COMPUTERNAME")
sFQDN = "@TheOrchard.com"
sTry = "2"

sSrcRoot = Replace(WScript.ScriptFullName, WScript.ScriptName, "")
sSystem32 = oProcessEnv("SYSTEMROOT") & "\system32\"
sLogDir = oProcessEnv("SYSTEMROOT") & "\EngLogs"
sScriptsDir = sLogDir & "\Scripts"
sEmailDir = sLogDir & "\Email"
sDebugLog = sScriptsDir & "\" & sScript & ".log"

sBlat = sSystem32 & "blat.exe"
sEngKey = "HKLM\SOFTWARE\ORCDENG\"

' Initialize WMI connection to cimv2
On Error Resume Next 
Set oWMI = GetObject("winmgmts:\\.\root\cimv2")
If Err.Number <> 0 Then
	iErrCode = Err.Number
	sWMIFailed = "Failed"
	sWMIMsgBody2 = Now & "__ Script was unable to successfully connect to cimv2, Error code: " & iErrCode & ", installations are dependent on WMI being healthy, cannot proceed."
End If
On Error GoTo 0

sMsg = "Scriptname: " & WScript.ScriptName
sMsg = sMsg & "|ScriptPath: " & WScript.ScriptFullName

' Ensure email alerts are available
Call CopyBlat

' Create directory(s) for local centralized logging
Call CreateLogDirs

' Create debug log or append to log if this script has been run before
Call CreateDebugLog("FirstCheck")

' Get what OS, CSD version are we working with
Call GetOSInfo
If s64Bit = "0" Then WSHLog "CriticalFailure", "This script does not support 32 bit OS."

' Get OS install date
Call GetOSInstDate

If sWMIFailed = "Failed" Then 'fail with hard error as we need WMI up and running (health to perform installs, etc..)
	If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
	WSHLog "CriticalFailure", sWMIMsgBody2
End If

' Get Nic information we are working with
Call GetNetworkInterface

' Check if DC Function
Call IsDC

Dim sConnectivity
Call CheckConnectivity
If sConnectivity = "Established" Then
	' Get Domain Name we are working with so we dont have to have additional copies of same script per AD Forest/Domain.
	Call GetDomainName
	sLib = "\\" & sDomFQDN & "\netlogon\lib\"

	' Based on asset classification, run next scripts
	Call ExecNextScripts
End If

If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Wrapper execution complete, total execution time: " & DateDiffToWords(vDateTime,Now))
WSHLog "Information", "Wrapper execution complete, total execution time: " & DateDiffToWords(vDateTime,Now)

' Log/email exit code, cleanup and exit
If Not (IsNull(iErrCode) Or IsEmpty(iErrCode)) Then
	If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
	DebugLog.WriteLine(Now & "__ Exiting... Wrapper exit code : " & iErrCode)
	If (sSuccess = "True") And (sPilot = "False") And (sCoreBlat = "") Then Email sScript & "  Status", "Wrapper exit code : " & iErrCode & "||" & sMsg
	Call Cleanup(sScript & "  Status", "Wrapper exit code : " & iErrCode & "||" & sMsg)
	WScript.Quit(iErrCode)
Else
	If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Exiting... Wrapper exit code  : " & Err.Number)
	If (sSuccess = "True") And (sPilot = "False") And (sCoreBlat = "") Then Email sScript & "  Status", "Wrapper exit code  : " & Err.Number & "||" & sMsg
	Call Cleanup(sScript & "  Status", "Wrapper exit code  : " & Err.Number & "||" & sMsg)
	WScript.Quit
End If

' ------   Packager's defined Functions/Subs section    -------

' Based on asset classification, run next script(s)
Function ExecNextScripts
	Dim safety : safety = 0
	If Not (IsServer = "True") Then
		safety = 1
	Else
		''' Remarked in order to be able to run on an asset that is not a DC.
		'If Not (DC = "True") Then
		'	safety = 1
		'Else
			Call ExecScript("DC", "Automation\AD-Auto-SRV-OnBoarding-v2-DEV.ps1")
		'End If
	End If
	If safety = 1 Then
		If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
		DebugLog.WriteLine(Now & "__ Found attempt made to run the script from an asset other than a DC")
		WSHLog "CriticalFailure", "Found attempt made to run the script from an asset other than a DC"
	End If
End Function

Sub ExecScript(sClass, sNSN)
	On Error Resume Next
	Dim sCMD, vCT, iStat, iErrDesc
	sCMD = "\\" & sDomFQDN & "\netlogon\DC\" & sNSN
	If Not oFSO.FileExists(sCMD) Then
		If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
		DebugLog.WriteLine(Now & "__ Script " & sCMD & " doesnt exist to execute.")
		WSHLog "Warning", "Script " & sCMD & " doesnt exist to execute."
	Else
		If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Executing" & sCMD)
		vCT = Now
		iStat = CreateObject("WScript.Shell").Run("powershell.exe " & Chr(34) & sCMD  & Chr(34), 1, True)
		If iStat = 0 Then
			If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Execution completed, exit code: " & iStat & ", total execution time: " & DateDiffToWords(vCT,Now))
		Else
			iErrCode = iStat
			iErrDesc = CStr(iStat) & " " & Err.Description & "."
			If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
			DebugLog.WriteLine(Now & "__ Execution of " & sCMD & ", FAILED. Result code: " & iErrDesc)
			WSHLog "Warning", "Execution of " & sCMD & ", FAILED. Result code: " & iErrDesc
		End If
	End If
	On Error GoTo 0
End Sub

' Check Connectivity to Domain Netlogon share
Function CheckConnectivity
	On Error Resume Next
	Dim sDN, DNKey, iErrDesc
	sDN = "HKLM\SYSTEM\CurrentControlSet\services\Tcpip\Parameters\Domain"
	DNKey = GetRegData(sDN, "{default}")
	If DNKey = "{default}" Then
		If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
		iErrCode = "53"
		DebugLog.WriteLine(Now & "__ Failed to read/obtain value for domain name from reg key: " & sDN & ". Cannot proceed.")
		WSHLog "Warning", "Failed to read/obtain value for domain name from reg key: " & sDN & ". Cannot proceed."
		sConnectivity = "Failed"
		Exit Function
	End If
	
	Dim sPath, oFolder
	sPath = "\\" & DNKey & "\netlogon"
	Set oFolder = oFSO.GetFolder(sPath)
	If Err.Number = 0 Then
		If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Testing access to" & sPath & " was successful.")
		If sDebug = "True" Then
			WSHLog "Information", "Testing access to" & sPath & " was successful."
		End If
		sConnectivity = "Established"
	Else
		iErrCode = Err.Number
		iErrDesc = CStr(Err.Number) & " " & Err.Description & "."
		If sDebug = "True" Then
			If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
			DebugLog.WriteLine(Now & "__ Testing our access to " & sPath & " was unsuccessful. Error code: " & iErrDesc & ".")
			WSHLog "Warning", "Testing our access to " & sPath & " was unsuccessful. Error code: " & iErrDesc & "."
		End If
		sConnectivity = "Failed"
	End If
	On Error GoTo 0
End Function

' ------   Wrapper 3.0.6 Functions/Subs section    -------

Function GetOSInstDate
	On Error Resume Next
	Dim dtmInstallDate, colOS, oOS, OSInstDate
	Set dtmInstallDate = CreateObject("WbemScripting.SWbemDateTime")
	Set colOS = oWMI.ExecQuery("SELECT InstallDate FROM Win32_OperatingSystem")
	For Each oOS in colOS
		dtmInstallDate.Value = oOS.InstallDate
		OSInstDate = dtmInstallDate.Month & "/" & dtmInstallDate.Day & "/" & dtmInstallDate.Year
	Next
	sMsg = sMsg & "|" & "OS Install Date: " & OSInstDate & "."
	On Error GoTo 0
End Function		

' Get what OS, CSD version are we working with
Function GetOSInfo
	On Error Resume Next
	Dim sPN, sId, sCSDVer
	sPN = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName"
	ProductName = GetRegData(sPN, "{default}")
	If ProductName = "{default}" Then
		iErrCode = "53"
		DebugLog.WriteLine(Now & "__ GetOSInfo function failed to read reg Key: " & sPN)
		WSHLog "CriticalFailure", "GetOSInfo function failed to read reg Key: " & sPN
	ElseIf ProductName = "" Then
		iErrCode = "53"
		DebugLog.WriteLine(Now & "__ GetOSInfo- function found a Null value in reg Value: " & sPN)
		WSHLog "CriticalFailure", "GetOSInfo- function found a Null value in reg Value: " & sPN
	End If
	If InStr(UCase(ProductName), "SERVER") Then
		IsServer = "True"	
		If Not oFSO.FileExists(oProcessEnv("SYSTEMROOT") & "\explorer.exe") Then
			IsServerCore = "True"
		End If
	ElseIf InStr(UCase(ProductName), "WINDOWS 10") Then
		sId = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ReleaseId"
		CBVer = GetRegData(sId, "{default}")
		If CBVer = "{default}" Then
			iErrCode = "53"
			DebugLog.WriteLine(Now & "__ GetOSInfo function on Windows 10 failed to read reg Key: " & sId)
			WSHLog "CriticalFailure", "GetOSInfo function on Windows 10 failed to read reg Key: " & sId
		ElseIf ProductName = "" Then
			iErrCode = "53"
			DebugLog.WriteLine(Now & "__ GetOSInfo- function on Windows 10 found a Null value in reg Value: " & sId)
			WSHLog "CriticalFailure", "GetOSInfo- function on Windows 10 found a Null value in reg Value: " & sId
		End If
	End If
	sCSDVer = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CSDVersion"
	CSDver = GetRegData(sCSDVer, "{default}")
	If CSDver = "{default}" Then CSDver = "RTM"
	s64Bit = "0"
	If oFSO.FileExists(oProcessEnv("SYSTEMROOT") & "\SysWOW64\wscript.exe") Then
		s64Bit = "1"
	End If
	' Check if corp build
	sPBV = sEngKey & "Build\BuildVersion"
	sPTV = sEngKey & "Build\DeployTSVersion"
	PBV = GetRegData(sPBV, "{default}")
	PTV = GetRegData(sPTV, "{default}")
	If PBV = "{default}" OR PBV = "" Or IsEmpty(PBV) Or IsNull(PBV) Then PBV = "Non-Corp"
	If PTV = "{default}" Or PTV = "" Or IsEmpty(PTV) Or IsNull(PTV) Then PTV = "No value"
	If InStr(UCase(ProductName), "10") Then
		sMsg = sMsg & "|Hostname: " & sCN & "|OS: " & ProductName & ", CB: " & CBVer & "|BuildVer: " & PBV & "|DeployTSVer: " & PTV & "." ' Do not remove this last & "." otherwise it wraps
	Else
		sMsg = sMsg & "|Hostname: " & sCN & "|OS: " & ProductName & ", " & CSDver & "|BuildVer: " & PBV & "|DeployTSVer: " & PTV & "." ' Do not remove this last & "." otherwise it wraps
	End If
	On Error GoTo 0
End Function

' Read Registry Key/Values Function
Function GetRegData(sRegKey, vDefault)
	On Error Resume Next
	Dim vReturn
	vReturn = oShell.RegRead(sRegKey)
	If Err.Number <> 0 Then
		GetRegData = vDefault
		Err.Clear
	Else
		GetRegData = vReturn
	End If
	On Error GoTo 0
End Function

' Get Network Interface
Function GetNetworkInterface
	On Error Resume Next
	If sWMIFailed = "Failed" Then
		sMsg = sMsg & "|Ethernet Adapter: (WMI not available) |IP address: (WMI not available) |Subnet Mask: (WMI not available)"
	Else
		Dim Adapters, Adapter, i, period, prevperiod, addressbyte, addressbytes(4)
		Dim subnetmaskbyte, subnetmaskbytes(4)
		Set Adapters = oWMI.ExecQuery("SELECT DefaultIPGateway, Description, IPAddress, IPSubnet FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled=TRUE")
		If Err.Number = 0 Then
			For Each Adapter In Adapters
				If Not IsNull(Adapter.DefaultIPGateway) Then
					If Not IsNull(Adapter.IPAddress) Then
						description = Adapter.Description
						address = Adapter.IPAddress(0)
						subnet = Adapter.IPSubnet(0)
						subnetmask = Adapter.IPSubnet(0)
						i = 0
						period = 1
						While period <> Len(address) + 2
							prevperiod = period
							period = InStr(period + 1, address, ".") + 1
							If period = 1 Then period = Len(address) + 2
							addressbyte = Mid(address, prevperiod, period-prevperiod - 1)
							addressbytes(i) = addressbyte
							i = i + 1
						Wend
						i = 0
						period = 1
						While period <> Len(subnet) + 2
							prevperiod = period
							period = Instr(period + 1, subnet, ".") + 1
							If period = 1 Then period = Len(subnet) + 2
							subnetmaskbyte = Mid(subnet, prevperiod, period-prevperiod - 1)
							subnetmaskbytes(i) = subnetmaskbyte
							i = i + 1
						Wend
						subnet = ""
						For i = 0 to 3
							subnet = subnet & (addressbytes(i) AND subnetmaskbytes(i)) & "."
						Next
						subnet = Left(subnet, Len(subnet)-1)
					End If
				End If
			Next
'		Else
'			WSHLog "Failure", "Critical issue, could not connect to WMI, cimv2:Win32_NetworkAdapterConfiguration to obtain Network Adapter Configuration."
		End If
		sMsg = sMsg & "|Ethernet Adapter: " & description & ".|IP address: " & address & "|Subnet Mask: " & subnetmask ' do not remove the dot in ".|IP address" otherwise it wraps
		Set Adapters = Nothing
	End If
	On Error GoTo 0
End Function

' Check if DC Function 
Function IsDC
	On Error Resume Next
	Dim DeviceInfo, oDomain
	Set DeviceInfo = oWMI.ExecQuery("SELECT DomainRole FROM Win32_ComputerSystem")
	If Err.Number = 0 Then
		For Each oDomain In DeviceInfo 
			If oDomain.DomainRole = 4 Or oDomain.DomainRole = 5 Then DC = "True"
		Next
	Else
		WSHLog "CriticalFailure", "Critical issue, could not connect to WMI, cimv2:Win32_ComputerSystem to obtain DomainRole information."
	End If
	Set DeviceInfo = Nothing
	On Error GoTo 0
End Function

' Get ID of who is running the script, as well as who is logged on (if anyone) Function
Function GetWhoIsRunningScript
	On Error Resume Next
	If sWMIFailed = "Failed" Then
		sMsg = sMsg & "|Script was executed utilizing account: (WMI not available) "
		sMsg = sMsg & "|Following account(s) are logged on during execution of script: (WMI not available) "
	Else
		Dim cProcessList, oProcess, cProperties, sNameOfUser, sUserDomain
		Set cProcessList = oWMI.ExecQuery("SELECT CommandLine,Name FROM Win32_Process WHERE " & "Name = 'cscript.exe' or Name = 'wscript.exe'")
		For Each oProcess in cProcessList
			If InStr(oProcess.CommandLine, Wscript.ScriptFullName) Then
				cProperties = oProcess.GetOwner(sNameOfUser,sUserDomain)
			End If
		Next
		If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Script was executed utilizing account: " & sUserDomain & "\" & sNameOfUser)
		sMsg = sMsg & "|Script was executed utilizing account: " & sUserDomain & "\" & sNameOfUser & "."	
	
		Dim cCS, oCS, LoggedInUser
		Set cCS = oWMI.ExecQuery("SELECT UserName FROM Win32_ComputerSystem")
		LoggedInUser = "NOONE"
		For Each oCS in cCS
			LoggedInUser = oCS.UserName
		Next
		If IsNull(LoggedInUser) Then
			If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Script detected the following account(s) are logged on during start of installation: No Logon detected")
			sMsg = sMsg & "|Following account(s) are logged on during execution of script: No Logon detected"
		Else
			If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Script detected the following account(s) are logged on during start of installation: " & LoggedInUser)
			sMsg = sMsg & "|Following account(s) are logged on during execution of script: " & LoggedInUser
		End If
	End If
	On Error GoTo 0
End Function

' Creates Corporate Engineering debug log (or append to existing log if run before) Function
Function CreateDebugLog(sCondition)
	If sCondition = "WriteLog" Then
		Call CreateDebugLogNow
	Else
		If (sCoreBlat <> "" Or sCoreBlat2 <> "" Or sCoreWMI <> "" Or sCoreInfo <> "" Or sCoreInfo2 <> "" Or sCoreInfo3 <> "") Then
			Call CreateDebugLogNow
		End If
	End If
End Function

Sub CreateDebugLogNow
	On Error Resume Next
	Const ForReading = 1 : Const ForWriting = 2 : Const ForAppending = 8
	Dim iErrDesc
	If NOT oFSO.FileExists(sDebugLog) Then
		Set DebugLog = oFSO.OpenTextFile(sDebugLog, ForWriting, True)
		If Err.Number <> 0 Then
			iErrCode = Err.Number
			iErrDesc = CStr(Err.Number) & " " & Err.Description & "."
			Call GetWhoIsRunningScript
			WSHLog "CriticalFailure", "Attempt to create Debuglog: " &  sDebugLog & ", failed. Error code: " & iErrDesc
		End If
	Else ' Append to existing log
		Set DebugLog = oFSO.OpenTextFile(sDebugLog, ForAppending, True)
		If Err.Number <> 0 Then
			iErrCode = Err.Number
			iErrDesc = CStr(Err.Number) & " " & Err.Description & "."
			Call GetWhoIsRunningScript
			WSHLog "CriticalFailure", "Attempt to append to Debuglog: " &  sDebugLog & ", failed. Error code: " & iErrDesc
		Else
			DebugLog.WriteLine(" ")
		End If
	End If
	WSHLog "Information", "Commencing execution of " & DEPLOYNAME & SIDE & RELEASE
	DebugLog.WriteLine(Now & "__ Commencing installation of " & DEPLOYNAME & SIDE & RELEASE & " on " & oProcessEnv("COMPUTERNAME"))
	DebugLog.WriteLine(Now & "__ Script/Path utilized: " & Wscript.ScriptFullName)
	If sCoreBlat <> "" Then	DebugLog.WriteLine(sCoreBlat)
	If sCoreBlat2 <> "" Then DebugLog.WriteLine(sCoreBlat2)
	If sCoreWMI <> "" Then DebugLog.WriteLine(sCoreWMI)
	If sCoreInfo <> "" Then DebugLog.WriteLine(sCoreInfo)
	If sCoreInfo2 <> "" Then DebugLog.WriteLine(sCoreInfo2)
	If sCoreInfo3 <> "" Then DebugLog.WriteLine(sCoreInfo3)
	Call GetWhoIsRunningScript
	On Error GoTo 0
End Sub

' Creates Corporate Engineering Logs directory(s) for script, package installation, and custom logging if they do not exist
Function CreateLogDirs
	If Not oFSO.FolderExists(sLogDir) Then Call CreateLogDir(sLogDir)
	If Not oFSO.FolderExists(sScriptsDir) Then Call CreateLogDir(sScriptsDir)
	If Not oFSO.FolderExists(sEmailDir) Then Call CreateLogDir(sEmailDir)
End Function

' Create Log directory's requested 
Sub CreateLogDir(sDir)
	On Error Resume Next
	Dim iErrDesc
	oFSO.CreateFolder(sDir)
	If Err.Number = 0 Then
		WSHLog "Success", sDir & " directory Created."
		If sDir = sLogDir Then sCoreInfo = Now & "__ " & sLogDir & " directory Created."
		If sDir = sScriptsDir Then sCoreInfo2 = Now & "__ " & sScriptsDir & " directory Created."
		If sDir = sEmailDir Then sCoreInfo3 = Now & "__ " & sEmailDir & " directory Created."
	Else
		iErrCode = Err.Number
		iErrDesc = CStr(Err.Number) & " " & Err.Description & "."
		Call GetWhoIsRunningScript
		oProcessEnv("SEE_MASK_NOZONECHECKS") = 1
		WSHLog "CriticalFailure", "Could not create " & sDir & " directory, Error # " & iErrDesc
	End If
	On Error GoTo 0
End Sub

' Copy blat file to system to ensure email alerts are available
Function CopyBlat
	On Error Resume Next
	Dim fn, vTimeThis, sLenghtTM, iErrDesc : fn = "blat.exe"
	If Not oFSO.FileExists(sBlat) Then
		If oFSO.FileExists(sLib & fn) Then
			vTimeThis = Now
			oFSO.CopyFile sLib & fn, sSystem32 & fn, True
			If Err.Number = 0 Then
				sLenghtTM = DateDiffToWords(vTimeThis,Now)
				WSHLog "Success", "Copied " & fn & " successfully. Took: " & sLenghtTM & "."
				sCoreBlat2 = Now & "__ Copied " & fn & " successfully. Took: " & sLenghtTM & "."
				If sDebugBlat = "True" Then Email "Copied " & fn & " successfully", "Copied " & fn & " successfully. Took: " & sLenghtTM & "."
			Else
				iErrCode = Err.Number
				iErrDesc = CStr(Err.Number) & " " & Err.Description & "."
				sBlat = sLib & "blat.exe"
				oProcessEnv("SEE_MASK_NOZONECHECKS") = 1
				WSHLog "Failure", "Could not copy " & fn & " from " & sLib & " to: " & sSystem32 & ", Error # " & iErrDesc & ". Will continue with network copy... ||"
				oProcessEnv.Remove("SEE_MASK_NOZONECHECKS")
			End If
		Else
			sCoreBlat = Now & "__ Blat not found, not in: " & sSystem32 & ", nor in: " & sLib & " no email status will be available."
			WSHLog "Failure", "Blat not found, not in: " & sSystem32 & ", nor in: " & sLib & " no email status will be available."
		End If
	End If
	On Error GoTo 0
End Function

' Get AD domain Name
Function GetDomainName
	On Error Resume Next
	Dim Info
	Set Info = CreateObject("AdSystemInfo")
	If Err.Number <> 0 Then
		iErrCode = Err.Number	
		Call CreateLogDirs
		If Not IsObject(DebugLog) Then Call CreateDebugLog("WriteLog")
		WSHLog "CriticalFailure", "Failed to create object AdSystemInfo, error: " & iErrCode
	Else
		sDomFQDN = Info.DomainDNSName
	End If
	On Error GoTo 0
End Function

' WSH Application Event Log, logging Function
Function WSHLog(EventType, Desc)
	On Error Resume Next
	If EventType = "Information" Then oShell.LogEvent 4, sScript & Chr(13) & "------------------------------------------------------" & Chr(13) & Desc
	If EventType = "Success" Then oShell.LogEvent 0, sScript & Chr(13) & "------------------------------------------------------" & Chr(13) & Desc
	If EventType = "Warning" Then
		oShell.LogEvent 2, sScript & Chr(13) & "------------------------------------------------------" & Chr(13) & Desc
		WScript.Sleep 500
		If sCoreBlat = "" Then Email EventType, Desc & "| |" & sMsg
	End If
	If EventType = "Failure" Then
		oShell.LogEvent 1, sScript & Chr(13) & "------------------------------------------------------" & Chr(13) & Desc
		WScript.Sleep 500
		If sCoreBlat = "" Then Email EventType, Desc & "| |" & sMsg
	End If
	If EventType = "CriticalFailure" Then
		oShell.LogEvent 1, sScript & Chr(13) &    "------------------------------------------------------" & Chr(13) & Desc & " Script exiting..."
		WScript.Sleep 500
		If Not(IsNull(iErrCode) Or IsEmpty(iErrCode)) Then
			If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Critical failure, exiting... Wrapper exit code : " & iErrCode)
			sPilot = "True" ' Force attachment of debuglog since we have a critical failure
			Call Cleanup(sScript & " - " & EventType, Desc & "| |" & sMsg)
			WScript.Quit(iErrCode)
		Else
			If IsObject(DebugLog) Then DebugLog.WriteLine(Now & "__ Critical failure exiting... Wrapper exit code  : " & Err.Number)
			sPilot = "True" ' Force attachment of debuglog since we have a critical failure
			Call Cleanup(sScript & " - " & EventType, Desc & "| |" & sMsg)
			WScript.Quit
		End If
	End If
	On Error GoTo 0
End Function

' EMail Results Function
Function Email(Subject, Body)
	On Error Resume Next
	Dim sTmpFile, sP1, sP2, iMail
	If Not(IsNull(sMailbox2) Or IsEmpty(sMailbox2)) Then
		sP1 = sMailbox1 & "," & sMailbox2
	Else
		sP1 = sMailbox1
	End If
	sTmpFile = sEmailDir & "\" & oFSO.GetTempName
	oFSO.CreateTextFile sTmpFile
	If Err.Number <> 0 Then
		sP2 = "-log " & Chr(34) & oProcessEnv("TEMP") & "\"
	Else
		oFSO.DeleteFile sTmpFile
		sP2 = "-log " & Chr(34) & sEmailDir & "\"
	End If

	Call Stamp
	If (sPilot = "True") And (IsObject(DebugLog)) Then
		iMail = oShell.Run(sBlat & " -body " & Chr(34) &_
		Body & Chr(34) & " -to " & sP1 & " -subject " & Chr(34) & Subject &_
		Chr(34) & " -server " & sRelayHost & " -f " & sCN & sFQDN & " -attacht " & Chr(34) & sDebugLog & Chr(34) & " -debug " & sP2 & sScript & "_" & altDate & "-" & altTime & ".log" & Chr(34) & " -try " & sTry, 2, True)
	Else
		iMail = oShell.Run(sBlat & " -body " & Chr(34) &_
		Body & Chr(34) & " -to " & sP1 & " -subject " & Chr(34) & Subject &_
		Chr(34) & " -server " & sRelayHost & " -f " & sCN & sFQDN & " -debug " & sP2 & sScript & "_" & altDate & "-" & altTime & ".log" & Chr(34) & " -try " & sTry, 2, True)
	End If
	On Error Goto 0
End Function

' Date/Time Stamping Function
Function Stamp
	On Error Resume Next
	Dim oSplit
	vDate = FormatDateTime(Now(), vbShortDate)
	altDate = Replace(Date, "/", "_")
	vTime = FormatDateTime(Now(), vbLongTime)
	altTime = Replace(Time, ":", ".")
	oSplit = Split(altTime)
	altTime = oSplit(0) & "." & oSplit(1)
	On Error GoTo 0
End Function

' Time into words Function
Function DateDiffToWords(d1, d2)
	Dim report, seconds
	report = ""
	seconds = abs(datediff("S", d1, d2))
	If seconds <= 0 Then
		report = "0 seconds"
	Else
		seconds = seconds mod (24*60*60)
		'divide by 3600 to get hours
		If seconds >= 3600 Then
			report = report & seconds\(3600) & " hour(s), "
		End If
		'use mod to get remaining seconds and divide to get minutes
		seconds = seconds mod (60*60)
		If seconds >= 60 Then
			report = report & seconds\(60) & " minute(s), "
		End If
		'use mod to get remaining seconds
		seconds = seconds Mod (60)
		report = report & seconds & " second(s)"
	End If
	DateDiffToWords = report
End Function

' Close up logs, objects, etc...
Function Cleanup(Subject, Body)
	' Close log(s)
	If IsObject(DebugLog) Then DebugLog.Close
	If (sPilot = "True") And (sCoreBlat = "") Then Email Subject, Body
	If oProcessEnv("SEE_MASK_NOZONECHECKS") = "1" Then oProcessEnv.Remove("SEE_MASK_NOZONECHECKS")
	
	'Clean Up
	If sWMIFailed <> "Failed" Then Set oWMI = Nothing
	Set oProcessEnv = Nothing
	Set oFSO = Nothing
	Set oShell = Nothing
End Function

' Script must be signed.

'' SIG '' Begin signature block
'' SIG '' MIIYxwYJKoZIhvcNAQcCoIIYuDCCGLQCAQExDzANBglg
'' SIG '' hkgBZQMEAgEFADB3BgorBgEEAYI3AgEEoGkwZzAyBgor
'' SIG '' BgEEAYI3AgEeMCQCAQEEEE7wKRaZJ7VNj+Ws4Q8X66sC
'' SIG '' AQACAQACAQACAQACAQAwMTANBglghkgBZQMEAgEFAAQg
'' SIG '' jcwxSYH1hb98Tcdo/eQmMUMMmjFZ8jN56BDB5zQ28Rmg
'' SIG '' ghNAMIIEFDCCAvygAwIBAgILBAAAAAABL07hUtcwDQYJ
'' SIG '' KoZIhvcNAQEFBQAwVzELMAkGA1UEBhMCQkUxGTAXBgNV
'' SIG '' BAoTEEdsb2JhbFNpZ24gbnYtc2ExEDAOBgNVBAsTB1Jv
'' SIG '' b3QgQ0ExGzAZBgNVBAMTEkdsb2JhbFNpZ24gUm9vdCBD
'' SIG '' QTAeFw0xMTA0MTMxMDAwMDBaFw0yODAxMjgxMjAwMDBa
'' SIG '' MFIxCzAJBgNVBAYTAkJFMRkwFwYDVQQKExBHbG9iYWxT
'' SIG '' aWduIG52LXNhMSgwJgYDVQQDEx9HbG9iYWxTaWduIFRp
'' SIG '' bWVzdGFtcGluZyBDQSAtIEcyMIIBIjANBgkqhkiG9w0B
'' SIG '' AQEFAAOCAQ8AMIIBCgKCAQEAlO9l+LVXn6BTDTQG6wkf
'' SIG '' t0cYasvwW+T/J6U00feJGr+esc0SQW5m1IGghYtkWkYv
'' SIG '' maCNd7HivFzdItdqZ9C76Mp03otPDbBS5ZBb60cO8eef
'' SIG '' nAuQZT4XljBFcm05oRc2yrmgjBtPCBn2gTGtYRakYua0
'' SIG '' QJ7D/PuV9vu1LpWBmODvxevYAll4d/eq41JrUJEpxfz3
'' SIG '' zZNl0mBhIvIG+zLdFlH6Dv2KMPAXCae78wSuq5DnbN96
'' SIG '' qfTvxGInX2+ZbTh0qhGL2t/HFEzphbLswn1KJo/nVrqm
'' SIG '' 4M+SU4B09APsaLJgvIQgAIMboe60dAXBKY5i0Eex+vBT
'' SIG '' zBj5Ljv5cH60JQIDAQABo4HlMIHiMA4GA1UdDwEB/wQE
'' SIG '' AwIBBjASBgNVHRMBAf8ECDAGAQH/AgEAMB0GA1UdDgQW
'' SIG '' BBRG2D7/3OO+/4Pm9IWbsN1q1hSpwTBHBgNVHSAEQDA+
'' SIG '' MDwGBFUdIAAwNDAyBggrBgEFBQcCARYmaHR0cHM6Ly93
'' SIG '' d3cuZ2xvYmFsc2lnbi5jb20vcmVwb3NpdG9yeS8wMwYD
'' SIG '' VR0fBCwwKjAooCagJIYiaHR0cDovL2NybC5nbG9iYWxz
'' SIG '' aWduLm5ldC9yb290LmNybDAfBgNVHSMEGDAWgBRge2Ya
'' SIG '' RQ2XyolQL30EzTSo//z9SzANBgkqhkiG9w0BAQUFAAOC
'' SIG '' AQEATl5WkB5GtNlJMfO7FzkoG8IW3f1B3AkFBJtvsqKa
'' SIG '' 1pkuQJkAVbXqP6UgdtOGNNQXzFU6x4Lu76i6vNgGnxVQ
'' SIG '' 380We1I6AtcZGv2v8Hhc4EvFGN86JB7arLipWAQCBzDb
'' SIG '' sBJe/jG+8ARI9PBw+DpeVoPPPfsNvPTF7ZedudTbpSeE
'' SIG '' 4zibi6c1hkQgpDttpGoLoYP9KOva7yj2zIhd+wo7AKvg
'' SIG '' IeviLzVsD440RZfroveZMzV+y5qKu0VN5z+fwtmK+mWy
'' SIG '' bsd+Zf/okuEsMaL3sCc2SI8mbzvuTXYfecPlf5Y1vC0O
'' SIG '' zAGwjn//UYCAp5LUs0RGZIyHTxZjBzFLY7Df8zCCBJ8w
'' SIG '' ggOHoAMCAQICEhEh1pmnZJc+8fhCfukZzFNBFDANBgkq
'' SIG '' hkiG9w0BAQUFADBSMQswCQYDVQQGEwJCRTEZMBcGA1UE
'' SIG '' ChMQR2xvYmFsU2lnbiBudi1zYTEoMCYGA1UEAxMfR2xv
'' SIG '' YmFsU2lnbiBUaW1lc3RhbXBpbmcgQ0EgLSBHMjAeFw0x
'' SIG '' NjA1MjQwMDAwMDBaFw0yNzA2MjQwMDAwMDBaMGAxCzAJ
'' SIG '' BgNVBAYTAlNHMR8wHQYDVQQKExZHTU8gR2xvYmFsU2ln
'' SIG '' biBQdGUgTHRkMTAwLgYDVQQDEydHbG9iYWxTaWduIFRT
'' SIG '' QSBmb3IgTVMgQXV0aGVudGljb2RlIC0gRzIwggEiMA0G
'' SIG '' CSqGSIb3DQEBAQUAA4IBDwAwggEKAoIBAQCwF66i07YE
'' SIG '' MFYeWA+x7VWk1lTL2PZzOuxdXqsl/Tal+oTDYUDFRrVZ
'' SIG '' UjtCoi5fE2IQqVvmc9aSJbF9I+MGs4c6DkPw1wCJU6IR
'' SIG '' MVIobl1AcjzyCXenSZKX1GyQoHan/bjcs53yB2AsT1iY
'' SIG '' AGvTFVTg+t3/gCxfGKaY/9Sr7KFFWbIub2Jd4NkZrItX
'' SIG '' nKgmK9kXpRDSRwgacCwzi39ogCq1oV1r3Y0CAikDqnw3
'' SIG '' u7spTj1Tk7Om+o/SWJMVTLktq4CjoyX7r/cIZLB6RA9c
'' SIG '' ENdfYTeqTmvT0lMlnYJz+iz5crCpGTkqUPqp0Dw6yuhb
'' SIG '' 7/VfUfT5CtmXNd5qheYjBEKvAgMBAAGjggFfMIIBWzAO
'' SIG '' BgNVHQ8BAf8EBAMCB4AwTAYDVR0gBEUwQzBBBgkrBgEE
'' SIG '' AaAyAR4wNDAyBggrBgEFBQcCARYmaHR0cHM6Ly93d3cu
'' SIG '' Z2xvYmFsc2lnbi5jb20vcmVwb3NpdG9yeS8wCQYDVR0T
'' SIG '' BAIwADAWBgNVHSUBAf8EDDAKBggrBgEFBQcDCDBCBgNV
'' SIG '' HR8EOzA5MDegNaAzhjFodHRwOi8vY3JsLmdsb2JhbHNp
'' SIG '' Z24uY29tL2dzL2dzdGltZXN0YW1waW5nZzIuY3JsMFQG
'' SIG '' CCsGAQUFBwEBBEgwRjBEBggrBgEFBQcwAoY4aHR0cDov
'' SIG '' L3NlY3VyZS5nbG9iYWxzaWduLmNvbS9jYWNlcnQvZ3N0
'' SIG '' aW1lc3RhbXBpbmdnMi5jcnQwHQYDVR0OBBYEFNSihEo4
'' SIG '' Whh/uk8wUL2d1XqH1gn3MB8GA1UdIwQYMBaAFEbYPv/c
'' SIG '' 477/g+b0hZuw3WrWFKnBMA0GCSqGSIb3DQEBBQUAA4IB
'' SIG '' AQCPqRqRbQSmNyAOg5beI9Nrbh9u3WQ9aCEitfhHNmmO
'' SIG '' 4aVFxySiIrcpCcxUWq7GvM1jjrM9UEjltMyuzZKNniiL
'' SIG '' E0oRqr2j79OyNvy0oXK/bZdjeYxEvHAvfvO83YJTqxr2
'' SIG '' 6/ocl7y2N5ykHDC8q7wtRzbfkiAD6HHGWPZ1BZo08AtZ
'' SIG '' WoJENKqA5C+E9kddlsm2ysqdt6a65FDT1De4uiAO0NOS
'' SIG '' KlvEWbuhbds8zkSdwTgqreONvc0JdxoQvmcKAjZkiLmz
'' SIG '' Gybu555gxEaovGEzbM9OuZy5avCfN/61PU+a003/3iCO
'' SIG '' Tpem/Z8JvE3KGHbJsE2FUPKA0h0G9VgEB7EYMIIFMDCC
'' SIG '' BBigAwIBAgIQBAkYG1/Vu2Z1U0O1b5VQCDANBgkqhkiG
'' SIG '' 9w0BAQsFADBlMQswCQYDVQQGEwJVUzEVMBMGA1UEChMM
'' SIG '' RGlnaUNlcnQgSW5jMRkwFwYDVQQLExB3d3cuZGlnaWNl
'' SIG '' cnQuY29tMSQwIgYDVQQDExtEaWdpQ2VydCBBc3N1cmVk
'' SIG '' IElEIFJvb3QgQ0EwHhcNMTMxMDIyMTIwMDAwWhcNMjgx
'' SIG '' MDIyMTIwMDAwWjByMQswCQYDVQQGEwJVUzEVMBMGA1UE
'' SIG '' ChMMRGlnaUNlcnQgSW5jMRkwFwYDVQQLExB3d3cuZGln
'' SIG '' aWNlcnQuY29tMTEwLwYDVQQDEyhEaWdpQ2VydCBTSEEy
'' SIG '' IEFzc3VyZWQgSUQgQ29kZSBTaWduaW5nIENBMIIBIjAN
'' SIG '' BgkqhkiG9w0BAQEFAAOCAQ8AMIIBCgKCAQEA+NOzHH8O
'' SIG '' Ea9ndwfTCzFJGc/Q+0WZsTrbRPV/5aid2zLXcep2nQUu
'' SIG '' t4/6kkPApfmJ1DcZ17aq8JyGpdglrA55KDp+6dFn08b7
'' SIG '' KSfH03sjlOSRI5aQd4L5oYQjZhJUM1B0sSgmuyRpwsJS
'' SIG '' 8hRniolF1C2ho+mILCCVrhxKhwjfDPXiTWAYvqrEsq5w
'' SIG '' MWYzcT6scKKrzn/pfMuSoeU7MRzP6vIK5Fe7SrXpdOYr
'' SIG '' /mzLfnQ5Ng2Q7+S1TqSp6moKq4TzrGdOtcT3jNEgJSPr
'' SIG '' CGQ+UpbB8g8S9MWOD8Gi6CxR93O8vYWxYoNzQYIH5DiL
'' SIG '' anMg0A9kczyen6Yzqf0Z3yWT0QIDAQABo4IBzTCCAckw
'' SIG '' EgYDVR0TAQH/BAgwBgEB/wIBADAOBgNVHQ8BAf8EBAMC
'' SIG '' AYYwEwYDVR0lBAwwCgYIKwYBBQUHAwMweQYIKwYBBQUH
'' SIG '' AQEEbTBrMCQGCCsGAQUFBzABhhhodHRwOi8vb2NzcC5k
'' SIG '' aWdpY2VydC5jb20wQwYIKwYBBQUHMAKGN2h0dHA6Ly9j
'' SIG '' YWNlcnRzLmRpZ2ljZXJ0LmNvbS9EaWdpQ2VydEFzc3Vy
'' SIG '' ZWRJRFJvb3RDQS5jcnQwgYEGA1UdHwR6MHgwOqA4oDaG
'' SIG '' NGh0dHA6Ly9jcmw0LmRpZ2ljZXJ0LmNvbS9EaWdpQ2Vy
'' SIG '' dEFzc3VyZWRJRFJvb3RDQS5jcmwwOqA4oDaGNGh0dHA6
'' SIG '' Ly9jcmwzLmRpZ2ljZXJ0LmNvbS9EaWdpQ2VydEFzc3Vy
'' SIG '' ZWRJRFJvb3RDQS5jcmwwTwYDVR0gBEgwRjA4BgpghkgB
'' SIG '' hv1sAAIEMCowKAYIKwYBBQUHAgEWHGh0dHBzOi8vd3d3
'' SIG '' LmRpZ2ljZXJ0LmNvbS9DUFMwCgYIYIZIAYb9bAMwHQYD
'' SIG '' VR0OBBYEFFrEuXsqCqOl6nEDwGD5LfZldQ5YMB8GA1Ud
'' SIG '' IwQYMBaAFEXroq/0ksuCMS1Ri6enIZ3zbcgPMA0GCSqG
'' SIG '' SIb3DQEBCwUAA4IBAQA+7A1aJLPzItEVyCx8JSl2qB1d
'' SIG '' HC06GsTvMGHXfgtg/cM9D8Svi/3vKt8gVTew4fbRknUP
'' SIG '' UbRupY5a4l4kgU4QpO4/cY5jDhNLrddfRHnzNhQGivec
'' SIG '' Rk5c/5CxGwcOkRX7uq+1UcKNJK4kxscnKqEpKBo6cSgC
'' SIG '' PC6Ro8AlEeKcFEehemhor5unXCBc2XGxDI+7qPjFEmif
'' SIG '' z0DLQESlE/DmZAwlCEIysjaKJAL+L3J+HNdJRZboWR3p
'' SIG '' +nRka7LrZkPas7CM1ekN3fYBIM6ZMWM9CBoYs4GbT8aT
'' SIG '' EAb8B4H6i9r5gkn3Ym6hU/oSlBiFLpKR6mhsRDKyZqHn
'' SIG '' GKSaZFHvMIIFTTCCBDWgAwIBAgIQA+rjH8M14KIj2YLk
'' SIG '' OUr9lTANBgkqhkiG9w0BAQsFADByMQswCQYDVQQGEwJV
'' SIG '' UzEVMBMGA1UEChMMRGlnaUNlcnQgSW5jMRkwFwYDVQQL
'' SIG '' ExB3d3cuZGlnaWNlcnQuY29tMTEwLwYDVQQDEyhEaWdp
'' SIG '' Q2VydCBTSEEyIEFzc3VyZWQgSUQgQ29kZSBTaWduaW5n
'' SIG '' IENBMB4XDTE4MDMyMjAwMDAwMFoXDTIxMDMyNTEyMDAw
'' SIG '' MFowgYkxCzAJBgNVBAYTAlVTMREwDwYDVQQIEwhOZXcg
'' SIG '' WW9yazERMA8GA1UEBxMITmV3IFlvcmsxKTAnBgNVBAoT
'' SIG '' IFRoZSBPcmNoYXJkIEVudGVycHJpc2VzIE5ZLCBJbmMu
'' SIG '' MSkwJwYDVQQDEyBUaGUgT3JjaGFyZCBFbnRlcnByaXNl
'' SIG '' cyBOWSwgSW5jLjCCASIwDQYJKoZIhvcNAQEBBQADggEP
'' SIG '' ADCCAQoCggEBAL64GstwHodIfXYXDeJCTTCesExH9ebI
'' SIG '' f6giehdOdCGEaFOV7o9aKhRSnhvsrq/Wjm3/uiqp5TVO
'' SIG '' VmEWtfDbTAZrRfkHZTTt55HIH2NYzJ4NqVtY9rNSV+iC
'' SIG '' a2IacdRNuPX4y2O2chvZ5W/u6Zw2iLuqE/Mm9UwMjIIn
'' SIG '' g5iLqkh9X6dWO4aLMYrcSnjd+Px4zWum+kXirGw+3/yY
'' SIG '' aBxtlUpU8RGR7O7w+GeqxCroEqnqdyr4FspqiXPBFxWL
'' SIG '' tlnOamydEUpTqMTTqzSm0GZQKX/tZjr2ox07RO7hE1gi
'' SIG '' 26KGsVpYvZYt2M8A29MUbbEvYOAjPgsRaBJRU67hpLCD
'' SIG '' f1cCAwEAAaOCAcUwggHBMB8GA1UdIwQYMBaAFFrEuXsq
'' SIG '' CqOl6nEDwGD5LfZldQ5YMB0GA1UdDgQWBBQVZvWOE8zP
'' SIG '' 0+a8Ws7DcVJMcdfKzDAOBgNVHQ8BAf8EBAMCB4AwEwYD
'' SIG '' VR0lBAwwCgYIKwYBBQUHAwMwdwYDVR0fBHAwbjA1oDOg
'' SIG '' MYYvaHR0cDovL2NybDMuZGlnaWNlcnQuY29tL3NoYTIt
'' SIG '' YXNzdXJlZC1jcy1nMS5jcmwwNaAzoDGGL2h0dHA6Ly9j
'' SIG '' cmw0LmRpZ2ljZXJ0LmNvbS9zaGEyLWFzc3VyZWQtY3Mt
'' SIG '' ZzEuY3JsMEwGA1UdIARFMEMwNwYJYIZIAYb9bAMBMCow
'' SIG '' KAYIKwYBBQUHAgEWHGh0dHBzOi8vd3d3LmRpZ2ljZXJ0
'' SIG '' LmNvbS9DUFMwCAYGZ4EMAQQBMIGEBggrBgEFBQcBAQR4
'' SIG '' MHYwJAYIKwYBBQUHMAGGGGh0dHA6Ly9vY3NwLmRpZ2lj
'' SIG '' ZXJ0LmNvbTBOBggrBgEFBQcwAoZCaHR0cDovL2NhY2Vy
'' SIG '' dHMuZGlnaWNlcnQuY29tL0RpZ2lDZXJ0U0hBMkFzc3Vy
'' SIG '' ZWRJRENvZGVTaWduaW5nQ0EuY3J0MAwGA1UdEwEB/wQC
'' SIG '' MAAwDQYJKoZIhvcNAQELBQADggEBACB1DiNI7jP47v3g
'' SIG '' CUKnMYg6afxdPZZMM9eDlvmU+DdnbZgxDkkeZHNZdrGb
'' SIG '' EUCEPyQJI8aEv4x8gkxm32FNt0zxZSKeoos29tUOIgo7
'' SIG '' Uf1WfDPlUnTeoZETGLFk6JQt540OaPqSHgpyoW3OKjQz
'' SIG '' /gYBExiLDIGDUI2UPn0m/PdHMVm6Cbcr7JdTUmXOcwnx
'' SIG '' ChjQxYeyIdX+cmyw2cxYKm9HtLTALmlKfcNd5LtdWZpI
'' SIG '' BzfFq/AKDmwkbctLYsrDHXaSxuP6Z/P63ZGpAgTmIXPz
'' SIG '' URWErupsXxxtEqGC1ypsKOqvd2yPiV8yl7/45xdHsMjB
'' SIG '' YYbKq5VS/S+qJpOmHbMxggTfMIIE2wIBATCBhjByMQsw
'' SIG '' CQYDVQQGEwJVUzEVMBMGA1UEChMMRGlnaUNlcnQgSW5j
'' SIG '' MRkwFwYDVQQLExB3d3cuZGlnaWNlcnQuY29tMTEwLwYD
'' SIG '' VQQDEyhEaWdpQ2VydCBTSEEyIEFzc3VyZWQgSUQgQ29k
'' SIG '' ZSBTaWduaW5nIENBAhAD6uMfwzXgoiPZguQ5Sv2VMA0G
'' SIG '' CWCGSAFlAwQCAQUAoIGEMBgGCisGAQQBgjcCAQwxCjAI
'' SIG '' oAKAAKECgAAwGQYJKoZIhvcNAQkDMQwGCisGAQQBgjcC
'' SIG '' AQQwHAYKKwYBBAGCNwIBCzEOMAwGCisGAQQBgjcCARUw
'' SIG '' LwYJKoZIhvcNAQkEMSIEIJoCXNlqbl6PKRr8J2JChato
'' SIG '' keQJfJrWNKY3MZixz6G7MA0GCSqGSIb3DQEBAQUABIIB
'' SIG '' AE4W4JYXWJJ6UzkDBAh7Vt9W/PuU3Ct625dgjQjie/j2
'' SIG '' V/xQ8VCgd8BIWDzHrNmDi9/I/uyMtJ8WnVRUr/Z591xo
'' SIG '' JcTzLQsxMeUbprjdDQSTEqFrYV7Z1Dm9dCC3AJQ/kem1
'' SIG '' /skKA7bhPipol6DWDFuHR/LYbFzXPgbe0uNlGSHb3skO
'' SIG '' qImFrDgDinI0srw9fcVipksK5ggPDTxzjieLzptnNbiV
'' SIG '' ZO5ftjDAqsmUcPZdraedKqvMSvx+jTw+S/vwVVeKEXfz
'' SIG '' waXHuBWii2tCi3YNVFckrnG+fBxkWit8+YL5E7S9cxWG
'' SIG '' ebE5Ip8G2nksgm/QuD4EhB9ZYDhnAV35A/ihggKiMIIC
'' SIG '' ngYJKoZIhvcNAQkGMYICjzCCAosCAQEwaDBSMQswCQYD
'' SIG '' VQQGEwJCRTEZMBcGA1UEChMQR2xvYmFsU2lnbiBudi1z
'' SIG '' YTEoMCYGA1UEAxMfR2xvYmFsU2lnbiBUaW1lc3RhbXBp
'' SIG '' bmcgQ0EgLSBHMgISESHWmadklz7x+EJ+6RnMU0EUMAkG
'' SIG '' BSsOAwIaBQCggf0wGAYJKoZIhvcNAQkDMQsGCSqGSIb3
'' SIG '' DQEHATAcBgkqhkiG9w0BCQUxDxcNMjAwNjA5MjAxMDA5
'' SIG '' WjAjBgkqhkiG9w0BCQQxFgQUHZBht94h3AUh3S/s4ke9
'' SIG '' +dahztgwgZ0GCyqGSIb3DQEJEAIMMYGNMIGKMIGHMIGE
'' SIG '' BBRjuC+rYfWDkJaVBQsAJJxQKTPseTBsMFakVDBSMQsw
'' SIG '' CQYDVQQGEwJCRTEZMBcGA1UEChMQR2xvYmFsU2lnbiBu
'' SIG '' di1zYTEoMCYGA1UEAxMfR2xvYmFsU2lnbiBUaW1lc3Rh
'' SIG '' bXBpbmcgQ0EgLSBHMgISESHWmadklz7x+EJ+6RnMU0EU
'' SIG '' MA0GCSqGSIb3DQEBAQUABIIBAHFMnDVRROrR7INBS95z
'' SIG '' JKdKs3MGKjHSTv/3gkBg/6C970p5qME3yO6NH06+bl97
'' SIG '' L/3+3oyYQ/b3YUSStRZODqjZEbGZinp7iSKNXhipkWeO
'' SIG '' ULvipe99cwvof3VVY2CcN6r61WVzeOHbupfm3ojBXo2j
'' SIG '' hLJCn75uTsy9O+tMm3gaNEwZ9BuZuuv4ONyTeERMuLQY
'' SIG '' R88QizWFb/+/d+zgELnrPCmmnVEmKw1BWjRtUjMBPDre
'' SIG '' Om8FzcLu0EmeT20I0NFll91qN8UZMewMn/LY8tg2ZGal
'' SIG '' ppC8Qg1Mqsvh1Ra29yFZriQ0JY85rfm7fnZVgAQxsmA2
'' SIG '' 9H/NYTIp3xJDEqI=
'' SIG '' End signature block