module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "abacus"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-accounting-terraform-state"
    key     = "qa/ows-royalties-workflows/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name   = "S3-${var.environment}-abacus-adjustments-usage-policy"
  policy = data.aws_iam_policy_document.abacus_adjustments_usage_policy.json
}

data "aws_iam_policy_document" "abacus_adjustments_usage_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation",
      "s3:ListBucketMultipartUploads"
    ]
    resources = ["arn:aws:s3:::qa-abacus-adjustments"] // the bucket is in the prod account
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:AbortMultipartUpload",
      "s3:CompleteMultipartUpload",
      "s3:CreateMultipartUpload",
      "s3:DeleteObject*",
      "s3:GetObject*",
      "s3:ListMultipartUploadParts",
      "s3:PutObject*",
      "s3:UploadPart"
    ]
    resources = ["arn:aws:s3:::qa-abacus-adjustments/*"]
  }
}

data "aws_iam_role" "accounting_role" {
  name = "accounting-role"
}