module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
  additional_tags = {
    terraformed = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.3.0"

  environment = var.environment
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "prod-ecommerce-terraform-state"
    key     = "lambda/security-group/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_security_group" "lambda_security_group" {
  name        = "${var.environment}-lambda-default-security-group"
  description = "Default security group for VPC-bound Lambda functions in ${var.environment} environment."
  vpc_id      = module.vpc_info.vpc_id
  tags        = { eiso-exception = "aws.08.30" }
}

resource "aws_security_group_rule" "allow_egress_for_lambda_security_group" {
  type              = "egress"
  protocol          = "-1"
  cidr_blocks       = ["0.0.0.0/0"]
  from_port         = 0
  to_port           = 0
  security_group_id = aws_security_group.lambda_security_group.id
}