locals {
  final_status_lambda_name = "asset-transcoder-final-status"
}

data "aws_iam_policy_document" "final_status_notification_lambda_policy_document" {
  statement {
    sid       = ""
    effect    = "Allow"
    resources = [module.sns_final_status.proxied_sns_arn]

    actions = [
      "sns:Subscribe",
      "sns:Unsubscribe",
    ]
  }
  statement {
    sid    = ""
    effect = "Allow"
    resources = [
      "arn:aws:elastictranscoder:us-east-1:${local.account_id}:job/*"
    ]

    actions = [
      "elastictranscoder:ReadJob"
    ]
  }
}

resource "aws_iam_policy" "final_status_notification_lambda_policy" {
  name        = "${var.environment}-${local.final_status_lambda_name}-lambda-policy"
  description = "Subscribe & unsubscribe to final_status topic for asset-transcoder lambdas"
  policy      = data.aws_iam_policy_document.final_status_notification_lambda_policy_document.json
}

module "final_status_notification_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//"

  environment_name = var.environment
  service_name     = "lambda-${local.final_status_lambda_name}"
}

# Lambda function for the final status notification lambda
module "final_status_notification_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git"

  environment              = var.environment
  lambda_name              = local.final_status_lambda_name
  use_custom_function_name = true
  custom_function_name     = "${local.final_status_lambda_name}-${var.environment}"
  lambda_description       = "Processes notifications for the final status of an asset"

  lambda_function_environment_variables = {
    Environment = var.environment,
    OWSREQUEST_SERVICE_MAP = "{\"ows-asset-transcoder\": \"dev-ows-asset-transcoder.dev.theorchard.io\"}"
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_security_group_ids                         = var.vpc_security_group_ids
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_policy_file_enabled                        = false
  iam_managed_policy_attachments = [
    aws_iam_policy.common_lambda_policy.arn,
    aws_iam_policy.final_status_notification_lambda_policy.arn,
    module.final_status_notification_owsrequest.policy_arn_output
  ]
}