locals {
  qa_service_name = "qa-${var.service_name}"
}

data "aws_iam_policy_document" "qa_ip_set_updater_assume_policy" {
  statement {
    effect = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["networking"]}:role/lambda-qa-lambda-ioc-update-waf-ipsets",
      ]
    }

    actions = ["sts:AssumeRole"]

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = [var.qa_external_id]
    }
  }
}

resource "aws_iam_role" "qa_ip_set_updater" {
  name               = "${local.qa_service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.qa_ip_set_updater_assume_policy.json
}

data "aws_iam_policy_document" "qa_ip_set_update_policy" {
  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "wafv2:ListIPSets",
    ]
  }
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:wafv2:us-east-1:${data.aws_caller_identity.current.account_id}:global/ipset/qa-gsirt-ioc-ip-set-ipv4/*",
      "arn:aws:wafv2:us-east-1:${data.aws_caller_identity.current.account_id}:regional/ipset/qa-gsirt-ioc-ip-set-ipv4/*",
    ]
    actions = [
      "wafv2:GetIPSet",
      "wafv2:UpdateIPSet",
    ]
  }
}

resource "aws_iam_role_policy" "qa_ip_set_update_policy" {
  role   = aws_iam_role.qa_ip_set_updater.id
  name   = "WAFV2-${local.qa_service_name}-policy"
  policy = data.aws_iam_policy_document.qa_ip_set_update_policy.json
}