module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
  service_name       = var.service_name
}

provider "aws" {
  region = "us-west-2"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "prod-royaltyshare-terraform-state"
    key     = "prod/gsirt-royaltyshare/vpc-flow-logs/terraform.tfstate"
    region  = "us-west-2"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_logs_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                   = var.environment
  bucket_name           = "rs-vpc-logs"
  custom_logging_bucket = "${var.environment}-rs-s3-logs"
  s3_read_only_policy   = true
  application_family    = var.application_family

  apply_server_side_encryption_by_default = {
    se_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 30
      storage_class = "DEEP_ARCHIVE"
    }
  ]

  lifecycle_rules_options_current_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 30
      storage_class = "DEEP_ARCHIVE"
    }
  ]
}

data "aws_iam_policy_document" "kms_data_policy" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:The same as above.

  version = "2012-10-17"
  statement {
    sid    = "Enable IAM User Permissions"
    effect = "Allow"
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::290365479392:root"]
    }
    actions   = ["kms:*"]
    resources = ["*"]
  }
  statement {
    sid    = "Allow sns and s3 to use kms key"
    effect = "Allow"
    principals {
      type        = "Service"
      identifiers = ["s3.amazonaws.com", "sns.amazonaws.com"]
    }
    actions   = ["kms:GenerateDataKey", "kms:Decrypt"]
    resources = ["arn:aws:kms:${var.aws_region}:${data.aws_caller_identity.current.account_id}:key/a5ef0909-e81e-4ba2-9036-fa70874f07a2"]
  }
}

resource "aws_kms_key" "aws_vpc_logging_kms_key" {
  description             = "${var.environment}-${var.service_name}-kms-key"
  policy                  = data.aws_iam_policy_document.kms_data_policy.json
  enable_key_rotation     = true
  deletion_window_in_days = 30

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = "true"
  }
}

resource "aws_kms_alias" "aws_vpc_logging_kms_key_alias" {
  name          = "alias/${var.environment}-${var.service_name}-data-key"
  target_key_id = aws_kms_key.aws_vpc_logging_kms_key.key_id
}


module "vpc_logs_sqs_queue_with_deadletter" {
  source = "git@github.com:theorchard/terraform-sqs.git?ref=2.5.0"

  environment                          = var.environment
  application_family                   = var.application_family
  queue_name                           = "rs-vpc-logs"
  sqs_kms_master_key_id                = aws_kms_alias.aws_vpc_logging_kms_key_alias.name
  sqs_deadletter_enabled               = true
  deadletter_max_receive_count         = 200
  deadletter_delay_seconds             = 10
  deadletter_max_message_size          = 2048
  deadletter_message_retention_seconds = 86400
  deadletter_receive_wait_time_seconds = 10
}

resource "aws_sns_topic" "vpc_logs_sns_topic" {
  name                          = "${var.environment}-rs-vpc-logs"
  kms_master_key_id             = aws_kms_key.aws_vpc_logging_kms_key.key_id
  sqs_failure_feedback_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/SNSFailureFeedback"
  sqs_success_feedback_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/SNSSuccessFeedback"
}

data "aws_iam_policy_document" "vpc_logs_sns_topic_policy" {

  statement {
    actions = [
      "SNS:Publish",
    ]

    condition {
      test     = "ArnLike"
      variable = "aws:SourceArn"

      values = [
        module.vpc_logs_s3_bucket.s3_bucket_arn_output,
      ]
    }

    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = ["s3.amazonaws.com"]
    }

    resources = [
      aws_sns_topic.vpc_logs_sns_topic.arn,
    ]
  }
}

resource "aws_sns_topic_policy" "vpc_logs_sns_topic_policy" {
  arn    = aws_sns_topic.vpc_logs_sns_topic.arn
  policy = data.aws_iam_policy_document.vpc_logs_sns_topic_policy.json
}

resource "aws_sns_topic_subscription" "vpc_logs_sns_sqs_target" {
  topic_arn              = aws_sns_topic.vpc_logs_sns_topic.arn
  protocol               = "sqs"
  endpoint               = module.vpc_logs_sqs_queue_with_deadletter.queue_arn
  endpoint_auto_confirms = true
}

# Policy document to allow SNS to send message to SQS
data "aws_iam_policy_document" "vpc_logs_sqs_queue_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sqs:SendMessage",
    ]

    principals {
      type        = "AWS"
      identifiers = ["*"]
    }

    resources = [
      module.vpc_logs_sqs_queue_with_deadletter.queue_arn,
    ]

    condition {
      test     = "ArnLike"
      variable = "aws:SourceArn"

      values = [
        aws_sns_topic.vpc_logs_sns_topic.arn
      ]
    }
  }
}

# Policy to allow SNS to send message to SQS
resource "aws_sqs_queue_policy" "vpc_logs_sqs_queue_policy" {
  queue_url = module.vpc_logs_sqs_queue_with_deadletter.queue_url
  policy    = data.aws_iam_policy_document.vpc_logs_sqs_queue_policy_document.json
}

resource "aws_s3_bucket_notification" "vpc_logs_bucket_notification" {
  bucket = module.vpc_logs_s3_bucket.s3_bucket_name_output

  topic {
    topic_arn = aws_sns_topic.vpc_logs_sns_topic.arn
    events    = ["s3:ObjectCreated:*"]
  }

  depends_on = [aws_sns_topic_policy.vpc_logs_sns_topic_policy]
}

data "aws_iam_policy_document" "vpc_logs_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:ListBucket",
    ]

    resources = [
      module.vpc_logs_s3_bucket.s3_bucket_arn_output,
      "${module.vpc_logs_s3_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sqs:ChangeMessageVisibility",
      "sqs:DeleteMessage",
      "sqs:GetQueueUrl",
      "sqs:GetQueueAttributes",
      "sqs:ListDeadLetterSourceQueues",
      "sqs:ListQueueTags",
      "sqs:ReceiveMessage",
    ]

    resources = [
      module.vpc_logs_sqs_queue_with_deadletter.queue_arn,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sqs:ListQueues",
    ]

    resources = [
      "*"
    ]
  }

  statement {
    sid       = ""
    effect    = "Allow"
    resources = ["arn:aws:kms:${var.aws_region}:${data.aws_caller_identity.current.account_id}:key/a5ef0909-e81e-4ba2-9036-fa70874f07a2"]

    actions = [
      "kms:GenerateDataKey",
      "kms:Decrypt",
    ]
  }
}

resource "aws_iam_policy" "vpc_logs_policy" {
  name   = "${var.environment}-vpc-logs-access-policy"
  policy = data.aws_iam_policy_document.vpc_logs_policy_document.json
}

# Role used by GSIRT
data "aws_iam_role" "gsirt_aws_monitoring_role" {
  name = "GSIRT_AWS_Monitoring_Role"
}

# Attach vpc-logs-access-policy to GSIRT_AWS_Monitoring_Role
resource "aws_iam_role_policy_attachment" "gsirt_waf_logs_access_policy_attachement" {
  role       = data.aws_iam_role.gsirt_aws_monitoring_role.name
  policy_arn = aws_iam_policy.vpc_logs_policy.arn
}