module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/transit-gateway-vpc-attachments/us-east-1/songwhip-qa/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "attachment_request" {
  filter {
    name   = "vpc-id"
    values = [var.vpc_id]
  }
}

data "aws_ec2_managed_prefix_list" "fansifter" {
  filter {
    name   = "prefix-list-name"
    values = ["qa-fansifter-private-subnet-prefix-list"]
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "prod" {
  filter {
    name   = "tag:vpc_name"
    values = ["prod"]
  }
}

data "aws_ec2_transit_gateway_vpc_attachment" "fansifter" {
  filter {
    name   = "tag:vpc_name"
    values = ["fansifter-qa"]
  }
}

data "aws_ec2_managed_prefix_list" "vpn_prefix_list" {
  for_each = var.managed_prefix_list_vpn_references
  name     = each.key
}

data "aws_ec2_transit_gateway_vpn_attachment" "vpn_attachment" {
  for_each = var.managed_prefix_list_vpn_references

  filter {
    name   = "tag:vpn_name"
    values = [each.value]
  }
}

module "transit_gateway_attachment" {
  source = "git@github.com:theorchard/terraform-transit-gateway.git//modules/transit-gateway-vpc-attachment?ref=1.3.1"

  transit_gateway_attachment_id = data.aws_ec2_transit_gateway_vpc_attachment.attachment_request.id
  environment                   = var.environment
  vpc_name                      = var.vpc_name

  managed_prefix_list_references = merge(
    { for key, value in var.managed_prefix_list_vpn_references :
      data.aws_ec2_managed_prefix_list.vpn_prefix_list[key].id => data.aws_ec2_transit_gateway_vpn_attachment.vpn_attachment[key].id
    },
    { "${data.aws_ec2_managed_prefix_list.fansifter.id}" : data.aws_ec2_transit_gateway_vpc_attachment.fansifter.id }
  )

  routes = {
    "10.100.0.0/16" = data.aws_ec2_transit_gateway_vpc_attachment.prod.id
  }
}