resource "aws_iam_policy" "lambda_tags_policy" {
  count  = var.tags_caching_enabled ? 1 : 0
  name   = "lambda-${var.environment}-${var.service_name}-tags-policy"
  policy = data.aws_iam_policy_document.lambda_tags_policy.json
}

data "aws_iam_policy_document" "lambda_tags_policy" {
  statement {
    effect = "Allow"
    actions = [
      "tag:GetResources"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject"
    ]
    resources = [
      "${module.datadog_forwarder_tags_cache_s3_bucket.s3_bucket_arn_output}",
      "${module.datadog_forwarder_tags_cache_s3_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

resource "aws_iam_policy" "lambda_secretsmanager_override_policy" {
  name   = "lambda-${var.environment}-${var.service_name}-secretsmanager-override-policy"
  policy = data.aws_iam_policy_document.lambda_secretsmanager_override_policy.json
}

data "aws_iam_policy_document" "lambda_secretsmanager_override_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret"
    ]
    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/datadog",
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/datadog/*"
    ]
  }
}

resource "aws_iam_policy" "lambda_s3_policy" {
  count  = var.s3_bucket_list != [] ? 1 : 0
  name   = "lambda-${var.environment}-${var.service_name}-s3-policy"
  policy = data.aws_iam_policy_document.lambda_s3_policy.json
}

data "aws_iam_policy_document" "lambda_s3_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
      "s3:GetObject"
    ]
    resources = flatten([
      formatlist("arn:aws:s3:::%s", var.s3_bucket_list),
      formatlist("arn:aws:s3:::%s/*", var.s3_bucket_list)
    ])
  }
}