module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = "devops"
  team_name          = "devops"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region = "us-west-2"
  alias  = "us-west-2"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-ecommerce-terraform-state"
    key     = "qa/gsirt/s3-logs/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_region" "current" {}

data "aws_iam_policy_document" "access_logs_bucket_policy" {
  statement {
    sid    = "S3ServerAccessLogsPolicy"
    effect = "Allow"
    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_logs_bucket.s3_bucket_arn_output}/*"
    ]

    principals {
      type = "Service"
      identifiers = [
        "logging.s3.amazonaws.com"
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "aws:SourceAccount"
      values = [
        data.aws_caller_identity.current.account_id
      ]
    }
  }
}

module "s3_logs_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

  env                = var.environment
  application_family = var.application_family
  bucket_name        = "${var.account_group}-s3-logs"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  // Don't configure access logging for S3 logging buckets themselves
  access_logging_enabled  = false
  bucket_policy_overrides = [data.aws_iam_policy_document.access_logs_bucket_policy.json]

  apply_replication_configuration = [
    {
      prefix                            = "${data.aws_caller_identity.current.account_id}/${data.aws_region.current.name}/"
      enabled                           = true
      delete_marker_replication_enabled = false
      destination_bucket                = var.aggregated_s3_logs_bucket
      storage_class                     = "STANDARD_IA"
    }
  ]
}

data "aws_iam_policy_document" "access_logs_bucket_us_west_2_policy" {
  statement {
    sid    = "S3ServerAccessLogsPolicy"
    effect = "Allow"
    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_logging_bucket_us_west_2.s3_bucket_arn_output}/*"
    ]

    principals {
      type = "Service"
      identifiers = [
        "logging.s3.amazonaws.com"
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "aws:SourceAccount"
      values = [
        data.aws_caller_identity.current.account_id
      ]
    }
  }
}

module "s3_logging_bucket_us_west_2" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

  providers = {
    aws = aws.us-west-2
  }

  env                = var.environment
  application_family = var.application_family
  bucket_name        = "${var.account_group}-s3-logs-us-west-2"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  // Don't configure access logging for S3 logging buckets themselves
  access_logging_enabled  = false
  bucket_policy_overrides = [data.aws_iam_policy_document.access_logs_bucket_us_west_2_policy.json]

  apply_replication_configuration = [
    {
      prefix                            = "${data.aws_caller_identity.current.account_id}/us-west-2/"
      enabled                           = true
      delete_marker_replication_enabled = false
      destination_bucket                = var.aggregated_s3_logs_bucket
      storage_class                     = "STANDARD_IA"
    }
  ]
}