module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
  service_name       = var.service_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-songwhip-terraform-state"
    key     = "qa/gsirt/lb-logs/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

# S3 bucket for lb logs destination
module "lb_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  application_family    = var.application_family
  env                   = var.environment
  bucket_name           = var.bucket_name
  custom_logging_bucket = "${var.environment}-songwhip-s3-logs"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [data.aws_iam_policy_document.lb_logs_bucket_policy_document.json]
}

# Custom policy for load balancer logs
data "aws_iam_policy_document" "lb_logs_bucket_policy_document" {
  statement {
    effect = "Allow"

    resources = [
      "arn:aws:s3:::${module.lb_s3_bucket.s3_bucket_name_output}/AWSLogs/${data.aws_caller_identity.current.account_id}/*",
      "arn:aws:s3:::${module.lb_s3_bucket.s3_bucket_name_output}/*",
    ]

    actions = [
      "s3:PutObject"
    ]

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::127311923021:root" #AWS Elastic Load Balancing account ID in us-east-1
      ]
    }
  }

  statement {
    effect = "Allow"
    resources = [
      "arn:aws:s3:::${module.lb_s3_bucket.s3_bucket_name_output}/*"
    ]
    actions = [
      "s3:PutObject"
    ]

    condition {
      test     = "StringEquals"
      variable = "s3:x-amz-acl"
      values = [
        "bucket-owner-full-control"
      ]
    }

    principals {
      type = "Service"
      identifiers = [
        "delivery.logs.amazonaws.com"
      ]
    }
  }

  statement {
    effect = "Allow"
    resources = [
      "arn:aws:s3:::${module.lb_s3_bucket.s3_bucket_name_output}"
    ]
    actions = [
      "s3:GetBucketAcl"
    ]

    principals {
      type = "Service"
      identifiers = [
        "delivery.logs.amazonaws.com"
      ]
    }
  }
}

data "aws_iam_policy_document" "kms_data_policy" {
  # checkov:skip=CKV_AWS_109:It is a KMS key policy, so it applies only to a specific key.
  # checkov:skip=CKV_AWS_111:The same as above.

  version = "2012-10-17"
  statement {
    sid    = "Enable IAM User Permissions"
    effect = "Allow"
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::${data.aws_caller_identity.current.account_id}:root"]
    }
    actions   = ["kms:*"]
    resources = ["*"]
  }
  statement {
    sid    = "Allow sns and s3 to use kms key"
    effect = "Allow"
    principals {
      type        = "Service"
      identifiers = ["s3.amazonaws.com", "sns.amazonaws.com"]
    }
    actions   = ["kms:GenerateDataKey", "kms:Decrypt"]
    resources = ["arn:aws:kms:${var.aws_region}:${data.aws_caller_identity.current.account_id}:key/b33eaad1-7d12-46fe-b8c4-356e9e8239dd"]
  }
}

resource "aws_kms_key" "lb_logs_kms_key" {
  description             = "${var.environment}-${var.service_name}-kms-key"
  policy                  = data.aws_iam_policy_document.kms_data_policy.json
  enable_key_rotation     = true
  deletion_window_in_days = 30

  tags = {
    environment        = var.environment
    service_name       = var.service_name
    application_family = var.application_family
    terraformed        = "true"
  }
}

resource "aws_kms_alias" "lb_logs_kms_key_alias" {
  name          = "alias/${var.environment}-${var.service_name}-data-key"
  target_key_id = aws_kms_key.lb_logs_kms_key.key_id
}

module "lb_logs_sqs_queue_with_deadletter" {
  source = "git@github.com:theorchard/terraform-sqs.git?ref=2.5.0"

  environment                          = var.environment
  application_family                   = var.application_family
  queue_name                           = "songwhip-lb-logs"
  sqs_kms_master_key_id                = aws_kms_alias.lb_logs_kms_key_alias.name
  sqs_deadletter_enabled               = "true"
  deadletter_max_receive_count         = 200
  deadletter_delay_seconds             = 10
  deadletter_max_message_size          = 2048
  deadletter_message_retention_seconds = 86400
  deadletter_receive_wait_time_seconds = 10
}

