data "aws_iam_policy_document" "guardduty_kms_key_policy" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:The same as above.
  statement {
    sid       = "Enable IAM User Permissions"
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "kms:*",
    ]

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:root",
      ]
    }
  }

  statement {
    sid       = "Allow GuardDuty to use key"
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "kms:GenerateDataKey",
    ]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "StringLike"
      variable = "aws:SourceArn"
      values   = formatlist("arn:aws:guardduty:*:%s:detector/*", module.aws_accounts.account_ids)
    }

    condition {
      test     = "StringEquals"
      variable = "aws:SourceAccount"
      values   = module.aws_accounts.account_ids
    }
  }
}

module "guardduty_logs_bucket" {
  source = "git@github.com:theorchard/terraform-gsirt.git//modules/access_logs?ref=2.3.4"
  providers = {
    aws = aws.us_east_1
  }

  environment                   = var.environment
  service_name                  = var.account_group
  access_log_type               = "guardduty"
  kms_override_policy_documents = [data.aws_iam_policy_document.guardduty_kms_key_policy.json]
  bucket_policy_overrides       = [data.aws_iam_policy_document.guardduty_bucket_policy_document.json]
}

data "aws_iam_policy_document" "guardduty_bucket_policy_document" {
  statement {
    sid       = "Deny non-HTTPS access"
    effect    = "Deny"
    resources = ["${module.guardduty_logs_bucket.access_logs_bucket_arn}/*"]
    actions   = ["s3:*"]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "Bool"
      variable = "aws:SecureTransport"
      values   = ["false"]
    }
  }

  statement {
    sid       = "Deny incorrect encryption header"
    effect    = "Deny"
    resources = ["${module.guardduty_logs_bucket.access_logs_bucket_arn}/*"]
    actions   = ["s3:PutObject"]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "StringNotEquals"
      variable = "s3:x-amz-server-side-encryption-aws-kms-key-id"
      values   = [module.guardduty_logs_bucket.access_logs_kms_key_arn]
    }
  }

  statement {
    sid       = "Deny unencrypted object uploads"
    effect    = "Deny"
    resources = ["${module.guardduty_logs_bucket.access_logs_bucket_arn}/*"]
    actions   = ["s3:PutObject"]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "StringNotEquals"
      variable = "s3:x-amz-server-side-encryption"
      values   = ["aws:kms"]
    }
  }

  statement {
    sid       = "Allow PutObject"
    effect    = "Allow"
    resources = ["${module.guardduty_logs_bucket.access_logs_bucket_arn}/*"]
    actions   = ["s3:PutObject"]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "StringLike"
      variable = "aws:SourceArn"
      values   = formatlist("arn:aws:guardduty:*:%s:detector/*", module.aws_accounts.account_ids)
    }

    condition {
      test     = "StringEquals"
      variable = "aws:SourceAccount"
      values   = module.aws_accounts.account_ids
    }
  }

  statement {
    sid       = "Allow GetBucketLocation"
    effect    = "Allow"
    resources = [module.guardduty_logs_bucket.access_logs_bucket_arn]
    actions   = ["s3:GetBucketLocation"]

    principals {
      type = "Service"
      identifiers = [
        "guardduty.amazonaws.com",
      ]
    }

    condition {
      test     = "StringLike"
      variable = "aws:SourceArn"
      values   = formatlist("arn:aws:guardduty:*:%s:detector/*", module.aws_accounts.account_ids)
    }

    condition {
      test     = "StringEquals"
      variable = "aws:SourceAccount"
      values   = module.aws_accounts.account_ids
    }
  }
}

data "aws_iam_role" "security_lake_role" {
  name = var.security_lake_iam_role_name
}

resource "aws_cloudwatch_event_rule" "security_lake_guardduty_event_forwarder" {
  name        = "Shared-${var.security_lake_iam_role_name}-guardduty-log-forward"
  description = "Forward S3 Object Created events for GuardDuty log bucket to Security Lake account"

  event_pattern = jsonencode({
    source      = ["aws.s3"]
    detail-type = ["Object Created"]
    detail = {
      bucket = {
        name = [module.guardduty_logs_bucket.access_logs_bucket_name]
      }
    }
  })
}

resource "aws_cloudwatch_event_target" "security_lake_event_bus_target" {
  rule      = aws_cloudwatch_event_rule.security_lake_guardduty_event_forwarder.name
  target_id = "SecurityLakeEventBus"
  arn       = "arn:aws:events:us-east-1:${var.security_lake_account_id}:event-bus/default"
  role_arn  = data.aws_iam_role.security_lake_role.arn
}