provider "snowflake" {
  account_name      = "dataplatform"
  organization_name = "sme"
  role              = "PROD_ATLANTIS"
  preview_features_enabled = [
    "snowflake_stage_resource",
    "snowflake_storage_integration_resource",
  ]
}

data "aws_caller_identity" "current" {}

locals {
  snowflake_integration_role_name = "${var.environment}-${var.service_name}-snowflake-integration-role"
}

resource "snowflake_storage_integration" "integration" {
  name             = "${var.environment}-${var.service_name}-s3-integration"
  storage_provider = "S3"
  storage_allowed_locations = ["s3://${module.s3_bucket.s3_bucket_name_output}/"]
  storage_aws_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${local.snowflake_integration_role_name}"
}

resource "snowflake_stage" "stage" {
  name                = "${var.environment}-${var.service_name}-s3-stage"
  url                 = "s3://${module.s3_bucket.s3_bucket_name_output}/"
  database            = var.snowflake_database
  schema              = var.snowflake_schema
  storage_integration = snowflake_storage_integration.integration.name
}

module "stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.7.5"

  database = snowflake_stage.stage.database
  schema   = snowflake_stage.stage.schema
  stage    = snowflake_stage.stage.name
}

data "aws_iam_policy_document" "assume_role" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type        = "AWS"
      identifiers = [snowflake_storage_integration.integration.storage_aws_iam_user_arn]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = [snowflake_storage_integration.integration.storage_aws_external_id]
    }
  }
}

data "aws_iam_policy_document" "s3_access" {
  statement {
    actions   = ["s3:GetObject", "s3:GetObjectVersion"]
    resources = ["${module.s3_bucket.s3_bucket_arn_output}/*"]
  }

  statement {
    actions   = ["s3:ListBucket", "s3:GetBucketLocation"]
    resources = [module.s3_bucket.s3_bucket_arn_output]
  }
}

resource "aws_iam_role" "snowflake_integration_role" {
  name               = local.snowflake_integration_role_name
  assume_role_policy = data.aws_iam_policy_document.assume_role.json
}

resource "aws_iam_role_policy" "s3_access" {
  name   = "${var.environment}-${var.service_name}-snowflake-s3-policy"
  role   = aws_iam_role.snowflake_integration_role.id
  policy = data.aws_iam_policy_document.s3_access.json
}