module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "prod-business-solutions-terraform-state"
    key     = "prod/route53-backup/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy_document" "route53_backup_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::079637511089:role/backup-route53-backup-task-role"]
    }
  }
}

data "aws_iam_policy_document" "route53_backup_policy" {
  # checkov:skip=CKV_AWS_108:A widely permissive policy is the goal.
  statement {
    effect = "Allow"

    actions = [
      "route53:ListHostedZones",
      "route53:ListResourceRecordSets",
      "route53:GetHostedZone"
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "route53_backup_policy" {
  name   = "Route53-${var.environment}-${var.service_name}-RO"
  policy = data.aws_iam_policy_document.route53_backup_policy.json
}

resource "aws_iam_role" "route53_backup_role" {
  name                 = "${var.service_name}-role"
  assume_role_policy   = data.aws_iam_policy_document.route53_backup_assume_role_policy.json
  max_session_duration = 3600
  tags                 = local.tags
}

resource "aws_iam_role_policy_attachment" "admin_role_policy_attachment" {
  role       = aws_iam_role.route53_backup_role.name
  policy_arn = aws_iam_policy.route53_backup_policy.arn
}