run "setup" {
  module {
    source = "./tests/setup"
  }
}

run "default" {
  variables {
    dev_box_id          = "terraform-test-${run.setup.random_string}"
    owner_email_address = "it@sonymusic-pde.com"
    owner_name          = "Dev User"
    vpc_name            = "dev"
    subnet_names = [
      "private00",
      "private01",
      "private02",
    ]
    route53_zone_name   = "dev.theorchard.io"
    subdomain           = "dev.theorchard.io"
    lb_logs_bucket_name = "aws-logs-103233932089-us-east-1"
    waf_name            = "dev-orcd-waf-block"
    aws_key_name        = "dev_orchard_admin"
    map_migrated_tag    = null
  }
}

run "verify" {
  module {
    source = "./tests/verify"
  }

  variables {
    oa_url          = run.default.oa_url
    workstation_url = run.default.workstation_url
    vapi_url        = run.default.vapi_url
  }

  assert {
    condition     = data.http.oa_health_check.status_code == 200
    error_message = "OA health check responded with HTTP status ${data.http.oa_health_check.status_code}"
  }

  assert {
    condition     = data.http.workstation_health_check.status_code == 200
    error_message = "Workstation health check responded with HTTP status ${data.http.workstation_health_check.status_code}"
  }

  assert {
    condition     = data.http.vapi_health_check.status_code == 200
    error_message = "VAPI health check responded with HTTP status ${data.http.vapi_health_check.status_code}"
  }
}