module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "abacus"
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}


terraform {
  backend "s3" {
    bucket  = "qa-accounting-terraform-state"
    key     = "uat/graphql-abacus/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.4"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.qa-accounting.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "qa-accounting.theorchard.io"
}

module "graphql_abacus_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.4"

  providers = {
    aws.dns = aws
  }

  environment                   = var.environment
  service_name                  = var.service_name
  application_family            = var.application_family
  aws_region                    = var.region
  commit_sha                    = "latest"
  container_port                = "8080"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 1024
  task_memory                   = var.task_memory
  maximum_capacity              = 4
  minimum_capacity              = 2
  route53_zone_id               = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  blocking_waf_enabled          = true
  https_listener_allow_prefix_list_names = [
    "uat-orcd-private-subnet-prefix-list",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = concat(
    [for policy in data.aws_iam_policy.existing_policies_to_attach : policy.arn]
  )

  environment_variables = [
    {
      NODE_OPTIONS = "--max-old-space-size=${var.task_memory - var.datadog_task_memory - var.fluentbit_task_memory}"
    },
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_INTROSPECTION = "false"
    },
    {
      APOLLO_PLAYGROUND = "false"
    },
    {
      S3_PAYMENTS_BUCKET_NAME = var.s3_payments_bucket_name
    },
    {
      BUCKET_UPLOAD_ROLE_ARN = aws_iam_role.graphql_abacus_browser_upload_role.arn
    },
    {
      BUCKET_UPLOAD_TOKEN_DURATION = var.bucket_upload_token_duration
    },
    {
      APOLLO_GRAPH_REF = "graphql-theorchard@qa"
    },
    {
      AUTH0_DOMAIN = "qa-orchard.auth0.com"
    },
    {
      OWS_ACCOUNT_URL = "https://qa-ows-account.theorchard.io/"
    },
    {
      OWS_MONEYHUB_URL = "https://qa-ows-moneyhub.theorchard.io/"
    },
    {
      OWS_PRODUCT_URL = "https://qa-ows-product.theorchard.io/"
    },
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    {
      SPLIT_API_KEY = "${var.environment}/split/API_KEY"
    }
  ]
}

module "graphql_abacus_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.0"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  datadog_service_type              = var.service_name
  datadog_service_name              = "graphql.execute"
  application_family                = var.application_family
  notification_endpoints            = "@slack-abacus-monitoring-uat @slack-graphql"
  escalation_notification_endpoints = "@slack-abacus-monitoring-uat @slack-graphql"
  dependent_applications            = var.dependent_applications
}

module "sentry-graphql-abacus" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  teams              = ["abacus-qa"]
  application_family = var.application_family
}

data "aws_s3_bucket" "graphql_abacus_payments_bucket" {
  bucket = var.s3_payments_bucket_name
}

data "aws_iam_policy_document" "graphql_abacus_put_only_bucket_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${data.aws_s3_bucket.graphql_abacus_payments_bucket.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "graphql_abacus_put_only_bucket_policy" {
  name        = "S3-${var.environment}-abacus-buckets-WO"
  description = "Write access to prod abacus bucket(s)"
  policy      = data.aws_iam_policy_document.graphql_abacus_put_only_bucket_policy.json
}

data "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name = var.s3_abacus_adjustments_usage_policy
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type        = "AWS"
      identifiers = [module.graphql_abacus_fargate_environment.fargate_task_iam_role_arn]
    }
  }
}

resource "aws_iam_role" "graphql_abacus_browser_upload_role" {
  name                 = "${var.environment}-graphql-abacus-browser-upload-role"
  max_session_duration = var.bucket_upload_token_duration
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_payments_browser_upload_policy_attachment" {
  role       = aws_iam_role.graphql_abacus_browser_upload_role.id
  policy_arn = aws_iam_policy.graphql_abacus_put_only_bucket_policy.arn
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_adjustments_browser_upload_policy_attachment" {
  role       = aws_iam_role.graphql_abacus_browser_upload_role.id
  policy_arn = data.aws_iam_policy.abacus_adjustments_usage_policy.arn
}

data "aws_iam_policy_document" "graphql_abacus_browser_upload_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.graphql_abacus_browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "graphql_abacus_browser_upload_assume_role_policy" {
  name        = "${var.environment}-graphql-abacus-browser-upload-assume-role-policy"
  description = "Assume browser upload role used by the graphql-abacus fargate role."
  policy      = data.aws_iam_policy_document.graphql_abacus_browser_upload_assume_role_policy_document.json
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_browser_upload_policy_attachment_to_fargate" {
  role       = module.graphql_abacus_fargate_environment.fargate_task_iam_role_name
  policy_arn = aws_iam_policy.graphql_abacus_browser_upload_assume_role_policy.arn
}

data "aws_iam_policy" "existing_policies_to_attach" {
  for_each = toset(var.existing_policies_to_attach)
  name     = each.value
}