resource "aws_sns_topic" "lb_logs_sns_topic" {
  name                          = "${var.environment}-songwhip-lb-logs"
  kms_master_key_id             = aws_kms_key.lb_logs_kms_key.key_id
  sqs_failure_feedback_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/SNSFailureFeedback"
  sqs_success_feedback_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/SNSSuccessFeedback"
  policy                        = <<POLICY
{
    "Version":"2012-10-17",
    "Statement":[{
        "Effect": "Allow",
        "Principal": { "Service": "s3.amazonaws.com" },
        "Action": "sns:Publish",
        "Resource": "arn:aws:sns:${var.aws_region}:${data.aws_caller_identity.current.account_id}:${var.environment}-songwhip-lb-logs",
        "Condition":{
            "ArnLike":{"aws:SourceArn":"${module.lb_s3_bucket.s3_bucket_arn_output}"}
        }
    }]
}
POLICY
}

data "aws_iam_policy_document" "lb_logs_sns_topic_policy" {

  statement {
    actions = [
      "sns:Publish",
    ]

    condition {
      test     = "ArnLike"
      variable = "aws:SourceArn"

      values = [
        module.lb_s3_bucket.s3_bucket_arn_output,
      ]
    }

    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = ["s3.amazonaws.com"]
    }

    resources = [
      aws_sns_topic.lb_logs_sns_topic.arn,
    ]
  }
}

resource "aws_sns_topic_policy" "lb_logs_sns_topic_policy" {
  arn    = aws_sns_topic.lb_logs_sns_topic.arn
  policy = data.aws_iam_policy_document.lb_logs_sns_topic_policy.json
}

resource "aws_sns_topic_subscription" "lb_logs_sns_sqs_target" {
  topic_arn              = aws_sns_topic.lb_logs_sns_topic.arn
  protocol               = "sqs"
  endpoint               = module.lb_logs_sqs_queue_with_deadletter.queue_arn
  endpoint_auto_confirms = true
}

# Policy document to allow SNS to send message to SQS
data "aws_iam_policy_document" "lb_logs_sqs_queue_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sqs:SendMessage",
    ]

    principals {
      type        = "AWS"
      identifiers = ["*"]
    }

    resources = [
      module.lb_logs_sqs_queue_with_deadletter.queue_arn,
    ]

    condition {
      test     = "ArnLike"
      variable = "aws:SourceArn"

      values = [
        aws_sns_topic.lb_logs_sns_topic.arn
      ]
    }
  }
}

# Policy to allow SNS to send message to SQS
resource "aws_sqs_queue_policy" "lb_logs_sqs_queue_policy" {
  queue_url = module.lb_logs_sqs_queue_with_deadletter.queue_url
  policy    = data.aws_iam_policy_document.lb_logs_sqs_queue_policy_document.json
}

# S3 Buckets only support a single notification configuration.
resource "aws_s3_bucket_notification" "lb_logs_bucket_notification" {
  bucket = module.lb_s3_bucket.s3_bucket_name_output

  topic {
    topic_arn = aws_sns_topic.lb_logs_sns_topic.arn
    events    = ["s3:ObjectCreated:*"]
  }

  depends_on = [aws_sns_topic_policy.lb_logs_sns_topic_policy]
}

data "aws_iam_policy_document" "lb_logs_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:ListBucket",
    ]

    resources = [
      module.lb_s3_bucket.s3_bucket_arn_output,
      "${module.lb_s3_bucket.s3_bucket_arn_output}/*"
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sqs:ChangeMessageVisibility",
      "sqs:DeleteMessage",
      "sqs:GetQueueUrl",
      "sqs:GetQueueAttributes",
      "sqs:ListDeadLetterSourceQueues",
      "sqs:ListQueueTags",
      "sqs:ReceiveMessage",
    ]

    resources = [
      module.lb_logs_sqs_queue_with_deadletter.queue_arn,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sqs:ListQueues",
    ]

    resources = [
      "*"
    ]
  }

  statement {
    sid       = ""
    effect    = "Allow"
    resources = ["arn:aws:kms:${var.aws_region}:${data.aws_caller_identity.current.account_id}:key/b33eaad1-7d12-46fe-b8c4-356e9e8239dd"]

    actions = [
      "kms:GenerateDataKey",
      "kms:Decrypt",
    ]
  }
}

resource "aws_iam_policy" "lb_logs_policy" {
  name   = "${var.environment}-lb-logs-access-policy"
  policy = data.aws_iam_policy_document.lb_logs_policy_document.json
}

# Role used by GSIRT
data "aws_iam_role" "gsirt_aws_monitoring_role" {
  name = "GSIRT_AWS_Monitoring_Role"
}

# Attach lb-logs-access-policy to GSIRT_AWS_Monitoring_Role
resource "aws_iam_role_policy_attachment" "gsirt_waf_logs_access_policy_attachement" {
  role       = data.aws_iam_role.gsirt_aws_monitoring_role.name
  policy_arn = aws_iam_policy.lb_logs_policy.arn
}