module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-accounting-terraform-state"
    key     = "qa/abacus-managed-airflow/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "aws_accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.1.0"
}

data "aws_iam_policy_document" "airflow_cross_account_lambda_assume" {
  statement {
    actions = [
      "sts:AssumeRole"
    ]
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["prod"]}:role/qa-abacus-airflow-airflow-execution-role"
      ]
    }
  }
}

resource "aws_iam_role" "airflow_cross_account_lambda_assume" {
  name     = "MWAA-${var.environment}-${var.service_name}-lambda-abacus-invoke"

  assume_role_policy = data.aws_iam_policy_document.airflow_cross_account_lambda_assume.json
}

data "aws_iam_policy" "airflow_invoke_lambda_policy" {
  name = "${var.environment}-lambda-abacus-generic-invoke-policy"
}

resource "aws_iam_role_policy_attachment" "airflow_invoke_lambda_attachment" {
  policy_arn = data.aws_iam_policy.airflow_invoke_lambda_policy.arn
  role       = aws_iam_role.airflow_cross_account_lambda_assume.name
}