provider "aws" {
  region = var.region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/graphql-product/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_secretsmanager_secret" "apollo_engine_api_key" {
  name = "${var.environment}/${var.service_name}/APOLLO_ENGINE_API_KEY"
}

data "aws_secretsmanager_secret_version" "apollo_engine_api_key" {
  secret_id = data.aws_secretsmanager_secret.apollo_engine_api_key.id
}

data "aws_secretsmanager_secret" "sentry_dsn" {
  name = "${var.environment}/${var.service_name}/SENTRY_DSN"
}

data "aws_secretsmanager_secret_version" "sentry_dsn" {
  secret_id = data.aws_secretsmanager_secret.sentry_dsn.id
}

module "graphql_product_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//"

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  scale_up_adjustment                      = 1
  scale_down_adjustment                    = -1
  route53_zone_id                          = "Z2RSKZ9M7TJ9Z"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = "vpc-7f0e841a"
  datadog_function_destination_arn         = "arn:aws:lambda:us-east-1:437795906767:function:DatadogLambdaFunction"
  https_listener_certificate_id            = "a76e4883-28aa-4062-a4cc-c06b8012ae28"
  http_listener_enabled                    = false

  # overriding here to add in the graphql_switchboard_vpc (10.120.0.0/16) private subnets
  prod_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "10.40.0.0/22",
    "10.30.0.0/22",
    "10.10.40.0/22",
    "10.120.0.0/24",
    "10.120.1.0/24",
  ]

  fargate_service_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  load_balancer_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_ENGINE_API_KEY = data.aws_secretsmanager_secret_version.apollo_engine_api_key.secret_string
    },
    {
      APOLLO_ENGINE_SCHEMA_TAG = var.environment
    },
    {
      SENTRY_DSN = data.aws_secretsmanager_secret_version.sentry_dsn.secret_string
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      CACHE_USE_REDIS = var.cache_use_redis
    },
    {
      CACHE_REDIS_HOST = var.cache_redis_host
    },
    {
      PLAYGROUND = var.playground
    },
    {
      TRACING = var.tracing
    },
    {
      CORS = var.cors
    },
    {
      DEBUG = var.debug
    },
    {
      DD_ENV = "${var.environment}-graphql-product"
    },
    {
      DD_LOGS_INJECTION = true
    },
  ]
}

module "graphql_product_service_dashboard" {
  source                 = "git@github.com:theorchard/terraform-datadog.git//modules/service"
  environment            = var.environment
  environment_type       = "fargate"
  service_name           = var.service_name
  notification_endpoints = "@slack-monitoring @slack-mobile"
  datadog_service_type   = "${var.service_name}-graphql"
  datadog_service_name   = "graphql.execute"
}