module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}
provider "aws" {
  region = "us-east-1"
  alias  = "us_east_1"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-amp-terraform-state"
    key     = "dev/iam/generic_resources/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

# This service link role is used as a data source in terraform-fargate module.
#resource "aws_iam_service_linked_role" "ecs_autoscaling_service_linked_role" {
#  aws_service_name = "ecs.application-autoscaling.amazonaws.com"
#}

# Fargate task execution policy document
data "aws_iam_policy_document" "fargate_task_execution_policy_document" {
  statement {
    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:BatchGetImage",
    ]

    resources = [
      "*",
    ]
  }

  statement {
    actions = [
      "logs:*",
    ]

    resources = [
      "arn:aws:logs:*:${data.aws_caller_identity.current.account_id}:log-group:*",
    ]
  }
}

# Fargate task execution policy
resource "aws_iam_policy" "fargate_task_execution_policy" {
  name   = "Fargate-task-execution-policy"
  policy = data.aws_iam_policy_document.fargate_task_execution_policy_document.json

  tags = local.tags
}

# Fargate datadog secrets manager policy document
data "aws_iam_policy_document" "fargate_datadog_secret_policy_document" {
  statement {
    effect = "Allow"

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/datadog/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/datadog/*",
    ]

    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret",
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions   = ["secretsmanager:GetRandomPassword"]
  }
}

# Fargate datadog secrets manager policy
resource "aws_iam_policy" "fargate_datadog_secret_policy" {
  name   = "SecretsManager-${var.environment}-datadog-policy"
  policy = data.aws_iam_policy_document.fargate_datadog_secret_policy_document.json

  tags = local.tags
}