module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/transit-gateway-vpc-attachments/us-east-1/prod/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "attachment_request" {
  filter {
    name   = "vpc-id"
    values = [var.vpc_id]
  }
}

data "aws_ec2_managed_prefix_list" "vpn_ny" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-ny"]
  }
}

data "aws_ec2_transit_gateway_vpn_attachment" "vpn_ny" {
  tags = {
    vpn_name = "ny"
  }
}

data "aws_ec2_managed_prefix_list" "vpn_sme_internal_primary" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-sme-internal-primary"]
  }
}

data "aws_ec2_transit_gateway_vpn_attachment" "vpn_sme_internal_primary" {
  tags = {
    vpn_name = "vpn-sme-internal-primary"
  }
}

data "aws_ec2_transit_gateway_peering_attachment" "us_west_2" {
  filter {
    name   = "tag:peer_region"
    values = ["us-west-2"]
  }
}

data "aws_ec2_managed_prefix_list" "transit_gateway_peering_prefix_list" {
  for_each = var.managed_prefix_list_transit_gateway_peering_references
  name     = each.key
}

data "aws_ec2_transit_gateway_peering_attachment" "transit_gateway_peering_attachment" {
  for_each = var.managed_prefix_list_transit_gateway_peering_references
  filter {
    name   = "tag:Name"
    values = [each.value]
  }
}

data "aws_ec2_managed_prefix_list" "vpc_prefix_list" {
  for_each = var.managed_prefix_list_vpc_references
  name     = each.key
}

data "aws_ec2_transit_gateway_vpc_attachment" "vpc_attachment" {
  for_each = setunion(values(var.managed_prefix_list_vpc_references), values(var.vpc_routes))

  filter {
    name   = "tag:vpc_name"
    values = [each.value]
  }
}

data "aws_ec2_managed_prefix_list" "accounting_uat_private" {
  name = "uat-accounting-private-subnet-prefix-list"
}

data "aws_ec2_transit_gateway_vpc_attachment" "accounting_uat" {
  filter {
    name   = "tag:vpc_name"
    values = ["accounting-qa"]
  }
}

module "transit_gateway_attachment" {
  source = "git@github.com:theorchard/terraform-transit-gateway.git//modules/transit-gateway-vpc-attachment?ref=1.3.1"

  transit_gateway_attachment_id = data.aws_ec2_transit_gateway_vpc_attachment.attachment_request.id
  environment                   = var.environment
  vpc_name                      = var.vpc_name

  managed_prefix_list_references = merge(
    {
      (data.aws_ec2_managed_prefix_list.vpn_ny.id)                     = data.aws_ec2_transit_gateway_vpn_attachment.vpn_ny.id
      (data.aws_ec2_managed_prefix_list.vpn_sme_internal_primary.id)   = data.aws_ec2_transit_gateway_vpn_attachment.vpn_sme_internal_primary.id
      (data.aws_ec2_managed_prefix_list.accounting_uat_private.id)     = data.aws_ec2_transit_gateway_vpc_attachment.accounting_uat.id
    },
    {
      for key, value in var.managed_prefix_list_vpc_references :
      data.aws_ec2_managed_prefix_list.vpc_prefix_list[key].id => data.aws_ec2_transit_gateway_vpc_attachment.vpc_attachment[value].id
    },
    {
      for key, value in var.managed_prefix_list_transit_gateway_peering_references:
      data.aws_ec2_managed_prefix_list.transit_gateway_peering_prefix_list[key].id => data.aws_ec2_transit_gateway_peering_attachment.transit_gateway_peering_attachment[key].id
    },
  )

  routes = merge(
    {
      "172.31.0.0/16" = data.aws_ec2_transit_gateway_peering_attachment.us_west_2.id # royaltyshare
    },
    {
      for key, value in var.vpc_routes :
      key => data.aws_ec2_transit_gateway_vpc_attachment.vpc_attachment[value].id
    }
  )
}