module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "shared-orcd-terraform-state"
    key     = "shared/datadog-rds-enhanced-monitoring/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

locals {
  organization_id = "o-bqioddgr91"
  organization_units = [
    "ou-ax9e-vu43qt3i", // The Orchard OU
  ]
}

data "aws_iam_policy_document" "lambda_code_bucket_policy" {
  statement {
    sid = "AllowOrganizationGetObject"

    principals {
      type        = "*"
      identifiers = ["*"]
    }

    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.lambda_code_bucket.s3_bucket_arn_output}/*",
    ]

    condition {
      test     = "ForAnyValue:StringLike"
      variable = "aws:PrincipalOrgPaths"
      values   = formatlist("${local.organization_id}/*/%s/*", local.organization_units)
    }
  }
}

module "lambda_code_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                = var.environment
  bucket_name        = var.bucket_name
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.lambda_code_bucket_policy.json,
  ]
}