module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-delphi-terraform-state"
    key     = "dev/gsirt/ioc-roles/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "aws_accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.1.0"
}

data "aws_iam_policy_document" "ip_set_updater_assume_policy" {
  statement {
    effect = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["networking"]}:role/lambda-prod-lambda-ioc-update-waf-ipsets",
      ]
    }

    actions = ["sts:AssumeRole"]

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = [var.external_id]
    }
  }
}

resource "aws_iam_role" "ip_set_updater" {
  name               = "${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.ip_set_updater_assume_policy.json
}

data "aws_iam_policy_document" "ip_set_update_policy" {
  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "wafv2:ListIPSets",
    ]
  }
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:wafv2:us-east-1:${data.aws_caller_identity.current.account_id}:global/ipset/gsirt-ioc-ip-set-*",
      "arn:aws:wafv2:*:${data.aws_caller_identity.current.account_id}:regional/ipset/gsirt-ioc-ip-set-*",
    ]
    actions = [
      "wafv2:GetIPSet",
      "wafv2:UpdateIPSet",
    ]
  }
}

resource "aws_iam_role_policy" "ip_set_update_policy" {
  role   = aws_iam_role.ip_set_updater.id
  name   = "WAFV2-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.ip_set_update_policy.json
}