module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name

  additional_tags = {
    vpc_name = var.vpc_name
  }
}

provider "aws" {
  region = "eu-central-1"
  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/transit-gateway-vpc-attachments/eu-central-1/dx-qa/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "attachment_request" {
  filter {
    name   = "vpc-id"
    values = [var.vpc_id]
  }
}

data "aws_ec2_managed_prefix_list" "vpn_sme_internal_primary" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-sme-internal-primary"]
  }
}

data "aws_ec2_transit_gateway_peering_attachment" "us_east_1" {
  filter {
    name   = "tag:peer_region"
    values = ["us-east-1"]
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "vpc_attachment" {
  for_each = var.vpc_routes
  filter {
    name   = "tag:vpc_name"
    values = [each.value]
  }
}

module "transit_gateway_attachment" {
  source = "git@github.com:theorchard/terraform-transit-gateway.git//modules/transit-gateway-vpc-attachment?ref=1.3.1"

  transit_gateway_attachment_id = data.aws_ec2_transit_gateway_vpc_attachment.attachment_request.id
  environment                   = var.environment
  vpc_name                      = var.vpc_name

  routes = {
    for key, value in var.vpc_routes :
    key => data.aws_ec2_transit_gateway_vpc_attachment.vpc_attachment[key].id
  }

  managed_prefix_list_references = {
    (data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id) = data.aws_ec2_transit_gateway_peering_attachment.us_east_1.id
  }
}