locals {
  lambda_abacus_earnings_transfer_service_name = "${var.service_name}-earnings-transfer"
}

# S3 Bucket

data "aws_iam_policy_document" "cross_account_integration_tests_policy" {
  statement {
    sid = "IntegrationTestsBucketTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["prod"]}:user/cucumber-tests"
      ]
    }

    actions = [
      "s3:ListBucket",
      "s3:ListBucketVersions",
      "s3:ListBucketMultipartUploads"
    ]

    resources = [
      module.s3_abacus_earnings_transfer_bucket.s3_bucket_arn_output
    ]
  }

  statement {
    sid = "IntegrationTestsAPathTrustRelationship"
    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::${module.aws_accounts.all_accounts["prod"]}:user/cucumber-tests"
      ]
    }

    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:PutObject",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload"
    ]

    resources = [
      "${module.s3_abacus_earnings_transfer_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

module "s3_abacus_earnings_transfer_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.1"
  env                = var.environment
  bucket_name        = "abacus-earnings-transfer"
  application_family = var.application_family

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cross_account_integration_tests_policy.json,
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "abacus_earnings_transfer_bucket_read_write_access_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject*",
      "s3:PutObject*",
    ]

    resources = [
      "${module.s3_abacus_earnings_transfer_bucket.s3_bucket_arn_output}/*",
      "${module.s3_abacus_earnings_transfer_bucket.s3_bucket_arn_output}/",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
    ]

    resources = [
      module.s3_abacus_earnings_transfer_bucket.s3_bucket_arn_output,
    ]
  }
}

resource "aws_iam_policy" "abacus_earnings_transfer_bucket_read_write_access_policy" {
  name        = "${var.environment}-abacus-earnings-transfer-read-write-access-policy"
  description = "Policy for abacus_earnings_transfer bucket read/write permissions"
  policy      = data.aws_iam_policy_document.abacus_earnings_transfer_bucket_read_write_access_document.json
}

# Lambda

module "lambda_abacus_earnings_transfer_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = local.lambda_abacus_earnings_transfer_service_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_earnings_transfer_owsrequest" {
  source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name = var.environment
  service_name     = local.lambda_abacus_earnings_transfer_service_name
}

module "lambda_abacus_earnings_transfer" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Reads files from the earnings-transfer input prefix and writes output."
  lambda_name                                       = "${var.service_name}-earnings-transfer"
  vpc_id                                            = module.vpc_info.vpc_id
  vpc_subnet_ids                                    = module.vpc_info.default_private_subnet_ids
  vpc_create_security_group                         = true
  application_family                                = var.application_family
  # lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 2
  lambda_function_memory_size                    = 1024

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    SENTRY_DSN  = module.lambda_abacus_earnings_transfer_sentry_project.sentry_key_dsn_public_output

    S3_BUCKET_NAME = module.s3_abacus_earnings_transfer_bucket.s3_bucket_name_output

    SNOWFLAKE_ACCOUNT   = var.lambda_snowflake_account
    SNOWFLAKE_DATABASE  = var.lambda_snowflake_database
    SNOWFLAKE_SCHEMA    = var.lambda_snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.lambda_snowflake_warehouse
    SNOWFLAKE_ROLE      = var.lambda_snowflake_role
    SNOWFLAKE_USER      = var.lambda_snowflake_user
  }

  iam_managed_policy_attachments = [
    module.lambda_abacus_earnings_transfer_owsrequest.policy_arn_output,
    aws_iam_policy.abacus_earnings_transfer_bucket_read_write_access_policy.arn,
  ]
}

module "lambda_abacus_earnings_transfer_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.snowflake_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = local.lambda_abacus_earnings_transfer_service_name
  secret_name        = each.value
}