data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "sfn_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "sfn_invoke_lambda_and_fargate_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_delete_intermediate_snapshots.lambda_arn,
    ]

  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-create-shareable-snapshot",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-create-shareable-snapshot:*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-manage-backup-snapshots",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-manage-backup-snapshots:*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:StopTask"
    ]
    resources = [
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.service_name}-create-shareable-snapshot/*",
      "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.service_name}-manage-backup-snapshots/*",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:DescribeTasks"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule"
    ]
    resources = [
      "arn:aws:events:${var.region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "iam:PassRole",
    ]
    resources = [
      module.fargate_create_shareable_snapshot.fargate_task_iam_role_arn,
      module.fargate_create_shareable_snapshot.fargate_task_iam_execution_role_arn,
      module.fargate_manage_backup_snapshots.fargate_task_iam_role_arn,
      module.fargate_manage_backup_snapshots.fargate_task_iam_execution_role_arn,
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "sts:AssumeRole",
    ]
    resources = [
      "arn:aws:iam::${var.shared_account_id}:role/prod-${var.service_name}-step-function-invoke-lambda-role",
    ]
  }
}

data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      "*",
    ]

    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_role" "sfn_role" {
  name               = "${var.environment}-${var.service_name}-sfn-role"
  description        = "${var.environment}-${var.service_name}-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_role_policy.json
}

resource "aws_iam_policy" "sfn_invoke_lambda_and_fargate_policy" {
  name        = "${var.environment}-${var.service_name}-invoke-lambda-and-fargate-policy"
  description = "${var.environment}-${var.service_name}-invoke-lambda-and-fargate-policy"
  policy      = data.aws_iam_policy_document.sfn_invoke_lambda_and_fargate_policy_document.json
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.service_name}-sfn-log-policy"
  description = "${var.environment}-${var.service_name}-sfn-log-policy"
  policy      = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_invoke_lambda_and_fargate_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_invoke_lambda_and_fargate_policy.arn
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
  tags              = local.tags
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_function_log_filter" {
  name            = "${var.environment}-${var.service_name}-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

resource "aws_sfn_state_machine" "sfn_rds_backup" {
  name     = "${var.environment}-${var.service_name}-state-machine"
  role_arn = aws_iam_role.sfn_role.arn
  definition = templatefile("${path.module}/sfn_rds_backup.json", {
    region                                                = var.region
    create_shareable_snapshot_fargate_cluster_arn         = module.fargate_create_shareable_snapshot.fargate_cluster_arn
    create_shareable_snapshot_fargate_task_definition_arn = "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-create-shareable-snapshot:${var.create_shareable_snapshot_task_revision}"
    create_shareable_snapshot_fargate_task_security_group = module.fargate_create_shareable_snapshot.fargate_security_group_id
    manage_backup_snapshots_fargate_cluster_arn           = module.fargate_manage_backup_snapshots.fargate_cluster_arn
    manage_backup_snapshots_fargate_task_definition_arn   = "arn:aws:ecs:${var.region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}-manage-backup-snapshots:${var.manage_backup_snapshots_task_revision}"
    manage_backup_snapshots_fargate_task_security_group   = module.fargate_manage_backup_snapshots.fargate_security_group_id
    fargate_task_subnets                                  = jsonencode(module.vpc_info.default_private_subnet_ids)
    lambda_delete_intermediate_snapshots_name             = module.lambda_delete_intermediate_snapshots.lambda_name
    lambda_invoke_role_arn                                = "arn:aws:iam::${var.shared_account_id}:role/prod-${var.service_name}-step-function-invoke-lambda-role"
    lambda_extract_native_configuration_arn               = "arn:aws:lambda:${var.region}:${var.shared_account_id}:function:shared-lambda-${var.service_name}-extract-native-configuration"
  })
  tags = local.tags

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}