data "aws_iam_policy_document" "abacus_sales_files_bucket_write_access_document" {
  statement {
    effect = "Allow"
    resources = [
      "${var.sales_files_bucket_arn}/*"
    ]
    actions = [
      "s3:GetObject",
      "s3:DeleteObject",
      "s3:PutObject"
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      var.sales_files_bucket_arn
    ]
    actions = [
      "s3:ListBucket"
    ]
  }
}

resource "aws_iam_policy" "abacus_sales_files_bucket_write_access_policy" {
  name        = "S3-${var.environment}-abacus-sales-files-write-access-policy"
  description = "Policy for sales files bucket write permissions"
  policy      = data.aws_iam_policy_document.abacus_sales_files_bucket_write_access_document.json
}

module "lambda_abacus_ledger_accounting_run_balance_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = "${var.service_name}-ledger-accounting-run-balance"
  teams              = ["abacus-qa"]
  application_family = var.application_family

}

# module "lambda_abacus_ledger_accounting_run_balance_owsrequest" {
#   source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
#   environment_name = var.environment
#   service_name     = "${var.service_name}-ledger-accounting-run-balance"
# }

module "lambda_abacus_ledger_accounting_run_balance" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.2.0"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Write run summary from snowflake to ledger service"
  lambda_name                                       = "${var.service_name}-ledger-accounting-run-balance"
  vpc_id                                            = module.vpc_info.vpc_id
  vpc_subnet_ids                                    = module.vpc_info.default_private_subnet_ids
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 2
  lambda_function_memory_size                    = 1024

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    SNOWFLAKE_ACCOUNT   = var.lambda_snowflake_account
    SNOWFLAKE_DATABASE  = var.lambda_snowflake_database
    SNOWFLAKE_SCHEMA    = var.lambda_snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.lambda_snowflake_warehouse
    SNOWFLAKE_ROLE      = var.lambda_snowflake_role
    SNOWFLAKE_USER      = var.lambda_snowflake_user
  }

  iam_managed_policy_attachments = [
    # module.lambda_abacus_ledger_accounting_run_balance_owsrequest.policy_arn_output,
    aws_iam_policy.abacus_sales_files_bucket_write_access_policy.arn
  ]
}

module "lambda_abacus_ledger_accounting_run_balance_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.accounting_run_balance_secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-ledger-accounting-run-balance"
  secret_name        = each.value
}