provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/secrets-manager-backup/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy_document" "orcd_secrets_manager_secrets_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::079637511089:role/backup-orcd-secrets-manager-secrets-task-role"]
    }
    condition {
      test     = "StringEquals"
      values   = ["NtbYNNznMhvc1F9M2ZASqPhf2XPN6UOs"]
      variable = "sts:ExternalId"
    }
  }
}

data "aws_kms_key" "dev_oa_auth0_secret" {
  key_id = "alias/dev-oa-auth0-secret"
}

data "aws_kms_key" "dev_royalties_poc_2" {
  key_id = "alias/dev-royalties-poc-2"
}

data "aws_kms_key" "dev_mymac80" {
  key_id = "alias/dev-mymac80"
}

data "aws_kms_key" "dev_sales_files_transfer" {
  key_id = "alias/dev-sales-files-transfer"
}

data "aws_iam_policy_document" "orcd_secrets_manager_secrets_policy" {
  # checkov:skip=CKV_AWS_108:A widely permissive policy is the goal.
  statement {
    effect = "Allow"

    actions = [
        "secretsmanager:DescribeSecret",
        "secretsmanager:GetSecretValue",
        "secretsmanager:ListSecrets"
    ]

    resources = [
      "*",
    ]
  }
  statement {
    effect = "Allow"

    actions = [
      "kms:Decrypt",
      "kms:GenerateDataKey"
    ]
    resources = [
      data.aws_kms_key.dev_oa_auth0_secret.arn,
      data.aws_kms_key.dev_royalties_poc_2.arn,
      data.aws_kms_key.dev_mymac80.arn,
      data.aws_kms_key.dev_sales_files_transfer.arn
    ]
  }
}

resource "aws_iam_policy" "orcd_secrets_manager_secrets_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-RO"
  policy = data.aws_iam_policy_document.orcd_secrets_manager_secrets_policy.json
}

resource "aws_iam_role" "orcd_secrets_manager_secrets_role" {
  name                 = "${var.service_name}-role"
  assume_role_policy   = data.aws_iam_policy_document.orcd_secrets_manager_secrets_assume_role_policy.json
  max_session_duration = 3600
  tags                 = local.tags
}

resource "aws_iam_role_policy_attachment" "orcd_secrets_manager_secrets_role_policy_attachment" {
  role       = aws_iam_role.orcd_secrets_manager_secrets_role.name
  policy_arn = aws_iam_policy.orcd_secrets_manager_secrets_policy.arn
}