module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"
  alias  = "us_east_1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region = "us-east-2"
  alias  = "us_east_2"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "prod-supply-chain-terraform-state"
    key     = "gsirt/config/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "aws_config_us_east_1" {
  source = "git@github.com:theorchard/terraform-gsirt.git//modules/config?ref=2.3.3"
  providers = {
    aws = aws.us_east_1
  }

  environment  = var.environment
  service_name = var.account_group

  create_iam_role                      = true
  existing_s3_bucket_name              = var.aggregated_logs_bucket

  exclude_resource_types = [
    "AWS::Config::ResourceCompliance",
    "AWS::EC2::VPC",
    "AWS::EC2::NetworkInterface",
  ]

  recording_frequency_override_resource_types = [
    "AWS::ElasticLoadBalancingV2::TargetGroup",
    "AWS::EC2::SecurityGroup",
    "AWS::EC2::Subnet",
  ]
}

module "aws_config_us_east_2" {
  source = "git@github.com:theorchard/terraform-gsirt.git//modules/config?ref=2.3.3"
  providers = {
    aws = aws.us_east_2
  }

  environment  = var.environment
  service_name = "${var.account_group}-us-east-2"

  create_s3_bucket        = false
  existing_s3_bucket_name = var.aggregated_logs_bucket
  existing_iam_role_arn   = module.aws_config_us_east_1.config_role_arn

  exclude_resource_types = [
    "AWS::Config::ResourceCompliance",
    "AWS::EC2::VPC",
    "AWS::EC2::NetworkInterface",
  ]

  recording_frequency_override_resource_types = [
    "AWS::ElasticLoadBalancingV2::TargetGroup",
    "AWS::EC2::SecurityGroup",
    "AWS::EC2::Subnet",
  ]
}