module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-aoma-delivery-terraform-state"
    key     = "dev/aoma-delivery-dev/vpc/eu-central-1/del-s2/terraform.tfstate"
    region  = "eu-central-1"
    encrypt = "true"
  }
}

data "aws_ec2_transit_gateway" "transit_gateway" {
  filter {
    name   = "options.amazon-side-asn"
    values = ["64515"]
  }
}

data "aws_subnet" "private_subnets" {
  for_each = toset(var.private_subnet_ids)
  id       = each.value
}

resource "aws_ec2_transit_gateway_vpc_attachment" "transit_gateway_attachment" {
  vpc_id             = var.vpc_id
  subnet_ids         = [for subnet in data.aws_subnet.private_subnets : subnet.id]
  transit_gateway_id = data.aws_ec2_transit_gateway.transit_gateway.id

  tags = {
    name     = "networking-transit-gateway-vpc-attachment-${var.vpc_tgw_name}"
    vpc_name = var.vpc_tgw_name
  }
}