module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "prod-eom-terraform-state"
    key     = "prod/eom-prod/vpc/eu-central-1/digsys-p3/terraform.tfstate"
    region  = "eu-central-1"
    encrypt = "true"
  }
}

data "aws_ec2_transit_gateway" "transit_gateway" {
  filter {
    name   = "options.amazon-side-asn"
    values = ["64515"]
  }
}

data "aws_ec2_managed_prefix_lists" "required_routes" {
  filter {
    name   = "prefix-list-name"
    values = var.vpc_routing_destination_prefix_lists
  }

  lifecycle {
    postcondition {
      condition     = length(self.ids) == length(var.vpc_routing_destination_prefix_lists)
      error_message = "Not all required managed prefix lists were found."
    }
  }
}

data "aws_subnet" "private_subnets" {
  for_each = toset(var.xapp_subnet_ids)
  id       = each.value
}

resource "aws_ec2_transit_gateway_vpc_attachment" "transit_gateway_attachment" {
  vpc_id             = var.vpc_id
  subnet_ids         = [for subnet in data.aws_subnet.private_subnets : subnet.id]
  transit_gateway_id = data.aws_ec2_transit_gateway.transit_gateway.id

  tags = {
    name     = "networking-transit-gateway-vpc-attachment-${var.vpc_tgw_name}"
    vpc_name = var.vpc_tgw_name
  }
}

resource "aws_route" "prefix_lists_private_internal_routes" {
  for_each = {
    for internal_route in local.pl_internal_routes : "${internal_route.route_table_id}.${internal_route.prefix_list_id}" => internal_route
  }

  route_table_id             = each.value.route_table_id
  transit_gateway_id         = data.aws_ec2_transit_gateway.transit_gateway.id
  destination_prefix_list_id = each.value.prefix_list_id
}

resource "aws_route" "cidr_blocks_private_internal_routes" {
  for_each = {
    for internal_route in local.cidr_internal_routes : "${internal_route.route_table_id}.${internal_route.cidr}" => internal_route
  }

  route_table_id         = each.value.route_table_id
  transit_gateway_id     = data.aws_ec2_transit_gateway.transit_gateway.id
  destination_cidr_block = each.value.cidr
}